[R] Obtenir les items supérieurs d'une TreeView

[TT22]

Salut à tous,

Voici mon problème, j'ai une TreeView qui est générée en fonction d'un fichier (cela ne me pose aucun problème).
Et j'aimerais que lorsqu'un item de cette TreeView est sélectionné récupérer tous les items supérieurs dans arborescence de façon à obtenir une chaine de caractères contenant tous les items permettant d'accéder à celui sélectionné.

Par exemple, avec cette TreeView,

trv.png (2.81 Kio) Vu 885 fois

obtenir cette chaine de caractères : "First/Sub2/Sub-Sub3/Last1"

Voilà, merci d'avance à ceux qui m'aideront.

[jguinch]

Salut TT22.
Tu as regardé du côté de ControlTreeView ?

► Afficher le texteControlTreeView

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

Global $gui = GUICreate("ControlTreeview test", 212, 212)
$bt = GUICtrlCreateButton("test", 10, 180, 120, 20)
Global $treeview = GUICtrlCreateTreeView(6, 6, 200, 160, -1, $WS_EX_CLIENTEDGE)
Global $h_tree = ControlGetHandle($gui, "", $treeview)

Global $root = GUICtrlCreateTreeViewItem("Root", $treeview)
GUICtrlCreateTreeViewItem("Item 1", $root)
GUICtrlCreateTreeViewItem("Item 2", $root)
GUICtrlCreateTreeViewItem("Item 3", $root)
Global $item4 = GUICtrlCreateTreeViewItem("Item 4", $root)
GUICtrlCreateTreeViewItem("Item 41", $item4)
GUICtrlCreateTreeViewItem("Item 42", $item4)
GUICtrlCreateTreeViewItem("Item 5", $root)


GUISetState(@SW_SHOW)


While 1
    Global $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $bt 
            _Check()
    EndSelect
WEnd


Func _Check()
    $path = StringReplace ( ControlTreeView ( $gui, "", $treeview, "GetSelected") , "|", "/")
    MsgBox(0, "", $path)
EndFunc

[mikell]

Hum TwentyToo tu fournis pas beaucoup d'infos sur la construction du treeview
Je te propose ça (un peu rustique, à adapter évidemment à tes besoins)
Quand tu sélectionnes un item, ça retourne son chemin

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
;#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>

Local $gui = GUICreate("ControlTreeview test", 212, 212)
Local $hTreeView = GUICtrlCreateTreeView(6, 6, 200, 160, -1, $WS_EX_CLIENTEDGE)

Local $root = GUICtrlCreateTreeViewItem("Root", $hTreeView)
GUICtrlCreateTreeViewItem("Item 1", $root)
GUICtrlCreateTreeViewItem("Item 2", $root)
GUICtrlCreateTreeViewItem("Item 3", $root)
Local $item4 = GUICtrlCreateTreeViewItem("Item 4", $root)
GUICtrlCreateTreeViewItem("Item 41", $item4)
GUICtrlCreateTreeViewItem("Item 42", $item4)
GUICtrlCreateTreeViewItem("Item 5", $root)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While 1
    Local $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
WEnd

;=============================================
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview
    $hWndTreeview = $hTreeView
    If Not IsHWnd($hTreeView) Then $hWndTreeview = GUICtrlGetHandle($hTreeView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndTreeview
            Switch $iCode
                Case $TVN_SELCHANGEDA, $TVN_SELCHANGEDW 
                    $path = _GUICtrlTreeView_GetTree($hWndTreeview)
                    If $path <> "" Then Msgbox(0,"", $path)
                    Return 0 
           EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 

[TT22]

Merci à vous deux !
Vos deux solutions fonctionnent, mais je vais prendre celle de jguinchard car La solution la plus simple est toujours la meilleure .

[mikell]

Absolument
Si j'avais lu correctement le message de jguinchard ça m'aurait économisé du post