[R] Récupérer contenu combo

[aulus]

Bonjour,

Je propose un combo dans lequel l'utilisateur fait son choix. S'il n'y trouve pas son bonheur, il peut entrer lui-même ses données. Par exemple, le combo propose les prénoms "Pierre, Jean, Paul, Jacques". Aucun de ces prénoms ne satisfaisant l'utilisateur, il peut entrer le prénom Louis.

Si je crée une fonction pour éditer la donnée (par exemple pour la mettre en majuscules), cette fonction va bien récupérer la donnée par un GUICtrlRead(), mais uniquement si l'utilisateur a pioché son prénom dans la liste du combo. Si c'est une donnée rentrée par lui, le GUICtrlRead() ne récupère rien.

Y a-t-il moyen de réussir la récupération dans tous les cas de figure ?

Je vous remercie.

[Tlem]

Chez moi, le code ci-dessous fonctionne comme vous le décrivez :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUICreate("Form1", 194, 122, 192, 124)
Global $Combo = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Pierre|Jean|Paul|Jacques")
Global $Ok = GUICtrlCreateButton("Ok", 56, 80, 75, 25)
GUISetState(@SW_SHOW)

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

  Case $Ok
    MsgBox(0, "", StringUpper(GUICtrlRead($Combo)))

 EndSwitch
WEnd

[aulus]

Merci Tlem pour votre test. Voici le mien dans lequel vous verrez que le code surligné en rouge n'a pas d'effet (le contenu de $Combo1 n'est pas mis en majuscules) :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

Global $Form1 = GUICreate("Form1", 194, 122, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE,"Quitter")
Global $Combo1 = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Pierre|Jean|Paul|Jacques")
GUICtrlSetOnEvent($Combo1, "Majuscule")
Global $Combo2 = GUICtrlCreateInput("", 24, 80, 145, 25)
GUISetState(@SW_SHOW)
While 1
    Sleep(1000)
WEnd
Func Majuscule()
    Select
Case @GUI_CtrlId = $Combo1
[color=#FF0000]GUICtrlSetData($Combo1, StringUpper(GUICtrlRead($Combo1)))[/color]
GUICtrlSetData($Combo2, StringUpper(GUICtrlRead($Combo1)))
msgbox(0,"1",GUICtrlRead($Combo1))
EndSelect
endfunc

Func Quitter()
    Exit
EndFunc
 

[jguinch]

Quand on y réfléchit, c'est assez logique que ça ne fonctionne pas en mode event...
En imaginant qu'à chaque fois que tapes un caractère ça génère un événement, tu aurais pour la saisie du prénom "alain" les événements "a", "l", "a", "i" et "n". Donc ça serait un peu le foutoir, non ?

Tout simplement, tu pourrais ajouter un bouton "+" ou un truc du genre qui te permettrait, lors du clic, d'ajouter le prénom saisi à la liste.

Voilà ci-dessous deux exemples :
- le premier utilise WM_COMMAND pour capter les changement dans la combo, pour afficher le bouton "+" quand tu saisis du texte manuellement
- le deuxième utilise GUISetAccelerators avec un contrôle de type dummy, ce qui permet d'appeler la fonction Majuscule quand on clique sur la touche "Enter"

► Afficher le texteAvec WM_COMMAND

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)


Global $Form1 = GUICreate("Form1", 194, 122, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE,"Quitter")

Global $Combo1 = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Pierre|Jean|Paul|Jacques")
GUICtrlSetOnEvent($Combo1, "Majuscule")

Global $add = GUICtrlCreateButton("+", 170, 24, 15, 20)
GUICtrlSetState($add, $GUI_HIDE)
GUICtrlSetOnEvent($add, "Majuscule")


Global $Combo2 = GUICtrlCreateInput("", 24, 80, 145, 25)



GUIRegisterMsg ($WM_COMMAND, "My_WM_COMMAND")   
GUISetState(@SW_SHOW)


While 1
    Sleep(1000)
WEnd


Func Majuscule()
    Select
        Case @GUI_CtrlId = $Combo1 OR @GUI_CtrlId = $add
            GUICtrlSetState($add, $GUI_HIDE)
            GUICtrlSetData($Combo1, StringUpper(GUICtrlRead($Combo1)))
            GUICtrlSetData($Combo2, StringUpper(GUICtrlRead($Combo1)))
            msgbox(0,"1",GUICtrlRead($Combo1))
    EndSelect
Endfunc



Func My_WM_COMMAND($hWnd, $imsg, $iwParam, $ilParam)
    Local $setHK = False
    $nNotifyCode = BitShift($iwParam, 16)
    $nID = BitAND($iwParam, 0x0000FFFF)
    $hCtrl = $ilParam
    
    If $nNotifyCode = $CBN_EDITCHANGE AND $hCtrl = GUICtrlGetHandle($Combo1) Then GUICtrlSetState($add, $GUI_SHOW)
    Return $GUI_RUNDEFMSG
    

EndFunc  ;==>My_WM_COMMAND

Func Quitter()
    Exit
EndFunc
     

► Afficher le texteAvec GUISetAccelerators

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)


Global $Form1 = GUICreate("Form1", 194, 122, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE,"Quitter")

Global $Combo1 = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Pierre|Jean|Paul|Jacques")
GUICtrlSetOnEvent($Combo1, "Majuscule")


Global $Combo2 = GUICtrlCreateInput("", 24, 80, 145, 25)

$dummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent($dummy, "Majuscule")
Local $aAccels[1][2]=[["{ENTER}", $dummy]]
GUISetAccelerators($aAccels)


GUISetState(@SW_SHOW)


While 1
    Sleep(1000)
WEnd


Func Majuscule()
    Select
        Case @GUI_CtrlId = $Combo1 OR @GUI_CtrlId = $dummy
            GUICtrlSetData($Combo1, StringUpper(GUICtrlRead($Combo1)))
            GUICtrlSetData($Combo2, StringUpper(GUICtrlRead($Combo1)))
            msgbox(0,"1",GUICtrlRead($Combo1))
    EndSelect
Endfunc



Func Quitter()
    Exit
EndFunc
     
 

Du coup, ça complexifie le code, mais bon, le mode Event n'a pas que des avantages...

[aulus]

Merci jguinch pour votre travail (codes et tests).

Dans les deux cas, le contenu de $form1 n'est pas mis en majuscules, but de l'opération. Le code de Tlem tout comme le mien n'y parviennent pas non plus.

Le code suivant est ignoré dans la fonction Majuscule() :

Code : Tout sélectionner

GUICtrlSetData($Combo, StringUpper(GUICtrlRead($Combo))) ; $Combo dans le code de Tlem
GUICtrlSetData($Combo1, StringUpper(GUICtrlRead($Combo1))) ; $Combo1 dans les nôtres
 

[aulus]

Oh ! merveille... je crois que j'ai trouvé une solution : $CBS_UPPERCASE

Code : Tout sélectionner

Global $Combo = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR([color=#FF0000]$CBS_UPPERCASE[/color], $CBS_DROPDOWN,$CBS_AUTOHSCROLL))

Merci à tous pour votre travail.

[TommyDDR]

Pour reprendre le code de jguinch :

► Afficher le textecode

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)


Global $Form1 = GUICreate("Form1", 194, 122, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE,"Quitter")

Global $Combo1 = GUICtrlCreateCombo("", 24, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Pierre|Jean|Paul|Jacques")
GUICtrlSetOnEvent($Combo1, "Majuscule")

Global $add = GUICtrlCreateButton("+", 170, 24, 15, 20)
GUICtrlSetState($add, $GUI_HIDE)
GUICtrlSetOnEvent($add, "Majuscule")


Global $Combo2 = GUICtrlCreateInput("", 24, 80, 145, 25)



GUIRegisterMsg ($WM_COMMAND, "My_WM_COMMAND")
GUISetState(@SW_SHOW)


While 1
    Sleep(1000)
WEnd


Func Majuscule()
    Select
        Case @GUI_CtrlId = $Combo1 OR @GUI_CtrlId = $add
            GUICtrlSetState($add, $GUI_HIDE)
            GUICtrlSetData($Combo1, StringUpper(GUICtrlRead($Combo1)))
            GUICtrlSetData($Combo2, StringUpper(GUICtrlRead($Combo1)))
            msgbox(0,"1",GUICtrlRead($Combo1))
    EndSelect
Endfunc



Func My_WM_COMMAND($hWnd, $imsg, $iwParam, $ilParam)
    Local $setHK = False
    $nNotifyCode = BitShift($iwParam, 16)
    $nID = BitAND($iwParam, 0x0000FFFF)
    $hCtrl = $ilParam

    If $nNotifyCode = $CBN_EDITCHANGE AND $hCtrl = GUICtrlGetHandle($Combo1) Then
        GUICtrlSetState($add, $GUI_SHOW)
        _GUICtrlComboBox_SetEditText($Combo1, StringUpper(GUICtrlRead($Combo1)))
        GUICtrlSetData($Combo2, StringUpper(GUICtrlRead($Combo1)))
    EndIf
    Return $GUI_RUNDEFMSG


EndFunc  ;==>My_WM_COMMAND

Func Quitter()
    Exit
EndFunc

[aulus]

Merci Tommy. Votre code met bien en majuscules l'entrée dans le combo lorsque celle-ci n'est pas sélectionnée dans la liste déroulante. Toutefois, si l'entrée est sélectionnée dans la liste déroulante, elle reste en minuscules. Cette solution est intéressante puisqu'il suffirait de remplir la liste déroulante directement en majuscules pour régler tous les cas de figure.

Toutefois, je vais garder la solution que j'ai trouvée et qui consiste à utiliser le style $CBS_UPPERCASE dans le combo, d'une simplicité imbattable !

[TommyDDR]

Oui, en effet, le $CBS_UPPERCASE semble être là pour ça, il me semble aussi être la meilleure solution.