[R] Récupération de la source d'une page web

patator · #1

Bonjour,

Je souhaiterais récupérer les informations de cette page :
http://pserver-evasion.com/fr/scripts/b ... record.php

J'écrit donc cela :

► Afficher le texte

Dans la message Box il m'écrit rien du tout

Au final je souhaite traiter ces informations mais j'essayerais seul, les récupérer serais déjà pas mal.
Avant de venir vers vous j'avais déjà écrit un script mais bizarrement depuis peu il ne fonctionne plus.

#2

Très probablement ce serveur a un gros coup de fatigue
InetRead a un timeout intégré donc ça te retourne une erreur
Un test avec ce code montre que (actuellement) le résultat tombe péniblement après 40 à 50 sec minimum

► Afficher le texte

patator · #3

Re

Alors la moi je dis GG

Une pitite erreur ici :

Code : Tout sélectionner

$tr_rows = StringRegExp($_txt, '(?s)<tr>(.*?)</tr>', 3)

remplacé immédiatement par

Code : Tout sélectionner

$tr_rows = StringRegExp($txt, '(?s)<tr>(.*?)</tr>', 3)

et tout fonctionne parfaitement.

Au vu de la qualité de la réponse je vais me permetre d'aller plus loin.
Je souhaiterais savoir s'il y'a mieux a faire pour le même résultat que ce qui suis :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
#include <String.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>

GUICreate("ListView Add Array", 400, 300)
$List1 = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
_GUICtrlListView_AddColumn($List1, "Boss", 130)
_GUICtrlListView_AddColumn($List1, "Time", 90)

$url="http://pserver-evasion.com/fr/scripts/boss/bossrecord.php"

$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("GET", $url, 0)
$oHTTP.Send()
$txt = $oHTTP.Responsetext
$oHTTP = 0

$source = _StringBetween($txt,'<table cellspacing=1 cellpadding=2 border=1 style="border-style:hidden;">','</table>')
$tableau = StringRegExp($source[0], '<td>(.*?)</td>',3)

$indexboss=0
$ArchangeDeMedianNok=0
$MiniDragonNok=0
$DragonNok=0
$CrypticBulldozerDNok=0
$BeginnerMagnaDNok=0
$GoddessMagnaDNok=0
$MasterKibeDNok=0
$CryptictheLastNok=0

While 1

If $tableau[$indexboss]= "Archange de Median" And $ArchangeDeMedianNok=0 Then
    $boss1=$tableau[$indexboss]
    $H1 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS1 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time1=$H1&" : "&$MS1
    $ArchangeDeMedianNok=1
EndIf
If $tableau[$indexboss]= "Mini Dragon" And $MiniDragonNok=0 Then
    $boss2=$tableau[$indexboss]
    $H2 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS2 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time2=$H2&" : "&$MS2
    $MiniDragonNok=1
EndIf
If $tableau[$indexboss]= "Dragon" And $DragonNok=0 Then
    $boss3=$tableau[$indexboss]
    $H3 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS3 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time3=$H3&" : "&$MS3
    $DragonNok=1
EndIf
If $tableau[$indexboss]= "Cryptic Bulldozer D" And $CrypticBulldozerDNok=0 Then
    $boss4=$tableau[$indexboss]
    $H4 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS4 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time4=$H4&" : "&$MS4
    $CrypticBulldozerDNok=1
EndIf
If $tableau[$indexboss]= "Beginner Magna D" And $BeginnerMagnaDNok=0 Then
    $boss5=$tableau[$indexboss]
    $H5 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS5 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time5=$H5&" : "&$MS5
    $BeginnerMagnaDNok=1
EndIf
If $tableau[$indexboss]= "Goddess Magna D" And $GoddessMagnaDNok=0 Then
    $boss6=$tableau[$indexboss]
    $H6 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS6 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time6=$H6&" : "&$MS6
    $GoddessMagnaDNok=1
EndIf
If $tableau[$indexboss]= "Master Kibe D" And $MasterKibeDNok=0 Then
    $boss7=$tableau[$indexboss]
    $H7 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS7 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time7=$H7&" : "&$MS7
    $MasterKibeDNok=1
EndIf
If $tableau[$indexboss]= "Cryptic the Last" And $CryptictheLastNok=0 Then
    $boss8=$tableau[$indexboss]
    $H8 = StringLeft(StringRight($tableau[$indexboss+1], 12),2)
    $MS8 = StringLeft(StringRight($tableau[$indexboss+1], 9),2)&" : "&StringLeft(StringRight($tableau[$indexboss+1], 6),2)
    $time8=$H8&" : "&$MS8
    $CryptictheLastNok=1
EndIf
If $ArchangeDeMedianNok=1 And $MiniDragonNok=1 And $DragonNok=1 And $CrypticBulldozerDNok=1 And $BeginnerMagnaDNok=1 And $GoddessMagnaDNok=1 And $MasterKibeDNok=1 And $CryptictheLastNok=1 Then
    ExitLoop
EndIf
$indexboss=$indexboss+1
WEnd

Dim $TableauF[8][2] = [[$boss1,$time1],[$boss2,$time2],[$boss3,$time3],[$boss4,$time4],[$boss5,$time5],[$boss6,$time6],[$boss7,$time7],[$boss8,$time8]]
_ArraySort($TableauF, 0, 0)
_GUICtrlListView_AddArray($List1, $TableauF)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Sachant qu'en plus je dois modifier les différents $H suivant l'horloge 24H en y ajoutant le temps de repop qui est différent pour chaque boss.

S'il y a mieux je re-posterais avec cette ajout pour voir une nouvelle fois s'il y'a mieux a faire.

MERCI BCP.

#4

Si le but de la manoeuvre c'est de récupérer le nom de chaque boss avec l'horaire correspondant le plus récent, alors oui on peut optimiser
Là j'ai mis le html en bas du script pour le test, ake apparemment en journée il arrive que le serveur soit injoignable (faudra mettre une gestion d'erreur)

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
#include <String.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>

GUICreate("ListView Add Array", 400, 300)
$List1 = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
_GUICtrlListView_AddColumn($List1, "Boss", 130)
_GUICtrlListView_AddColumn($List1, "Time", 90)

#cs
$url="http://pserver-evasion.com/fr/scripts/boss/bossrecord.php"
$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("GET", $url, 0)
$oHTTP.Send()
$txt = $oHTTP.Responsetext
$oHTTP = 0
#ce

$txt = StringRegExpReplace(FileRead(@scriptfullpath), '(?s).+<mikell>(.+?)</mikell>.+', "$1")

$source = _StringBetween($txt,'<center>','</table>')
$tableau = StringRegExp($source[0], '<td>(.*?)</td>',3)

$boss_str = "|Archange de Median|Mini Dragon|Dragon|Cryptic Bulldozer D" & _
            "|Beginner Magna D|Goddess Magna D|Master Kibe D|Cryptic the Last|"
Dim $boss[8][2], $n = 0

For $i = 0 to UBound($tableau)-1
  If StringInStr($boss_str, "|" & $tableau[$i] & "|") Then
      $boss_str = StringReplace($boss_str, $tableau[$i], "")
      $boss[$n][0] = $tableau[$i]
      $boss[$n][1] = StringRegExpReplace($tableau[$i+1], '.+(\d\d):(\d\d):(\d\d).+', "$1 : $2 : $3")
      $n += 1
  EndIf
Next
 
_ArraySort($boss)
_GUICtrlListView_AddArray($List1, $boss)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
 
;======================================================================
#cs
<mikell>
<center>Boss records
          <table>
          <tr>
          <th>Who killed</th>
          <th>Boss Name</th>
          <th>Death Time</th>
          <th>Map ID</th>
          </tr><tr><td>Berlioz</td><td>Mini Dragon</td><td>2013-11-24 16:01:47.000</td><td>Cantabilian</td></tr><tr><td>Brania</td><td>Cryptic the Last</td><td>2013-11-24 15:51:51.000</td><td>Dimension Crack</td></tr><tr><td>.Hakuma</td><td>Archange de Median</td><td>2013-11-24 15:46:15.000</td><td>D-Water</td></tr><tr><td>Mugiwara</td><td>Dragon</td><td>2013-11-24 15:35:26.000</td><td>Deep Desert 1</td></tr><tr><td>Overs</td><td>Goddess Magna L</td><td>2013-11-24 14:39:50.000</td><td>Ruine Arcanes 2</td></tr><tr><td>Kalmanto</td><td>Fantasma Dragon</td><td>2013-11-24 14:28:04.000</td><td>Fantasma's Lair</td></tr><tr><td>M.G.K.</td><td>Master Kibe D</td><td>2013-11-24 14:06:08.000</td><td>Teodores</td></tr><tr><td>Brania</td><td>Cryptic Bulldozer D</td><td>2013-11-24 13:19:22.000</td><td>Dimension Crack</td></tr><tr><td>.Jerem</td><td>Corrupt Paros</td><td>2013-11-24 12:44:00.000</td><td>Paros Temple</td></tr><tr><td>YOSHIMURA</td><td>Beginner Magna D</td><td>2013-11-24 11:05:55.000</td><td>Ruine Hypnosis</td></tr><tr><td>Kraw</td><td>Goddess Magna D</td><td>2013-11-24 10:53:30.000</td><td>Ruine Hypnosis</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-24 10:06:19.000</td><td>Caelum Sacra</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-24 09:50:00.000</td><td>Caelum Sacra</td></tr><tr><td>GroSDef</td><td>Cryptic Bulldozer L</td><td>2013-11-24 09:11:48.000</td><td>Dimension Crack</td></tr><tr><td>-Azii-</td><td>Master Kibe L</td><td>2013-11-24 09:00:04.000</td><td>Pantanasa</td></tr><tr><td>olimac</td><td>Duplicated Rapioru</td><td>2013-11-24 08:48:05.000</td><td>Rapioru Maze</td></tr><tr><td>-Greyback-</td><td>Mini Dragon</td><td>2013-11-24 07:27:22.000</td><td>Cantabilian</td></tr><tr><td>-Azii-</td><td>Archange de Median</td><td>2013-11-24 06:36:52.000</td><td>D-Water</td></tr><tr><td>.Lova.</td><td>Beginner Magna L</td><td>2013-11-24 04:16:11.000</td><td>Ruines Arcanes 1</td></tr><tr><td>CourDevantMoi</td><td>Bebe Dragon</td><td>2013-11-24 04:05:23.000</td><td>Proelium</td></tr><tr><td>.Fox.</td><td>Cloron Dragon</td><td>2013-11-24 02:29:37.000</td><td>Cloron's Lair</td></tr><tr><td>_SetH_</td><td>Queen Vanus</td><td>2013-11-24 02:15:19.000</td><td>Queen Servus</td></tr><tr><td>schtroumpf</td><td>Dragon</td><td>2013-11-24 01:44:34.000</td><td>Deep Desert 1</td></tr><tr><td>vince</td><td>Cryptic Bulldozer D</td><td>2013-11-24 00:06:51.000</td><td>Dimension Crack</td></tr><tr><td>EtherSword</td><td>Corrupt Paros</td><td>2013-11-23 23:53:07.000</td><td>Paros Temple</td></tr><tr><td>-Greyback-</td><td>Mini Dragon</td><td>2013-11-23 23:24:24.000</td><td>Cantabilian</td></tr><tr><td>SanGo</td><td>Goddess Magna L</td><td>2013-11-23 22:20:29.000</td><td>Ruine Arcanes 2</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-23 20:01:48.000</td><td>Caelum Sacra</td></tr><tr><td>wXORXw</td><td>Cryptic the Last</td><td>2013-11-23 19:36:21.000</td><td>Dimension Crack</td></tr><tr><td>PaFy</td><td>Archange de Median</td><td>2013-11-23 19:30:34.000</td><td>D-Water</td></tr><tr><td>Deeky</td><td>Secreta</td><td>2013-11-23 18:18:12.000</td><td>Kanos Illium</td></tr></table></center>
</mikell>
#ce

Pour avoir le même résultat mais pour tous les boss et sans avoir besoin d'inscrire leurs noms il faut procéder un peu différemment

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
;#include <String.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>

#cs
$url="http://pserver-evasion.com/fr/scripts/boss/bossrecord.php"
$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("GET", $url, 0)
$oHTTP.Send()
$txt = $oHTTP.Responsetext
$oHTTP = 0
#ce

$txt = StringRegExpReplace(FileRead(@scriptfullpath), '(?s).+<mikell>(.+?)</mikell>.+', "$1")

$tableau = _Tab2Array($txt)
;_ArrayDisplay($tableau)

GUICreate("ListView Add Array", 400, 300)
$List1 = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
_GUICtrlListView_AddColumn($List1, "Boss", 130)
_GUICtrlListView_AddColumn($List1, "Time", 90)

Dim $result[UBound($tableau)][2], $boss_str = "|", $n = 0
For $i = 0 to UBound($tableau)-1
   If not StringInStr($boss_str, "|" & $tableau[$i][1] & "|") Then
        $boss_str &= $tableau[$i][1] & "|"
        $result[$n][0] = $tableau[$i][1]
        $result[$n][1] = StringRegExpReplace($tableau[$i][2], '.+(\d\d):(\d\d):(\d\d).+', "$1 : $2 : $3")
        $n += 1
   EndIf
Next
Redim $result[$n][2]
; _ArrayDisplay($result)

_ArraySort($result)
_GUICtrlListView_AddArray($List1, $result)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
 

;=================================================
Func _Tab2Array($_txt)
$tr_rows = StringRegExp($_txt, '<tr>(.*?)</tr>', 3)
If @error Then Exit Msgbox(0,"erreur", "database connection error")
$rows = UBound($tr_rows)
$cols = 1
Dim $array[$rows][$cols]
For $i = 0 to $rows-1
   $cells = StringRegExp($tr_rows[$i], '<td>(.*?)</td>', 3)
   If UBound($cells) > $cols Then 
       $cols = UBound($cells)
       Redim $array[$rows][$cols]
   EndIf
   For $j = 0 to UBound($cells)-1
       $array[$i][$j] = $cells[$j]
   Next
Next
Return $array
EndFunc


;=======================================================

#cs
<mikell>
<center>Boss records
          <table>
          <tr>
          <th>Who killed</th>
          <th>Boss Name</th>
          <th>Death Time</th>
          <th>Map ID</th>
          </tr><tr><td>Berlioz</td><td>Mini Dragon</td><td>2013-11-24 16:01:47.000</td><td>Cantabilian</td></tr><tr><td>Brania</td><td>Cryptic the Last</td><td>2013-11-24 15:51:51.000</td><td>Dimension Crack</td></tr><tr><td>.Hakuma</td><td>Archange de Median</td><td>2013-11-24 15:46:15.000</td><td>D-Water</td></tr><tr><td>Mugiwara</td><td>Dragon</td><td>2013-11-24 15:35:26.000</td><td>Deep Desert 1</td></tr><tr><td>Overs</td><td>Goddess Magna L</td><td>2013-11-24 14:39:50.000</td><td>Ruine Arcanes 2</td></tr><tr><td>Kalmanto</td><td>Fantasma Dragon</td><td>2013-11-24 14:28:04.000</td><td>Fantasma's Lair</td></tr><tr><td>M.G.K.</td><td>Master Kibe D</td><td>2013-11-24 14:06:08.000</td><td>Teodores</td></tr><tr><td>Brania</td><td>Cryptic Bulldozer D</td><td>2013-11-24 13:19:22.000</td><td>Dimension Crack</td></tr><tr><td>.Jerem</td><td>Corrupt Paros</td><td>2013-11-24 12:44:00.000</td><td>Paros Temple</td></tr><tr><td>YOSHIMURA</td><td>Beginner Magna D</td><td>2013-11-24 11:05:55.000</td><td>Ruine Hypnosis</td></tr><tr><td>Kraw</td><td>Goddess Magna D</td><td>2013-11-24 10:53:30.000</td><td>Ruine Hypnosis</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-24 10:06:19.000</td><td>Caelum Sacra</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-24 09:50:00.000</td><td>Caelum Sacra</td></tr><tr><td>GroSDef</td><td>Cryptic Bulldozer L</td><td>2013-11-24 09:11:48.000</td><td>Dimension Crack</td></tr><tr><td>-Azii-</td><td>Master Kibe L</td><td>2013-11-24 09:00:04.000</td><td>Pantanasa</td></tr><tr><td>olimac</td><td>Duplicated Rapioru</td><td>2013-11-24 08:48:05.000</td><td>Rapioru Maze</td></tr><tr><td>-Greyback-</td><td>Mini Dragon</td><td>2013-11-24 07:27:22.000</td><td>Cantabilian</td></tr><tr><td>-Azii-</td><td>Archange de Median</td><td>2013-11-24 06:36:52.000</td><td>D-Water</td></tr><tr><td>.Lova.</td><td>Beginner Magna L</td><td>2013-11-24 04:16:11.000</td><td>Ruines Arcanes 1</td></tr><tr><td>CourDevantMoi</td><td>Bebe Dragon</td><td>2013-11-24 04:05:23.000</td><td>Proelium</td></tr><tr><td>.Fox.</td><td>Cloron Dragon</td><td>2013-11-24 02:29:37.000</td><td>Cloron's Lair</td></tr><tr><td>_SetH_</td><td>Queen Vanus</td><td>2013-11-24 02:15:19.000</td><td>Queen Servus</td></tr><tr><td>schtroumpf</td><td>Dragon</td><td>2013-11-24 01:44:34.000</td><td>Deep Desert 1</td></tr><tr><td>vince</td><td>Cryptic Bulldozer D</td><td>2013-11-24 00:06:51.000</td><td>Dimension Crack</td></tr><tr><td>EtherSword</td><td>Corrupt Paros</td><td>2013-11-23 23:53:07.000</td><td>Paros Temple</td></tr><tr><td>-Greyback-</td><td>Mini Dragon</td><td>2013-11-23 23:24:24.000</td><td>Cantabilian</td></tr><tr><td>SanGo</td><td>Goddess Magna L</td><td>2013-11-23 22:20:29.000</td><td>Ruine Arcanes 2</td></tr><tr><td>Tiggy</td><td>Dios Exiel</td><td>2013-11-23 20:01:48.000</td><td>Caelum Sacra</td></tr><tr><td>wXORXw</td><td>Cryptic the Last</td><td>2013-11-23 19:36:21.000</td><td>Dimension Crack</td></tr><tr><td>PaFy</td><td>Archange de Median</td><td>2013-11-23 19:30:34.000</td><td>D-Water</td></tr><tr><td>Deeky</td><td>Secreta</td><td>2013-11-23 18:18:12.000</td><td>Kanos Illium</td></tr></table></center>
</mikell>
#ce

patator · #5

Re

Il y a eu un reboot serveur ce matin pour maintenance d'ou le petit problème rencontré.
Alors il est vrai que je n'ai pas expliqué le but de la manœuvre, je le fait tout de suite.

Le script a pour but de récupérer certain Boss et l'heure de leur décès

pour pouvoir par la suite ajouter a cette horaire leur temps de repop minimum pour m'alerter quand il sont susceptible d’être présent.
Tous les boss on un temps de repop différent de plus ou moins 1h donc je me focalise sur la repop minimum donc -1h.

Repop mini des boss :
Archange de Median : 8h
Dragon : 11h
Mini Dragon : 7h
Master Kibe D : 15h
Cryptic Bulldozer D : 11h
Beginner Magna D : 14h
Goddess Magna D : 14h
Cryptic the Last : 19h

J'aimerais une piste pour retravailler le

Code : Tout sélectionner

$boss[$n][1]

et y ajouter le repop tout en tenant compte de l'horloge de 24h.
Je séche, je me demande comment récupérer juste l'heure, y ajouter le repop mini suivant le boss tout en vérifiant qu'il n'ai pas supérieur a 23, y réacoller les minutes et les secondes puis classer le tout pour que le premier a pop sois en haut de la liste.
(Je ne pense pas avoir besoin de prendre la date en compte, se serai vraiment un manque de bol qu'un des boss n'ai pas été down depuis plusieurs jours)

Après rectification du code pour aller lire la source sur le net, bizarrement il me loupe un boss. En l'occurence le "Mini Dragon".

► Afficher le texte

Et encore un pitit merci ça mange pas de pain

#6

S'il te manque "Mini Dragon" c'est simplement qu'il est absent de la page que tu enregistres ^^

Et je te conseille de prendre la date en compte

Code : Tout sélectionner

#include <Date.au3>

$date = "2013-11-24 16:01:47.000"
$date = StringReplace(StringTrimRight($date, 4), "-", "/")
$new_date = _DateAdd('h', 8, $date)
MsgBox(4096, "", $new_date)

à intégrer comme ça

► Afficher le texte

patator · #7

Re

GG

Après petit bidouillage (intégration du repop) le script fait exactement ce que je veut mais il me loupe toujours le "Mini Dragon". L'orthographe est bonne et il est présent dans la liste a l'heure actuel, je ne comprend pas. Par contre il y a un vide comme première item avec ce code, je pense donc que le Mini Dragon devrai ce trouver la mais rien

.

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
#include <String.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <Date.au3>

GUICreate("ListView Add Array", 400, 300)
$List1 = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
_GUICtrlListView_AddColumn($List1, "Boss", 130)
_GUICtrlListView_AddColumn($List1, "Time", 130)

$url="http://pserver-evasion.com/fr/scripts/boss/bossrecord.php"
$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("GET", $url, 0)
$oHTTP.Send()
$txt = $oHTTP.Responsetext
$oHTTP = 0

$source = _StringBetween($txt,'<table','</table>')
$tableau = StringRegExp($source[0], '<td>(.*?)</td>',3)

$boss_str = "|Archange de Median|Mini Dragon|Dragon|Cryptic Bulldozer D" & _
            "|Beginner Magna D|Goddess Magna D|Master Kibe D|Cryptic the Last|"
Dim $boss[8][2], $n = 0

For $i = 0 to UBound($tableau)-1
  If StringInStr($boss_str, "|" & $tableau[$i] & "|") Then
    $boss_str = StringReplace($boss_str, $tableau[$i], "")
    $boss[$n][0] = $tableau[$i]
    $date = StringReplace(StringTrimRight($tableau[$i+1], 4), "-", "/")
    If  $tableau[$i]="Archange de Median" Then
        $new_date = _DateAdd('h', 8, $date)
    ElseIf  $tableau[$i]="Mini Dragon" Then
        $new_date = _DateAdd('h', 7, $date)
    ElseIf  $tableau[$i]="Dragon" Then
        $new_date = _DateAdd('h', 11, $date)
    ElseIf  $tableau[$i]="Cryptic Bulldozer D" Then
        $new_date = _DateAdd('h', 11, $date)
    ElseIf  $tableau[$i]="Beginner Magna D" Then
        $new_date = _DateAdd('h', 14, $date)
    ElseIf  $tableau[$i]="Goddess Magna D" Then
        $new_date = _DateAdd('h', 14, $date)
    ElseIf  $tableau[$i]="Master Kibe D" Then
        $new_date = _DateAdd('h', 15, $date)
    ElseIf  $tableau[$i]="Cryptic the Last" Then
        $new_date = _DateAdd('h', 19, $date)
    EndIf
    $boss[$n][1] = StringRegExpReplace($new_date, '.+(\d\d):(\d\d):(\d\d).+', "$1 : $2 : $3")
    $n += 1
  EndIf
Next

_ArraySort($boss, 0, 0, 0, 1)  ; plus récent
_GUICtrlListView_AddArray($List1, $boss)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

#8

Hum ... faut optimiser un peu plus

► Afficher le texte

NB :
Dans le code précédent fallait corriger ça :

Code : Tout sélectionner

  If StringInStr($boss_str, "|" & $tableau[$i] & "|") Then
    $boss_str = StringReplace($boss_str, "|" & $tableau[$i] & "|", "|")
;... etc

patator · #9

Re

C'est vraiment un truc de dingue. Je ne suis pas tous le code qui a été pondu mais je dis chapeau.
Et si tu veut bien prendre le temps de tout mais vraiment tout commenter sur le code je suis preneur.

Je met en résolu la parceque le soundplay lorsque l'heure fatidique arrive je v réussir a le casser tout seul, enfin espérons

Je te remercie énorment pour ce code qui fait 15millions de ligne de moin que mon ancien script a 2 francs six sous je t'assure.

Merci et heu merci

#10

Si tu comprends les tableaux tu vas comprendre le code sans problème
Voilà les commentaires

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
#include <String.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <Date.au3>

GUICreate("ListView Add Array", 400, 300)
$List1 = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()
_GUICtrlListView_AddColumn($List1, "Boss", 130)
_GUICtrlListView_AddColumn($List1, "Time", 130)

SplashTextOn ("", "Loading ...", 280, 55, -1, -1, 49)
$url="http://pserver-evasion.com/fr/scripts/boss/bossrecord.php"
$oHTTP = ObjCreate("Microsoft.XMLHTTP")
$oHTTP.Open("GET", $url, 0)
$oHTTP.Send()
$txt = $oHTTP.Responsetext
$oHTTP = 0
SplashOff()

$source = _StringBetween($txt,'<table','</table>')
$tableau = StringRegExp($source[0], '<td>(.*?)</td>',3)


; on crée une array 2D pour référencer le nom des boss (col 0) et leur temps de repop (col 1)

Dim $boss_ref[8][2] = [ _
        ["Archange de Median", 8], _ 
        ["Mini Dragon", 7], _ 
        ["Dragon", 11], _ 
        ["Cryptic Bulldozer D", 11], _ 
        ["Beginner Magna D", 14], _ 
        ["Goddess Magna D", 14],  _
        ["Master Kibe D", 15], _ 
        ["Cryptic the Last", 19]]

Dim $boss[8][2]     ; déclaration de l'array finale
$n = 0      ; initialisation de la variable qui va servir à construire cette array (nb de lignes)

For $i = 0 to UBound($tableau)-1 
    
; on utilise _ArraySearch pour rechercher l'élément $tableau[$i] dans l'array $boss_ref 
; pas de paramètre précisé => on recherche dans la col 0 (colonne des noms)

  $index = _ArraySearch($boss_ref, $tableau[$i])

; si la recherche retourne un index >= 0 c'est que $tableau[$i] est bien un nom de boss
; cet index (n° de ligne dans le tableau) $index est celui de ce boss dans l'array $boss_ref

  If not @error Then

    $boss[$n][0] = $tableau[$i]     ; soit aussi  = $boss_ref[$index][0]

; on met la date au format 'réglementaire' pour qu'elle soit comprise par _DateAdd
; YYYY/MM/DD HH:MM:SS

    $date = StringReplace(StringTrimRight($tableau[$i+1], 4), "-", "/")

; $boss_ref[n][0] = nom
; $boss_ref[n][1] = temps de repop

    $new_date = _DateAdd('h', $boss_ref[$index][1], $date)

; formatage de la date
    $boss[$n][1] = StringRegExpReplace($new_date, '(\d{4})/(\d\d)/(\d\d)\h+(\d\d):(\d\d):(\d\d)', "$3-$2-$1  $4:$5:$6")

; on a trouvé un boss, donc on incrémente $n (on rajoute une ligne dans $boss pour y mettre le prochain boss trouvé)
    $n += 1
  EndIf
Next

_ArraySort($boss, 0, 0, 0, 1)  ; plus récent
_GUICtrlListView_AddArray($List1, $boss)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

patator · #11

Alors oui vu comme ça le code s'éclaircis mais une petite précision sur

Code : Tout sélectionner

$new_date, '(\d{4})/(\d\d)/(\d\d)\h+(\d\d):(\d\d):(\d\d)', "$3-$2-$1  $4:$5:$6"

serais la bien venu. C'est bien la que l'on modifie l'horaire et que l'on y ajoute le temps de repop?

#12

Oy non

c'est _DateAdd() qui ajoute le temps
Voilà le détail pour les dates

Code : Tout sélectionner

#include <Date.au3>

$date = "2013-11-24 16:01:47.000"   ; exemple
$date1 = StringReplace(StringTrimRight($date, 4), "-", "/")
Msgbox(0,"", $date &@crlf& "après mise au format pour _DateAdd() :" &@crlf& $date1)

$date2 = _DateAdd('h', 8, $date1)
Msgbox(0,"", $date1 &@crlf& "après ajout de 8 heures :" &@crlf& $date2)

$date3 = StringRegExpReplace($date2, '(\d{4})/(\d\d)/(\d\d)\h+(\d\d):(\d\d):(\d\d)', "$3-$2-$1  $4:$5:$6")
Msgbox(0,"", $date2 &@crlf& "après mise au format perso :" &@crlf& $date3)

patator · #13

Re

Bon ben une fois de plus le script se casse les dents alors qu'il fonctionné très bien.

C'est moi ou j'ai pas de bol

#14

Un peu pas de bol, un peu plus le script

Bon c'est vrai j'aurais pu y penser

C'est juste que le script ne tient pas compte du fait que dans la page le même boss peut être mentionné plusieurs fois ce qui entraîne une erreur d'array
Donc une ligne à rajouter pour pallier cette éventualité

► Afficher le texte

patator · #15

Ha oui j'avais prévu moi hihi avec une incrémentation de variable dés que le bosse était trouvé.
J'aurai du souligner cela, je te remercie encore pour m'avoir lu,subit le code d'un débutant et aidé.

Franchement un grand grand merci.

#16

N'oubliez pas de passer votre post en résolu avec un petit [R] qui je n'en doute pas fera plaisir au chat

AutoIt Français

[R] Récupération de la source d'une page web

[R] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [R] Récupération de la source d'une page web

Re: [R] Récupération de la source d'une page web

Re: [R] Récupération de la source d'une page web

Re: [R] Récupération de la source d'une page web

Re: [R] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web

Re: [..] Récupération de la source d'une page web