Functions > Window > Controls >


ControlTreeView

Envoie une commande à un contrôle TreeView32.

ControlTreeView ( "title", "text", controlID, "command" [, option1] )

Paramètres

title Le titre/hWnd/class de la fenêtre à atteindre. Consultez Définition spéciale de titre.
text Le texte de la fenêtre à atteindre. Consultez Définition spéciale de texte.
controlID Le contrôle avec lequel interagir. Consultez Contrôles.
command La commande à envoyer au contrôle (Voir ci-dessous).
option1 [optionnel] Paramètre additionnel requis par certaines commandes.

Valeur de retour

Dépend de la commande comme le montre le tableau ci-dessous. En cas d'erreur (telle qu'une commande ou fenêtre/contrôle invalide), @error = 1.
Commande, Option1 Opération
"Check", "item" Coche un élément (si celui-ci le permet).
"Collapse", "item" Replie un élément pour cacher ses sous-éléments.
"Exists", "item" Retourne 1 si un élément existe, sinon 0.
"Expand", "item" Déploie un élément pour montrer ses sous-éléments.
"GetItemCount", "item" Retourne le nombre de sous-éléments pour un élément sélectionné.
"GetSelected" [, UseIndex] Retourne la référence de l'élément de la sélection en cours, par la référence de son texte (ou par son index si UseIndex est mis à 1).
"GetText", "item" Retourne le texte d'un élément.
"IsChecked" Retourne l'état d'un élément. 1:coché, 0:décoché, -1:n'est pas de type CheckBox.
"Select", "item" Sélectionne un élément.
"Uncheck", "item" Décoche un élément (si celui-ci le permet).


Le paramètre "item" est un paramètre chaîne qui est utilisé pour référencer un élément spécifique du 'treeview' par une combinaison de texte et d'index. Les index sont de base 0. Par exemple:
Heading1
----> H1SubItem1
----> H1SubItem2
----> H1SubItem3
----> ----> H1S1SubItem1
Heading2
Heading3

Chaque "niveau" est séparé par le caractère "|". Et chaque index est précédé du caractère "#". Exemples:
Elément Référence d'élément
Heading2 "Heading2" ou "#1"
H1SubItem2 "Heading1|H1SubItem2" ou "#0|#1"
H1S1SubItem1 "Heading1|H1SubItem3|H1S1SubItem1" ou "#0|#2|#0"

Les références peuvent aussi être mixées tel que "Heading1|#1".

Remarque

Comme AutoIt est une application 32-bit, quelques commandes ne sont pas disponibles pour référencer une application 64-bit comme Explorer lors de l'exécution sur un Windows 64-bit.

En relation

ControlCommand

Exemple

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("ControlTreeView Example", 212, 212)
    Local $idTreeView_1 = GUICtrlCreateTreeView(6, 6, 200, 160, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    Local $hTreeView_1 = ControlGetHandle($hGUI, "", $idTreeView_1)

    Local $idRoot = GUICtrlCreateTreeViewItem("Root", $idTreeView_1)
    GUICtrlCreateTreeViewItem("Item 1", $idRoot)
    GUICtrlCreateTreeViewItem("Item 2", $idRoot)
    GUICtrlCreateTreeViewItem("Item 3", $idRoot)
    Local $idItem_4 = GUICtrlCreateTreeViewItem("Item 4", $idRoot)
    GUICtrlCreateTreeViewItem("Item 4.1", $idItem_4)
    GUICtrlCreateTreeViewItem("Item 4.2", $idItem_4)
    GUICtrlCreateTreeViewItem("Item 5", $idRoot)

    GUISetState(@SW_SHOW, $hGUI)

    ControlTreeView($hGUI, "", $hTreeView_1, "Expand", "Root")

    ControlTreeView($hGUI, "", $hTreeView_1, "Exists", "Root|Item 4")
    ControlTreeView($hGUI, "", $hTreeView_1, "Check", "Root|Item 4")
    ControlTreeView($hGUI, "", $hTreeView_1, "Select", "Root|Item 4")
    ControlTreeView($hGUI, "", $hTreeView_1, "Expand", "Root|Item 4")

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete($hGUI)
EndFunc   ;==>Example