[R] Suppression dossiers et fichiers dans une boucle

[guillaume]

Bonjour à tous,

Je cherche à développer un script pour nettoyer les profils itinérant de mes utilisateurs (suppressions de fichiers et dossiers )

Jusque là pas de problèmes pour supprimer les fichiers, j'utilise une boucle pour lister les dossiers des utilisateurs.

mais comme je veux aussi supprimer des sous-dossiers je ne peux pas le faire avec un FileDelete du coup je dois faire une 2ième boucle dans ma boucle pour faire un DirRemove

Je ne sais pas si on peut faire ça, mais avec mon script j'ai un "non-Array variable"


Bon j'imagine que j'ai du faire un peu n'importe quoi, je ne suis pas le roi de la mise en forme...

Si vous pouvez m'aider à faire ça de manière propre ça serait top !

merci

► Afficher le texte

$dossier_profil = "E:\ProfilsTSE\"

$FileList=_FileListToArray($dossier_profil, "*.*", 2)



For $indice = 1 to $FileList[0]

FileDelete ($dossier_profil&$FileList[$indice]&"\logiciel\temp\*.*" )
FileDelete ($dossier_profil&$FileList[$indice]&"\AppData\Roaming\Microsoft\Windows\Cookies\*.*" )
$word=($dossier_profil&$FileList[$indice]&"\AppData\Roaming\Microsoft\Word")

_word()

Next



Func _word()

$files = _FileListToArray($word, "*", 2)

For $i = 1 To $files[0]

DirRemove($dir & '\' & $file, 1)
FileDelete($dir & '\' & $file)
Next


EndFunc



Exit

[bloodwolff]

Je n'ai pas fais d'autoit depuis un petit moment mais c'est totalement faisable. Voici l’algorithme que je te propose.

FonctionSuppressionDossier($Chemin)
Tu liste les dossiers
Pour chaque dossier tu appelle la fonction FonctionSupressionDossier(Chemin + \ + nom du dossier)
Tu listes les fichiers
Tu supprimes les fichiers
Tu supprime le dossier parent
EndFunc

Voilà en espérant avoir pu t'aider, si sa ne suffis pas je peux rouvir mes fichiers d'aide autoit

[guillaume]

oui c'est à peu près ce que j'ai essayé de faire, mais j'ai du faire une connerie car quand j'appelle la fonction, j'ai un problème de variable.
(je ne suis pas du tout développeur alors pas facile de tout assimiler )

[bloodwolff]

Code : Tout sélectionner

#include <File.au3>



SupprimerDossier("E:\ProfilsTSE\")




Func SupprimerDossier($Chemin)
    $Dirs = _FileListToArray($Chemin, "*", 2)
    If Not @error Then
        For $i = 1 To $Dirs[0]
            SupprimerDossier($Chemin & "\" & $Dirs[$i])
        Next
    EndIf
    $Files = _FileListToArray($Chemin, "*", 1)
    if Not @error Then
        For $i = 1 To $Files[0]
            FileDelete($Chemin & "\" & $Files[$i])
        Next
    EndIf
    DirRemove($Chemin)
EndFunc

[guillaume]

ah oui mais là par contre ça me supprime le dossier complètement.

je veux supprimer juste le contenu (fichiers + sous dossiers ), mais il faut que le dossier que je veux vider reste, c'est pour ça que j'essaie d'utiliser une boucle

[bloodwolff]

Code : Tout sélectionner

Func SupprimerDossier($Chemin)
    $Dirs = _FileListToArray($Chemin, "*", 2)
    If Not @error Then
        For $i = 1 To $Dirs[0]
            SupprimerDossier($Chemin & "\" & $Dirs[$i])
            [color=#FF0000]DirRemove($Chemin & "\" & $Dirs[$i])[/color]
        Next
    EndIf
    $Files = _FileListToArray($Chemin, "*", 1)
    if Not @error Then
        For $i = 1 To $Files[0]
            FileDelete($Chemin & "\" & $Files[$i])
        Next
    EndIf
    [strike]DirRemove($Chemin)[/strike]
EndFunc

Ce n'était pourtant pas très difficile

[guillaume]

j'étais en train de chercher en même temps, mais pas assez rapide.

Pas bien réveillé c'est dur le lundi !


merci

[mikell]

C'est pas redondant la récursivité ?

Code : Tout sélectionner

Func SupprimerContenu($Chemin)
    Local $file, $Files = _FileListToArray($Chemin, "*", 0)
    If Not @error Then
       For $i = 1 To $Files[0]
          $file = $Chemin & "\" & $Files[$i]
          If StringInStr(FileGetAttrib($file), "D") Then
              DirRemove($file, 1)
          Else
              FileDelete($file)
          EndIf
       Next
   EndIf
EndFunc

[bloodwolff]

Code : Tout sélectionner

$dirName = "E:\ProfilsTSE\"
DirRemove($dirName, 1)
DirCreate($dirName)

C'est pas redondant créer des fonctions personnels et utiliser des boucles ? Nan je rigole mais j'ai fais sa assez rapidement sans même regarder les param

Reste que je ne vois pas où est le problème de la récursivité, j'aurais besoin que tu m'éclaires

[mikell]

Pas un problème, juste inutile
Ta solution à 3 lignes étant bien évidemment la meilleure

[bloodwolff]

Ta solution à 3 lignes étant bien évidemment la meilleure

J'ai lancer les 3 fonctions sur un dossier identique avec un petit timer et voici le podium

► Afficher le texte163ms

Code : Tout sélectionner

Func SupprimerDossier($Chemin)
    $Dirs = _FileListToArray($Chemin, "*", 2)
    If Not @error Then
        For $i = 1 To $Dirs[0]
            SupprimerDossier($Chemin & "\" & $Dirs[$i])
            DirRemove($Chemin & "\" & $Dirs[$i])
        Next
    EndIf
    $Files = _FileListToArray($Chemin, "*", 1)
    if Not @error Then
        For $i = 1 To $Files[0]
            FileDelete($Chemin & "\" & $Files[$i])
        Next
    EndIf
EndFunc

► Afficher le texte271ms

Code : Tout sélectionner

$dirName = "E:\ProfilsTSE\"
DirRemove($dirName, 1)
DirCreate($dirName)

► Afficher le texte279ms

Code : Tout sélectionner

Func SupprimerContenu($Chemin)
    Local $file, $Files = _FileListToArray($Chemin, "*", 0)
    If Not @error Then
       For $i = 1 To $Files[0]
          $file = $Chemin & "\" & $Files[$i]
          If StringInStr(FileGetAttrib($file), "D") Then
              DirRemove($file, 1)
          Else
              FileDelete($file)
          EndIf
       Next
   EndIf
EndFunc

Donc à voir les résultats la récursivité s'en tire plutôt pas mal ! Sans rancune

[mikell]

Tout à fait surprenant qu'exécuter une ribambelle de _FileListToArray successivement fasse le meilleur temps

Sans rancune

Pourquoi diable ?
En mode compète [ON] j'aurais utilisé le timer AVANT de poster

[guillaume]

c'est nickel, merci beaucoup j'ai pu mettre le code dans mon script pour faire ce que je voulais.

[guillaume]

juste si je peux me permettre, question bête sans doute pour vous.

Mais si je veux faire des exclusions sur les suppressions j'utilise quoi ?

En gros je voudrais comparer la valeur de la variable $Dirs[$i] avec le nom d'un dossier que je listerais dans une autre variable.

si dans la boucle de ma fonction $Dirs[$i]= $nom_dossier (ex "administrateur" )

alors je n'applique pas la suppression, sinon je supprime

J'ai pensé à StringCompare en faisant quelques recherches mais je ne sais pas si c'est très adapté !

merci !

[guillaume]

j'ai fait comme ça,

peut être pas très propre mais ça fonctionne :

Code : Tout sélectionner

Local $result = StringCompare($Dirs[$i], $user1)

    If $result < 0 Then
        SupprimerDossier($Chemin &"\"& $Dirs[$i])
        DirRemove($Chemin & "\" & $Dirs[$i])

ElseIf $result > 0 Then
        SupprimerDossier($Chemin &"\"& $Dirs[$i])
        DirRemove($Chemin & "\" & $Dirs[$i])
Else
EndIf

[guillaume]

euh oui non mais plus simple même :

Code : Tout sélectionner

            Local $result = StringCompare($Dirs[$i], $user1)
            If $result = 0 Then

            Else
                SupprimerDossier($Chemin &"\"& $Dirs[$i])
                DirRemove($Chemin & "\" & $Dirs[$i])
            EndIf

j'apprends, j'apprends...

[guillaume]

Finalement je bloque complètement quand il s'agit de gérer plusieurs exclusions...

Je crois que je vais relancer le topic,

voici donc la fonction :

Code : Tout sélectionner

$user1 = "user1"
$user2 = "user2"
$user3 = "user3"


SupprimerDossier ("E:\utilisateur\")


Func SupprimerDossier($Chemin)
    
    $Dirs = _FileListToArray($Chemin, "*", 2)
    If Not @error Then
        
        For $i = 1 To $Dirs[0]

            Local $result = StringCompare($Dirs[$i], $user1)
            If $result = 0 Then
              Else
                SupprimerDossier($Chemin &"\"& $Dirs[$i])
                DirRemove($Chemin & "\" & $Dirs[$i])
            EndIf

        Next

    EndIf
    
    $Files = _FileListToArray($Chemin, "*", 1)
    if Not @error Then
       For $i = 1 To $Files[0]

            FileDelete($Chemin & "\"&  $Files[$i])
        Next
    EndIf

EndFunc

Si je n'ai qu'un utilisateur alors pas de soucis, mon dossier n'est pas supprimé

Mais quand j'en ai plusieurs, je n'arrive pas à trouver comment faire la comparaison sur les dossiers.


merci si vous pouvez m'aider

[bloodwolff]

Je le laisserais à l'Extérieur de la fonction, sinon tout les dossiers qui ont un nom identique à un nom d'utilisateur ne seront pas effacer même si ils sont situé plus profondément comme sur le bureau par exemple ("E:\utilisateur\user1\bureau\user2")

► Afficher le texte

Code : Tout sélectionner

#include <array.au3>
#include <file.au3>

dim $users[3] = ["user1", "user2", "user3"]


$Dirs = _FileListToArray("E:\utilisateur", "*", 2)
If Not @error Then
    For $i = 1 To $Dirs[0]
        If  _ArraySearch($users, $Dirs[$i], Default, Default, Default, 2) == -1 Then
            SupprimerDossier("E:\utilisateur\" & $Dirs[$i])
            DirRemove("E:\utilisateur\" & $Dirs[$i])
        EndIf
    Next
EndIf

Func SupprimerDossier($Chemin)

    $Dirs = _FileListToArray($Chemin, "*", 2)
    If Not @error Then
        For $i = 1 To $Dirs[0]
                SupprimerDossier($Chemin &"\"& $Dirs[$i])
                DirRemove($Chemin & "\" & $Dirs[$i])
        Next
    EndIf

    $Files = _FileListToArray($Chemin, "*", 1)
    if Not @error Then
       For $i = 1 To $Files[0]
            FileDelete($Chemin & "\"&  $Files[$i])
        Next
    EndIf
EndFunc

[guillaume]

merci, mais par contre j'ai :

$users[3] = ["user1", "user2", "user3"]
$users^ERROR

Error: Expected a "=" operator in assignment statement

[bloodwolff]

ah oui pour déclarer un tableau on doit impérativement mettre dim devant
Le code du message précédent à été corrigé