[R] detecter la connexion d'un disque USB (et sa taille)

[GhostLine]

Salut à tous !

Je suis en train d'essayer, à des fins d'industrialisation de duplication de disques (avec de multiples masters) de détecter le disque dur qui va être connecté dans une station d'accueil USB.

J'ai zoné sur le forum américain, trouvé un certain nombre de choses, "frankensteinisé" quelques scripts (IT'S *almost* ALIVE !), sans vraiment réussir à obtenir un résultat probant :

Code : Tout sélectionner

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = @ComputerName

$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")

$colEvents = $objWMIService.ExecNotificationQuery _
        ("Select * From __InstanceOperationEvent Within 5 Where " _
         & "TargetInstance isa 'Win32_LogicalDisk'")

$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_DiskDrive", "WQL", _
        $wbemFlagReturnImmediately + $wbemFlagForwardOnly)


While 1
    $objEvent = $colEvents.NextEvent
    ConsoleWrite($objEvent.TargetInstance.DriveType)
    If $objEvent.TargetInstance.DriveType = 4 Then
        For $objItem In $colItems
;~          If $objItem.DeviceID <> "\\.\PHYSICALDRIVE0" Then
            MsgBox(0, "", $objItem.DeviceID & " - Size: " & Round($objItem.Size / 1024 ^ 3, 2) & "Gb")
;~          EndIf
        Next
    EndIf
WEnd

Un p'ti coup de main ?

Merci d'avance !

[jguinch]

Pour la détection, voilà un truc qui pourrait te servir :http://www.autoitscript.fr/forum/viewto ... 470#p83470

Pour la taille, tu peux utiliser DriveSpaceTotal()

[GhostLine]

J'ai oublié de préciser que les disques sont vierges de toute partition (sinon, ca serait pas drôle ).

[jguinch]

En partant du script récupéré ici, je pense que ça devrait convenir :

► Afficher le texte

Code : Tout sélectionner

Local $strComputer = "."
Local $objWMIServices = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")

Local $sink = ObjCreate("WbemScripting.SWbemSink")
ObjEvent($sink, "SINK_")

Local $model, $size

$objWMIServices.ExecNotificationQueryAsync($sink, "SELECT * FROM __InstanceOperationEvent WITHIN 5 WHERE TargetInstance ISA 'Win32_DiskDrive'")

While 1
    Sleep(250)
WEnd



Func SINK_OnObjectReady($objObject, $objAsyncContext)
    If $objObject.TargetInstance.InterfaceType = "USB" Then
        Select
            Case $objObject.Path_.Class() = "__InstanceCreationEvent"
                $model = $objObject.TargetInstance.Model
                $size = $objObject.TargetInstance.Size

                ConsoleWrite("Lecteur " & $model & " ajouté : taille = " & $size & @CRLF)

            Case $objObject.Path_.Class() = "__InstanceDeletionEvent"
                $model = $objObject.TargetInstance.Model
                ConsoleWrite("Lecteur " & $model & " supprimé" & @CRLF)
        EndSelect
    EndIf
EndFunc   ;==>SINK_OnObjectReady

[GhostLine]

Merveilleux, exactement ce dont j'avais besoin !

MERCI !