[..] Décortiquer un string

[Crypto0]

Salut tout le monde, suite à mon dernier post qui fut très rapidement corrigé, j'aimerais savoir de quelle manière dois-je m'y prendre pour décortiquer un string de la forme :

Code : Tout sélectionner

Pudding=Lait[0.5],Pain[500],Oeuf[6]

Il faudrait que je me retrouve à la fin avec des variables qui contiendraient un ingrédient avec sa quantité, par exemple :
$Var = Lait[0.5].
Merci d'avance.

[mikell]

Il y a plusieurs façons de procéder en fonction de la forme finale recherchée
Par exemple pour mettre dans un ini, vu que ton sujet précédent comportait un "Recettes.ini" :

Code : Tout sélectionner

$string = "Pudding=Lait[0.5],Pain[500],Oeuf[6]"

_AddRecette("Recettes.ini", $string)

Func _AddRecette($ini, $str)
  Local $txt = ""
  Local $split1 = StringSplit($str, "=")
  Local $split2 = StringSplit($split1[2], ",")
  For $i = 1 to $split2[0]
     $txt &= StringRegExpReplace($split2[$i], '(\w+)\[([\d.]+)\]', '$1=$2') & @lf
     ; ou bien:    $txt &= StringReplace(StringReplace($split2[$i], '[', '='), ']', '') & @lf
  Next
  IniWriteSection($ini, $split1[1], $txt)
EndFunc

[Tlem]

Salut. Je propose ceci :

Code : Tout sélectionner

#include <Array.au3>
Local $Var = "Pudding=Lait[0.5],Pain[500],Oeuf[6]"

$Var = StringTrimLeft($Var, StringInStr($Var, "=")) ; On supprime = et ce qu'il y a avant
Local $aVar = StringSplit($Var, ",") ; On met en tableau

_ArrayDisplay($aVar)

Comme ça tout est en tableau direct.

Edit : Ou sinon comme Michel l'a fait :

Code : Tout sélectionner

#include <Array.au3>
Local $str = "Pudding=Lait[0.5],Pain[500],Oeuf[6]"

Local $split1 = StringSplit($str, "=")
Local $split2 = StringSplit($split1[2], ",")

_ArrayDisplay($split2)

[mikell]

Ou comme dit Thierry, avec une array qui décortique toutes les données :

Code : Tout sélectionner

#include <Array.au3>
$string = "Pudding=Lait[0.5],Pain[500],Oeuf[6]"

$split1 = StringSplit($string, "=")
$data = StringReplace(StringReplace($split1[2], '[', '='), ']', '')
$split2 = StringSplit($data, ",")
Local $array[$split2[0]+1][2]
For $i = 1 to $split2[0]
  $split3 = StringSplit($split2[$i], "=")
  $array[$i][0] = $split3[1]
  $array[$i][1] = $split3[2]
Next
$array[0][0] = $split1[1]
_ArrayDisplay($array)

ou encore ça

Code : Tout sélectionner

#include <Array.au3>
$string = "Pudding=Lait[0.5],Pain[500],Oeuf[6]"

$res = StringRegExp(StringRegExpReplace($string, '[^\w\d.]', "="), "[\w\d.]+", 3)
_ArrayDisplay($res)

[Tlem]

Que de choix ...

[mikell]

Ben oui, qu'est ce que tu veux, il pleut ...

[jchd]

Oui, mais ce sont des perles de codes qui pleuvent et fertilisent ce sujet !

[Tlem]

Magnifique Jean-Christophe. Tu es donc d'humeur fleur bleu aujourd'hui.

[jchd]

Surtout tout émoustillé de voir un string décortiqué de mille façons par autant de praticiens empressés

[mikell]

C'est ça le sens des responsabilités. On se fait un devoir de méthodiquement décortiquer le string et consciencieusement fertiliser le sujet

[Crypto0]

Je vous remercie énormément, vous assurez un max. J'ai opté pour la solution de Mikell ( la plus courte des deux).

[jguinch]

Si le problème est résolu, merci de mettre en [R] dans le sujet du premier message.