[..] Installation d'imprimante suivant la passerelle

[Glouton]

Bonjour, ayant des imprimantes sur de mutiples sites sur toute une region, je travaille sur la possibilité d'installer une imprimante lors de la premiere connection via l'AD...
Le but est des que tu viens tu te connectes et tu choisis entre plusieurs imprimantes, une a installer...
Bref en contactant la passerelle , offrir une liste d'imprimante qui ont la meme passerelle...

peut etre en passant par le REg...

Est ce possible ?

Merci

[jl56]

Bonjour,

Oui c'est très possible sans passer par le reg
pour paramétrer l'imprimante
Dans un de mes scripts j'utilise pour cela rundll32 printui.dll,PrintUIEntry ......

exécute cette commande et tu aura toute la syntaxe
rundll32 printui.dll,PrintUIEntry /?

Tu peux connaitre la passerelle et utiliser une liste d'imprimante que tu a créer

A+

JL56

[jguinch]

Salut.
Pour récupérer la passerelle par défaut, tu peux regarder du côté de l'UDF Configuration réseau, avec les fonctions _GetNetworkAdapterList et _GetNetworkAdapterInfos.
Pour l'ajout des imprimantes, _AddWindowsPrinterConnection pourrait t'aider (tout comme la proposition de jl56)

De quelle manière penses-tu récupérer la liste des imprimantes ? Fichiers texte, AD ... ? Peux-tu alimenter un fichier de référence ?

[Glouton]

Salut.
Pour récupérer la passerelle par défaut, tu peux regarder du côté de l'UDF Configuration réseau, avec les fonctions _GetNetworkAdapterList et _GetNetworkAdapterInfos.
Pour l'ajout des imprimantes, _AddWindowsPrinterConnection pourrait t'aider (tout comme la proposition de jl56)

De quelle manière penses-tu récupérer la liste des imprimantes ? Fichiers texte, AD ... ? Peux-tu alimenter un fichier de référence ?

Merci , en fait suivant la passerelle, je veux proposer un des serveurs d'impression. J'ai aussi des imprimantes en Ip mais je pense que cela va etre plus difficile. Les imprimantes ne sont pas declarée dans l'AD.
J'avais pensez choper le defaultgetewaydhcp dans le reg et le comparer aux serveurs...

Apres sur l'install de l'imprimante serveur , je pense avoir des problemes de spooleur
rundll32 printui.dll,PrintUIEntry installe l'imp mais pas de connection ...
_AddWindowsPrinterconnection ,je m'y attele de suite
Merci
pour les infos
et bon travail cerebral

[jl56]

Bonjour,

Pour créer un port IP j'utilise un vbs (prnport.vbs) déjà présent sur le système

je lance ce vbs comme ceci exemple.

Code : Tout sélectionner

Run("cscript "&@SystemDir&"\prnport.vbs -a -r "&$nomport&" -h "&$adresseipport&" -o raw -n "&$numeroduport&$option,"",@SW_HIDE)

rechercher sur votre system et editez le prnport.VBS pour avoir des précisions sur la saint axe ( priez pour nous )

A+ JL56

[jguinch]

Les imprimantes ne sont pas declarée dans l'AD.

D'où ma question : de quelle manière penses-tu récupérer la liste des imprimantes ?

[Glouton]

Les imprimantes ne sont pas declarée dans l'AD.

D'où ma question : de quelle manière penses-tu récupérer la liste des imprimantes ?

oiups dans le REG du serveur :

Code : Tout sélectionner

$val = RegEnumVal ("\\serveur\HKCU\Software\Microsoft\Windows NT\CurrentVersion\PrinterPorts", $i )

je peux meme le lister ...

[jguinch]

J'ai quand même un doute sur \\serveur\HKCU... soit. De plus, les utilisateurs auront-ils les droits suffisants pour accéder au registre du serveur à distance ?
Sinon autre solution, requête WMI...

Comment le script sur les postes clients saura t-il quel serveur d'impression il doit interroger pour avoir la liste des imprimantes ?

Désolé pour toutes ces questions, mais ça permettra d'avancer un peu

[Maurice]

Attention, je crois me souvenir que cette clé n'est pas purgée systématiquement quand les imprimantes sont désinstallées. Tu risques de te retrouver avec une liste non conforme à la réalité si tu ne pratique pas toi même cette purge.

Bon courage

[Glouton]

J'ai quand même un doute sur \\serveur\HKCU... soit. De plus, les utilisateurs auront-ils les droits suffisants pour accéder au registre du serveur à distance ?
Sinon autre solution, requête WMI...

Comment le script sur les postes clients saura t-il quel serveur d'impression il doit interroger pour avoir la liste des imprimantes ?

Désolé pour toutes ces questions, mais ça permettra d'avancer un peu

d'ou interroger la passerelle ou le nommage machine...

Mon but c'est de proposer UNE installation d'imprimante lors du premier logging...
style Mdp logging , first use => script imp et outlook ...
Apres si telle passerelle ou pas , proposition imp

Bref j'ai recuperer un bout de script et fait des assais avec la base de registre mais cela ne s'installe pas tres bien, bref j'ai l'install mais pas la connection... pourtan telle existe...

[Glouton]

Attention, je crois me souvenir que cette clé n'est pas purgée systématiquement quand les imprimantes sont désinstallées. Tu risques de te retrouver avec une liste non conforme à la réalité si tu ne pratique pas toi même cette purge.

Bon courage

Oui ce n'est pas top, j'ai des imprimantes fantomes

faut que trouve autre chose

[jguinch]

Salut.
Pour le listage, voici un exemple de requête WMI qui pourrait t'aider :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>

Global $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")


Local $server = @ComputerName  ; A remplacer par ton/tes serveur(s)
$list = _EnumPrinters($server)
_ArrayDisplay($list, "Imprimantes disponible sur " & $server, -1, 0, "", "", "RowID|DeviceID|DriverName|Name|ServerName|Shared|ShareName|PortName|PortIP")



Func _EnumPrinters($strComputer = @ComputerName)
    Local $aResult[1][8]

    Local $wbemFlagReturnImmediately = 0x10
    Local $wbemFlagForwardOnly = 0x20
    
    Local $objWMIService, $colPrinters, $objPrinter
    
    $objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
    $colPrinters = $objWMIService.ExecQuery ("Select * from Win32_Printer", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If NOT IsObj($colPrinters) Then Return 0
   
    $i = 0
    For $objPrinter in $colPrinters
        $i += 1
        Redim $aResult[$i][8]

        $aResult[$i - 1][0] = $objPrinter.DeviceID
        $aResult[$i - 1][1] = $objPrinter.DriverName
        $aResult[$i - 1][2] = $objPrinter.Name
        $aResult[$i - 1][3] = $objPrinter.ServerName
        $aResult[$i - 1][4] = $objPrinter.Shared
        $aResult[$i - 1][5] = $objPrinter.ShareName
        $aResult[$i - 1][6] = $objPrinter.PortName
        $aResult[$i - 1][7] = _GetPrinterPortIP($objPrinter.PortName, $strComputer)

    Next
    Return $aResult
EndFunc


Func _GetPrinterPortIP($sPortName, $strComputer)
    Local $wbemFlagReturnImmediately = 0x10
    Local $wbemFlagForwardOnly = 0x20
    
    Local $objWMIService, $colPort, $colPort

    $objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
    $colPort = $objWMIService.ExecQuery ("select * from Win32_TCPIPPrinterPort Where Name = '" & $sPortName & "'", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If NOT IsObj($colPort) Then Return 0
    
    
    For $objPort in $colPort
        Return $objPort.HostAddress
    Next
    
    Return ""
    
EndFunc



Func _ErrFunc($oError)
    Local $txt = "Error number : " & $oError.number & @CRLF & _
            "WinDescription:" & @TAB & $oError.windescription & @CRLF & _
            "Description : " & @TAB & $oError.description & @CRLF & _
            "Source : " & @TAB & $oError.source
    MsgBox(16, "Error", $txt)
EndFunc   ;==>_ErrFunc


Func _StringUnSplit($aVal, $sSep = ";")
    If NOT IsArray($aVal) Then Return 0
    Local $sReturn = ""
    For $i = 0 To UBound($aVal) - 1
        If $i = 0 Then
            $sReturn = $aVal[$i]
        Else
            $sReturn &= $sSep & $aVal[$i]
        EndIf
    Next
    Return $sReturn
EndFunc