[R] LDAP utilisateur + infos

[jcaspar]

B onjour à tous !

Je souhaiterais récupérer les informations de notre annuaire LDAP en fonction du nom d'utilisateur authentifié...

exemple l'utilisateur toto s'authentifie puis je souhaiterais récupérer son nom,prenom,service,téléphone
fax, adresse email


Je vous remercie pour vos conseils !

Jean-Marc

[jguinch]

Salut
C'est quoi comme annuaire LDAP ?
Si c'est de l'Active Directory, il y a un UDFsur le forum US.

[DimVar]

Bonsoir,


Je vous recommande les query LDAP :
http://social.technet.microsoft.com/wik ... lters.aspx



Cdlt.

[jguinch]

J'ai retrouvé ça dans mes scripts, ça pourra peut-être t'aider :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>

$infos = _userInfos()
_ArrayDisplay($infos)

Func _userInfos()
    Local $aInfos[11]
    Local $sGroups = ""

    Local $oADSystemInfo  = ObjCreate("ADSystemInfo")
    If $oADSystemInfo = 0 Then Return 0

    Local $objUser = ObjGet("LDAP://" & $oADSystemInfo.UserName)
    If NOT IsObj($objUser) Then Return 0

    $aInfos[0] = $objUser.givenName
    $aInfos[1] = $objUser.sn
    $aInfos[2] = $objUser.displayName
    $aInfos[3] = $objUser.distinguishedName
    $aInfos[4] = $objUser.description
    $aInfos[5] = $objUser.physicalDeliveryOfficeName
    $aInfos[6] = $objUser.telephoneNumber
    $aInfos[7] = $objUser.otherTelephone
    $aInfos[8] = $objUser.facsimileTelephoneNumber
    $aInfos[9] = $objUser.mail

    Local $objmemberOf  = $objUser.GetEx("memberOf")
    For $objGroup in $objmemberOf
        $sGroups &= @CRLF & $objGroup 
    Next
    $sGroups = StringRegExpReplace($sGroups, "\A\R", "")
    $aInfos[10] = $sGroups

    ; $aInfos[11] = __TranslateSID($objUser.objectSid)

    Return $aInfos
EndFunc