[R] Enregistrer une capture d'écran haute qualité

[Niverton]

Bonsoir à tous ! Il se fait tard, et après avoir passé ma soirée penché sur ce problème, j'ai décidé de venir demander de l'aide.
Voilà, tout à l'heure m'est venue l'idée de créer un script qui, en faisant un clique droit dans son icône de barre des tâches, enregistre une capture d'écran dans des dossiers prédéfinis (ici le Bureau ou mon dossier Dropbox). Quelques recherches sur internet et dans la doc m'ont amené à la création de ce script, dont je suis assez fier :

► Afficher le texteCapture

Code : Tout sélectionner

;~ Enregistre automatiquement les captures d'écran

#include <ScreenCapture.au3>
#include <Constants.au3>
#include <GDIPlus.au3>

Opt("TrayAutoPause", 0)
Opt("TrayMenuMode", 1)

$trayDeskID = TrayCreateItem("Capture vers Bureau")
$trayDropID = TrayCreateItem("Capture vers Dropbox")
$traySep1 = TrayCreateItem("")
$trayExit = TrayCreateItem("Quitter")

while 1
    local $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $trayDeskID
            TrayItemSetState($trayDeskID, $TRAY_UNCHECKED)
            saveToDesk()
        Case $msg = $trayDropID
            TrayItemSetState($trayDropID, $TRAY_UNCHECKED)
            saveToDrop()
        Case $msg = $trayExit
            ExitLoop
    EndSelect
WEnd

Func saveToDesk()
    _GDIPlus_Startup()
    local $hBMP = _ScreenCapture_Capture()
;~  _ScreenCapture_SaveImage(@DesktopDir & getName(@DesktopDir), $image) ;Pas terrible !
    local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
    _GDIPlus_ImageSaveToFile($hBitmap, @DesktopDir & getName(@DesktopDir))

    _GDIPlus_BitmapDispose($hBitmap)
    _WinAPI_DeleteObject($hBMP)
    _GDIPlus_Shutdown()
EndFunc

Func saveToDrop()
    _GDIPlus_Startup()
    local $hBMP = _ScreenCapture_Capture()
;~  _ScreenCapture_SaveImage(@UserProfileDir & "\Dropbox\Public" & getName(@UserProfileDir & "\Dropbox\public"), $image) ;Pas terrible !
    local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
    _GDIPlus_ImageSaveToFile($hBitmap, @UserProfileDir & "\Dropbox\Public" & getName(@UserProfileDir & "\Dropbox\public"))

    _GDIPlus_BitmapDispose($hBitmap)
    _WinAPI_DeleteObject($hBMP)
    _GDIPlus_Shutdown()
EndFunc

Func getName($path)
    local $id = 0
    local $name =  "\Capture" & $id & ".jpg"
    While FileExists($path & $name)
        $id = $id + 1
        local $name = "\Capture" & $id & ".jpg"
    WEnd
    Return $name
EndFunc

En lisant ce script vous pouvez voir que j'ai essayé deux méthodes d'enregistrement de la capture (directement avec _ScreenCapture_Capture, ou en passant par _GDIPlus_ImageSaveToFile), mais voilà qui nous amène à mon problème : la qualité de ces captures n'est vraiment pas terrible ! Il semblerait que la qualité baisse fortement à l'enregistrement, puisqu'en essayant le script d'exemple de la fonction _GDIPlus_ImageSaveToFile, la capture d'écran garde sa résolution à l'affichage.
Voilà, vous savez tout de mon problème ! Je n'ai pas réussi à trouver de solution sur internet, et je trouve bien vexant de ne pas réussir à sauvegarder une capture d'écran correctement, alors que Paint le fait très bien...
C'est sur ces dernières paroles que je vous quitte, bonne nuit, en espérant qu'elle me porte conseil, et en attendant l'aide de l'un d'entre vous.

[jguinch]

Tu peux éventuellement regarder du côté de _ScreenCapture_SetJPGQuality, mais j'y crois pas trop...

[mikell]

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hBitmap1, $hImage1, $hGraphics
    _GDIPlus_Startup()

    $hBitmap1 = _ScreenCapture_Capture("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
    $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage1)
    DllCall($ghGDIPDll, "int", "GdipSetInterpolationMode", "hwnd", $hGraphics, "int", "7")
            ;InterpolationModeHighQualityBicubic = 7
    DllCall($ghGDIPDll, "int", "GdipSetSmoothingMode", "hwnd", $hGraphics, "int", 2)
            ;SmoothingModeHighQuality = 2

    $CLSID = _GDIPlus_EncodersGetCLSID("JPG")
    $tParams = _GDIPlus_ParamInit(1)
    $tData = DllStructCreate("int quality")
    DllStructSetData($tData, "Quality", 100)  ; 100 = maxi
    $pData = DllStructGetPtr($tData)
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData)
    $pParams = DllStructGetPtr($tParams)

   _GDIPlus_ImageSaveToFileEx($hImage1, @desktopDir & "\GDIPlus_Image.jpg", $CLSID, $pParams)
    _GDIPlus_ImageDispose($hImage1)
    _WinAPI_DeleteObject($hBitmap1)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Main
 

La qualité augmente mais la taille des fichiers aussi ^^

[Niverton]

Merci pour vos réponses !

Tu peux éventuellement regarder du côté de _ScreenCapture_SetJPGQuality, mais j'y crois pas trop...

J'avais tenté de manière désespérée hier, malheureusement il n'y a pas de changement, d'après la doc la qualité par défaut est la qualité maximum :/

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
&nbsp; &nbsp; Local $hBitmap1, $hImage1, $hGraphics
&nbsp; &nbsp; _GDIPlus_Startup()

&nbsp; &nbsp; $hBitmap1 = _ScreenCapture_Capture("")
&nbsp; &nbsp; $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)
&nbsp; &nbsp; $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage1)
&nbsp; &nbsp; DllCall($ghGDIPDll, "int", "GdipSetInterpolationMode", "hwnd", $hGraphics, "int", "7")
&nbsp; &nbsp; &nbsp; &nbsp; &nbsp; &nbsp; ;InterpolationModeHighQualityBicubic = 7
&nbsp; &nbsp; DllCall($ghGDIPDll, "int", "GdipSetSmoothingMode", "hwnd", $hGraphics, "int", 2)
&nbsp; &nbsp; &nbsp; &nbsp; &nbsp; &nbsp; ;SmoothingModeHighQuality = 2

&nbsp; &nbsp; $CLSID = _GDIPlus_EncodersGetCLSID("JPG")
&nbsp; &nbsp; $tParams = _GDIPlus_ParamInit(1)
&nbsp; &nbsp; $tData = DllStructCreate("int quality")
&nbsp; &nbsp; DllStructSetData($tData, "Quality", 100) &nbsp;; 100 = maxi
&nbsp; &nbsp; $pData = DllStructGetPtr($tData)
&nbsp; &nbsp; _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData)
&nbsp; &nbsp; $pParams = DllStructGetPtr($tParams)

&nbsp; &nbsp;_GDIPlus_ImageSaveToFileEx($hImage1, @desktopDir & "\GDIPlus_Image.jpg", $CLSID, $pParams)
&nbsp; &nbsp; _GDIPlus_ImageDispose($hImage1)
&nbsp; &nbsp; _WinAPI_DeleteObject($hBitmap1)
&nbsp; &nbsp; _GDIPlus_Shutdown()
EndFunc &nbsp; ;==>_Main
&nbsp;

La qualité augmente mais la taille des fichiers aussi ^^

J'ai tenté ton scrip, et j'ai comparé deux images prises avec ton script et le mien, et la différence n'est pas flagrante :/
On obtient la même qualité visiblement, ce qui change, c'est un ko de plus sur la capture de ton script... Cependant, je suis maintenant persuadé que la solution se cache dans le format d'enregistrement, ce qui nous amène à un autre problème: je n'y connais absolument rien en format ! En attendant votre aide, je vais plancher sur un moyen de récupérer le lien public de l'image que j'enregistre sur Dropbox automatiquement.

[TT22]

Sinon tu peux enregistrer l'image au format BMP et donc sans perte de qualité :

► Afficher le texte

Code : Tout sélectionner

#include <ScreenCapture.au3>
_ScreenCapture_Capture(@ScriptDir&"\capture.bmp")

[Niverton]

Sinon tu peux enregistrer l'image au format BMP et donc sans perte de qualité :

► Afficher le texte

Code : Tout sélectionner

#include <ScreenCapture.au3>
_ScreenCapture_Capture(@ScriptDir&"\capture.bmp")

Wow, effectivement ! Je ne sais pas pourquoi je n'ai pas déjà essayé ^^'
Merci beaucoup, on obtient une qualité bien meilleure qu'avec les autres méthodes je trouve. Problème résolu

EDIT: J'ai encore un peu travaillé mon script, et n'ayant pas pu trouver de fonction pour masquer le curseur, sans utiliser de pratiques barbares (changer le curseur pour un curseur transparent, puis remettre l'ancien), le script va cacher la souris dans un coin tranquille, attendre un peu que le menu contextuel disparaisse, et prendre la capture.

[julie]

salut j'ai la solution pour ton soucis de souris a masquer

Opt("MouseCoordMode", 2); en entete

puis la ou ca te chante

_SetCursorState(0) ; 1 on peut voir la souris 0 on ne la voit plus

[matwachich]

RTFM

Code : Tout sélectionner

_ScreenCapture_Capture([$sFileName = "" [, $iLeft = 0 [, $iTop = 0 [, $iRight = -1 [, $iBottom = -1 [, [b][u]$fCursor = True[/u][/b]]]]]]])

[Niverton]

RTFM

Code : Tout sélectionner

_ScreenCapture_Capture([$sFileName = "" [, $iLeft = 0 [, $iTop = 0 [, $iRight = -1 [, $iBottom = -1 [, [b][u]$fCursor = True[/u][/b]]]]]]])

Ahah, je l'avais pas vu celle là x)
Merci, c'est plus propre comme ça