[R] Identification web

[DimVar]

Bonjour,

Suite au topic suivant, je souhaite tester la disponibilité d'un site web, et l'identification d'un user/mdp.
Apres quelques recherches sur le net, je dois connaitre le type de serveur web ainsi que sa base associée, ex : (apache + mysql), pour determiner les fonctions que je vais devoir utiliser.
1) Est ce que s'assurer que le serveur est "up" et faire un test de login à la base, signifie à coup sur que une identification est possible depuis un navigateur ?
2) En imaginant que je ne connaisse pas le type de serveur ou de base qu'il y a derriere une url, comment investiguer sur ce point ? Sont ce des informations publique que l'on peut recuperer dans le code source de la page d'index du site par ex ?

Ensuite viendront des questions sur les fonctions à utiliser...

D'avance merci.

[FireFox]

Tu peux tout savoir depuis le header :

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3> ;juste pour afficher les résultats

TCPStartup()

Global $aRespHeader = StringSplit(_INetGetHeader("http://www.autoitscript.fr/"), @CR)

_ArrayDisplay($aRespHeader)

TCPShutdown()

Func _INetGetHeader($sURL) ;By FireFox aka d3monCorp (some of it from _INetGetPostSource by GTASpider)
    Local $iSocket, $sHeader, $sRecv, $iIP, $sHost, $aRegExp, $sHttp1, $iErr, $iSend, $sRecvHeader

    If $sURL = "" Then Return SetError(1, 0, 0)

    If StringLeft($sURL, 7) <> "http://" And StringLeft($sURL, 8) <> "https://" Then $sURL = "http://" & $sURL
    If StringRight($sURL, 1) <> "/" Then $sURL &= "/"

    $aRegExp = StringRegExp($sURL, "http?://(.*?)/", 3)
    If @error Then Return SetError(2, 0, 0)

    $sHost = $aRegExp[0]
    If $sHost = "" Then Return SetError(3, 0, 0)

    $sHttp1 = StringTrimLeft($sURL, StringInStr($sURL, "/", -1, 3) - 1)
    If $sHttp1 = "" Then Return SetError(3, 0, 0)

    $sHeader = "GET " & $sHttp1 & " HTTP/1.1" & @CRLF & _
            "Host: " & $sHost & @CRLF & _
            "Connection: close" & @CRLF & _
            "User-Agent: AutoIt v3" & @CRLF & @CRLF

    TCPStartup() ;If not already done
    $iIP = TCPNameToIP($sHost)

    If $iIP = "" Or StringInStr($iIP, ".") = 0 Then Return SetError(4, 0, 0)
    $iSocket = TCPConnect($iIP, 80)
    If @error Or $iSocket < 0 Then Return SetError(5, 0, 0)

    $iSend = TCPSend($iSocket, $sHeader)
    If @error Or $iSend < 1 Then Return SetError(6, 0, 0)

    While 1
        $sRecv = TCPRecv($iSocket, 1024)
        $iErr = @error
        If $sRecv <> "" Then
            $sRecvHeader &= $sRecv

            If StringInStr($sRecv, @CRLF & @CRLF) Then
                $sRecvHeader = StringLeft($sRecvHeader, StringInStr($sRecvHeader, @CRLF & @CRLF) - 1)
                ExitLoop
            EndIf
        EndIf
        If $iErr Then Return SetError(7, 0, 0)
    WEnd

    TCPCloseSocket($iSocket)

    Return $sRecvHeader
EndFunc   ;==>_INetGetHeader
 

Cdlt, FireFox.

[DimVar]

Merci Demon.

Quelques interrogations :

1) lorsque je tente la meme url chez http://tools.apocalx.com/entete-http/?q ... tscript.fr il me retourne :
"X-Powered-By: PHP/5.2.17 " que je ne retrouve pas dans le tableau généré par ton script. Pourquoi ? Cette info peut m'etre utile dans l'investigation.

2) J'ai decomposé ta fonction, mis des msgbox un peu partout (apres les seterror) pour voir ce que renvoyait les commandes utilisés, et j'ai du mal à cerner la variable $sHeader que tu rempli avec des @crlf. Vu que tu envoi le contenu de cette variable avec "Tcpsend" ensuite, j'imagine que le serveur à l'autre bout est capable de l'interpreter. S'agit il de commandes communes à tous les serveurs web ? Est ce uniquement reservé au type de serveur qui nous occupe (apache) ?



Merci de ton retour.

Cdlt.

[FireFox]

1) lorsque je tente la meme url chez http://tools.apocalx.com/entete-http/?q ... tscript.fr il me retourne :
"X-Powered-By: PHP/5.2.17 " que je ne retrouve pas dans le tableau généré par ton script. Pourquoi ? Cette info peut m'etre utile dans l'investigation.

Car l'url que j'ai spécifiée est une exception, elle renvoie une erreur 403 car il n'accepte pas le user-agent que je lui envoie.

Code : Tout sélectionner

;change la ligne user agent par celle-ci (correspond à la dernière version de Chrome)
            "User-Agent: Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.4 (KHTML, like Gecko) Chrome/22.0.1229.94 Safari/537.4" & @CRLF & @CRLF
 

Vu que tu envoi le contenu de cette variable avec "Tcpsend" ensuite, j'imagine que le serveur à l'autre bout est capable de l'interpreter. S'agit il de commandes communes à tous les serveurs web ? Est ce uniquement reservé au type de serveur qui nous occupe (apache) ?

Si, le serveur comprend la requête, c'est une requête GET comme quand tu charges cette page.

Il faut que tu te documentes sur les headers pour savoir comment ça marche et répondre à ton problème.

Cdlt, FireFox.

[DimVar]

Ok, je me renseigne sur ces points.
Quid de la base d'un site ? Peut on connaitre le type de base derrière le serveur ?


Merci.

[FireFox]

Quid de la base d'un site ? Peut on connaitre le type de base derrière le serveur ?

Tout dépend du type de serveurs, certains renvoient plus d'informations que d'autres donc selon les cas tu n'auras pas toutes les infos dont tu as besoin.

Cdlt, FireFox.

[DimVar]

Comment se fait il que Demon soit remplacé par Firefox ?

[Tlem]

Parce que c'est la même personne et que Demon n'est plus ...