[..] Traitement de fichiers txt

[Pyrithe]

Bonjour,

Avant de me pencher plus en avant dans Autoit, j'aimerais qu'on puisse me valider (ou me déconseiller) son utilisation dans le cadre de mon besoin du moment. Je vous l'expose :

J'aimerais faire traiter, quotidiennement, une dizaine de fichiers txt afin de les "décortiquer".
Voilà la structure d'un fichier txt :

► Afficher le texte

En rouge les infos à récupérer

ENTETE
E,1,SUCR01,00,02012013,02012013,27.37,0.00,0.00,0.00,0.00,1.50,00228213,14,,1,,,,
PREPA
P,,
COMMENT
C,,
LIGNES
L,0,1,4578,2.000,0,11.94,0.00,0.00,0.00,0.00,0.00,,11.94,,1,,FLEFILPOUROT,,
L,1,1,6934,1.000,0,3.49,0.00,0.00,0.00,0.00,0.00,,3.49,,1,,MIXTAB,,

Tout ce qui est entre les virgules peux avoir une longueur différente.
Je ne peux donc me baser uniquement sur le numéro de la ligne à traiter par rapport à une section (première ligne après ENTETE, et toutes les lignes après LIGNES), et par le nombre de virgules avant ce que je veux récupérer...

Est ce que c'est possible?
Si oui, est ce que vous pouvez m'apporter quelques pistes de départ afin que je bosse là dessus?

D'avance, je remercie ceux qui m'aideront et qui me feront avancer dans cette découverte concrète d'AutoIt.

[mikell]

Prière de mettre le titre du sujet en conformité
http://www.autoitscript.fr/forum/viewto ... f=35&t=595

Sinon AutoIt va très bien pour ce genre de tâche si les fichiers ont exactement la même structure
(nombre de virgules dans chaque ligne constant d'un fichier à l'autre)

[Pyrithe]

Prière de mettre le titre du sujet en conformité
http://www.autoitscript.fr/forum/viewto ... f=35&t=595

Salut, désolé, j'ai effectivement zappé cette règle de ce forum.
C'est corrigé.

Sinon AutoIt va très bien pour ce genre de tâche si les fichiers ont exactement la même structure
(nombre de virgules dans chaque ligne constant d'un fichier à l'autre)

Bon, déjà ca va me permettre de bosser dessus alors.
Est ce que tu aurais une piste de départ, un tuto ou une approche d'un projet un peu similaire, histoire de voir comment on aborde ce genre de cas?
Ca m'aiderait à avancer dans la bonne direction tout de suite...

[jguinch]

Salut.
Il y a plusieurs façons de faire ce découpage, je te propose une méthode simple pour commencer :
- lecture du fichier dans un tableau avec _FileReadToArray()
- récupération de l'index des lignes "ENTETE" et "LIGNES" avec _ArraySearch()
- découpage des lignes avec StringSplit()
- pour les lignes qui suivent "LIGNES", faire une boucle pour découper chaque ligne

Petit exemple pour illustrer la procédure :

► Afficher le texteexemple

Code : Tout sélectionner

#include <Array.au3>
#include <File.au3>

Local $aData
$data = "data.txt"

; On lit tout le fichier d'un coup et on met le contenu dans un tableau
; Chaque ligne du tableau correspondra à une ligne du fichier
_FileReadToArray($data, $aData) 

; On récupère la position (index) de la ligne ENTETE dans le tableau
$iEntete = _ArraySearch($aData, "ENTETE")

; On récupère la ligne qui suit l'entete ($iEntete + 1)
$line = $aData[ $iEntete + 1]

; On découpe la ligne avec StringSplit en spécifiant le séparateur "," , le résultat sera un tableau.
$aSplit = StringSplit($line, ",")

; On affiche le résustat
$sDataEntete1 = $aSplit[3] ; Premier élément
$sDataEntete2 = $aSplit[5] ; Deuxième élément
MsgBox(0, "ENTETE", $sDataEntete1 & @LF & $sDataEntete2)



; On récupère l'index de la ligne LIGNES dans le tableau
$iLignes = _ArraySearch($aData, "LIGNES")

; On lit de la ligne qui suit LIGNES jusqu'à la fin et on fait la même chose que précédemment
For $i = $iLignes + 1 To $aData[0]
    $line = $aData[$i]
    $aSplit = StringSplit($line, ",")
    $sDataLignes1 = $aSplit[5]
    $sDataLignes2 = $aSplit[18]
    MsgBox(0, "LIGNES", $sDataLignes1 & @LF & $sDataLignes2)
Next

A toi ensuite de lire la doc et essayer de comprendre le fonctionnement de chaque fonction.

[Pyrithe]

Merci jguinch!!
Je vais de ce pas potasser les fonctions que tu me recommande, afin de comprendre leur fonctionnement, et essayer de faire ce que j'ai besoin autour de ton exemple de code.
Une journée de débuts sur AutoIt avec le soleil!!

[mikell]

Quand même jguinch pour un débutant en autoit tu aurais pu faire plus simple

Code : Tout sélectionner

#include <String.au3>

$file = FileRead("1.txt")

$entete = _StringBetween($file, "ENTETE", "PREPA")
$split = StringSplit($entete[0], ",")
$infos = $split[3] & " - " & $split[5] & @crlf & @crlf

$lignes = _StringBetween($file, "LIGNES", "")
$lines = StringRegExp($lignes[0], '(\S+)', 3)
For $i = 0 to UBound($lines)-1
   $split = StringSplit($lines[$i], ",")
   $infos &= $split[5] & " - " & $split[18] & @crlf
Next
Msgbox(64, "", $infos)
 

[jguinch]

@mikell : on peut toujours faire plus simple... StringRegExp() pour un débutant ???

[jchd]

Bah voui. Il serait plus simple et plus efficace de faire une seule regexp pour récupérer le tout.
Ca permettrait au passage de tester la motivation de l'impétrant.

[Sea]

Au pire il peux s'aider perso j'ai découvert ce tool tout bête et ça m'aide plutôt pas mal ^^

http://www.autoitscript.com/forum/topic ... tester-v2/

[mikell]

Non mais là arrêtez quoi
@jguinch, les expressions régulières c'est pas Satan, ici le regex est plus que basique et avec une petite lecture du fichier d'aide on comprend de suite
@jchd, c'est pas faux mais dans ce cas il faudrait vraiment que la motivation de l'impétrant soit 'stainless steel' pour résister au regexp à utiliser ^^
@Sea, n'en rajoute pas