[R] Retrouver position d'une img à la réouverture de la GUI

[aulus]

Bonjour et bon Noël !

L'image est affichée selon ce code :

Code : Tout sélectionner

$oIE = ObjCreate("Shell.Explorer.2")
$image = GUICtrlCreateObj($oIE, 0, 0, 1000, 500)
Local $tmp = @TempDir & "\tmp.htm"
Local $f = FileOpen($tmp, 2)
FileWrite($f, '<img src="' & $fichier & '">')
FileClose($f)
$oIE.Navigate($tmp)
 

L'utilisateur fait défiler l'image dans sa fenêtre, à sa convenance.
Il quitte la GUI affichant l'image lorsque besoin il y a, puis revient à cette même GUI affichant l'image lorsque nécessaire.
Est-il possible de coder de telle sorte, qu'au retour, il retrouve son image à la position où il l'avait laissée dans sa fenêtre (verticalement et horizontalement) ?
Pour être plus précis, cette image représente un texte que l'utilisateur fait défiler. Je souhaiterais qu'au retour il ait devant les yeux la ligne qu'il avait atteinte avant de quitter la GUI.

J'ai pensé aux fonction $pos = MouseGetPos() en quittant la GUI affichant l'image, puis MouseMove($pos[0], $pos[1], 0) au retour dans la GUI. Me faut-il creuser l'idée ou l'abandonner car ne me conduisant nulle part ? Pour l'instant je n'arrive à rien.

Je vous remercie de votre éclairage.

[mikell]

Si on met la gui en hide/show au lieu de la fermer/rouvrir la position se conserve
Sinon tu peux aussi enregistrer la position pour réutiliser ensuite

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>

InetGet("http://musee.jeannedarc.pagesperso-orange.fr/images/genealogie.jpg", @TempDir & "\ze_img.jpg");, 1)
Local $tmp = @TempDir & "\tmp.htm"
Local $f = FileOpen($tmp, 2)
FileWrite($f, '<img name="myimg" src="' & @TempDir & '\ze_img.jpg">')
FileClose($f)

$oIE=ObjCreate("Shell.Explorer.2")
$gui1 = GUICreate ("test", 550, 350)
$label = GuiCtrlCreateLabel($tmp, 20, 320, 500, 30)
$btn = GuiCtrlCreateButton("get scroll", 420, 40, 80, 30)
$btn2 = GuiCtrlCreateButton("set scroll", 420, 80, 80, 30)
$hide = GuiCtrlCreateButton("Hide", 420, 180, 80, 30)
$show = GuiCtrlCreateButton("Show", 420, 220, 80, 30)
GUISetState()
$gui2 = GUICreate ("", 400, 300, 0, 0, $WS_POPUPWINDOW,$WS_EX_MDICHILD, $gui1)
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 400, 300)   ;img 721x534
GUISetState()
$oIE.Navigate($tmp)

Global $w, $h

While 1
$msg = GuiGetMsg()
If $msg = -3 Then Exit
If $msg = $btn Then 
  $w = $oIE.document.body.scrollLeft
  $h = $oIE.document.body.scrollTop
 ; msgbox(0,"", $w &@crlf& $h)
EndIf
If $msg = $btn2 Then $oIE.document.parentwindow.scroll($w, $h)
If $msg = $hide Then GUISetState(@SW_HIDE, $gui2)  
If $msg = $show Then GUISetState(@SW_SHOW, $gui2)  
Wend
 

[aulus]

Merci Mikell pour ce beau code. Ca marche parfaitement.