[..] Insérer une fenêtre "enregistrer sous"

[mikell]

BON ça m'agace, je m'en sors pas de cette foutue syntaxe
J'aime pas les guillemets
Essaye de remplacer toute la 2ème partie de la fonction (décompression et install) par ça

Code : Tout sélectionner

If @OSArch = "x86" Then $path7z = @ScriptDir & "\7-Zip\x86\7-zip32.dll"
If @OSArch = "x64" Then $path7z = @ScriptDir & "\7-Zip\x64\7-zip64.dll"
$outdir = @scriptdir & "\CD-WEB2"
Local $buffer = DllStructCreate("char[32768]")
DllCall($path7z, 'int', 'SevenZip', _
    'hwnd', 0, _
    'str', 'e "' & $chemin_complet & '" -aoa -o"' & $outdir & '"', _
    'ptr', DllStructGetPtr($buffer), _
    'int', DllStructGetSize($buffer))
Sleep(500)
ShellExecute ($outdir  & "\Install.exe")

[greenkev]

C'est en cours de téléchargement mikell, je te dis ce qu'il en est .

En tout cas, merci pour ton aide et désolé de te faire galérer :s.

[greenkev]

Alors je viens de tester ce que tu m'as donné, malheureusement la décompression ne fonctionne pas .

Concernant le lancement du fichier "Install.exe", ça ne pointe pas au bon endroit (au lieu que ça pointe sur le chemin de destination choisi au début, ça pointe dans le répertoire que j'utilise en ce moment).

J'ai fais une capture d'écran du message d'erreur que ça me donne concernant le lancement de "Install.exe" ci-dessous :

http://hpics.li/132fd89

Je te mets les lignes de codes que tu m'as fourni :

► Afficher le texte

Code : Tout sélectionner

Func telechargeProgress()
   If _Ischecked($fichier1) and $stop = 0 Then
       If StringRight($chemin_complet, 4) <> ".zip" Then $chemin_complet &= ".zip"
       Local $hDownload = InetGet("ftp://nomutilisateur:motdepasse@ftp.***-********.**/CD-WEB2.zip", $chemin_complet, 1, 1)

        GuiCtrlSetData($telecharger_1, "Annuler")
        GuiCtrlSetState($quitter, $GUI_DISABLE)
        Do
           If $stop = 1 Then
                 InetClose($hDownload)
                 Exitloop
           EndIf
           $info = InetGetInfo($hDownload)
          _SetProgress($progressbar, $info[1], $info[0])
          Sleep(100)
       Until $info[2]
        If $stop = 1 Then
            MsgBox(64, "CD-WEB2", "Téléchargement interrompu")
            GuiCtrlSetData($telecharger_1, "Télécharger")
            GuiCtrlSetData($progressbar, 0)
            Exit
        Else

            MsgBox(64, "CD-WEB2", "Téléchargement terminé")
        EndIf
        EndIf
       GuiCtrlSetState($quitter, $GUI_ENABLE)

   ;codes pour décompresser le dossier
[color=#FF0000]If @OSArch = "x86" Then $path7z = @ScriptDir & "\7-Zip\x86\7-zip32.dll"
If @OSArch = "x64" Then $path7z = @ScriptDir & "\7-Zip\x64\7-zip64.dll"
$outdir = @scriptdir & "\CD-WEB2"
Local $buffer = DllStructCreate("char[32768]")
DllCall($path7z, 'int', 'SevenZip', _
    'hwnd', 0, _
    'str', 'e "' & $chemin_complet & '" -aoa -o"' & $outdir & '"', _
    'ptr', DllStructGetPtr($buffer), _
    'int', DllStructGetSize($buffer))
Sleep(500)
ShellExecute ($outdir  & "\Install.exe")

EndFunc[/color]
 

[mikell]

ça doit être juste une histoire de chemin parce que chez moi ce test marche

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;#include <7Zip.au3>
Opt("GUIOnEventMode", 1)


Global $autoit = "http://www.autoitscript.com/forum/files/download/44-xskin-fully-loaded/xskin-fully-loaded.zip"
Global $SizeFile = InetGetSize($autoit)
Global $iFreeSpace = Round(DriveSpaceFree(@HomeDrive & "\")*1024*1024)
;; msgbox(0,"", $SizeFile &@crlf& $iFreeSpace)

Global $spaceOK = true, $stop = 0
If $iFreeSpace < $SizeFile Then
      $spaceOK = false
Else
      $outdir = @scriptdir & "\CD-WEB2\"
      If not FileExists($outdir) Then DirCreate($outdir)
EndIf


    Global $Gestion = GUICreate("Téléchargement CD-WEB2", 350, 410, 500, 300)
    GUISetBkColor(0x94CEDD)
    Global $Group1 = GUICtrlCreateGroup("Cochez la case puis cliquez sur Télécharger", 24, 152, 229, 135)
    Global $fichier1 = GUICtrlCreateCheckbox("autoit.zip", 30, 226, 100, 17)
    GUICtrlSetOnEvent( -1,"checkbox")
    Global $telecharger_1 = GUICtrlCreateButton("Télécharger", 160, 194, 75, 25)
    GuiCtrlSetState(-1, $GUI_DISABLE)
    GUICtrlSetOnEvent( -1,"telechargeProgress")
    Global $quitter_1 = GUICtrlCreateButton("Quitter", 160, 232, 75, 25)
    GUICtrlSetOnEvent( -1,"quitter")
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    Global $progressbar = GUICtrlCreateProgress(18, 306, 220, 20)
    GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")
GUIRegisterMsg($WM_SYSCOMMAND, "_WM_SYSCOMMAND")

While 1
   sleep(10)
WEnd

;===============================================

Func checkbox()
  If _Ischecked(@GUI_CtrlId) then
      If $spaceOK = false Then
           GuiCtrlSetState($telecharger_1, $GUI_DISABLE)
           MsgBox (1024, "", "espace disque disponible insuffisant")
       Else
           GuiCtrlSetState($telecharger_1, $GUI_ENABLE)
           MsgBox (1024, "", "espace disque disponible ok")
        EndIf
  EndIf
EndFunc


Func telechargeProgress()
    If GUICtrlRead($fichier1) = "1" Then

       $chemin_complet = FileSaveDialog("Choisir un emplacement :", @HomeDrive, "Fichiers d'archivage (*.zip)", 16, "xskin-fully-loaded.zip")
       If @error Then Return
       If StringRight($chemin_complet, 4) <> ".zip" Then $chemin_complet &= ".zip"

        Local $hDownload = InetGet($autoit, $chemin_complet, 1, 1)
        Do
            If $stop = 1 Then
                InetClose($hDownload)
                Exitloop
           EndIf
           $info = InetGetInfo($hDownload)
           _SetProgress($progressbar, $info[1], $info[0])
           Sleep(100)
       Until $info[2]
       MsgBox(64, "CD-WEB2", "Fin du téléchargement" &@crlf& $chemin_complet)
    EndIf

If @OSArch = "x86" Then $path7z = @ScriptDir & "\7-Zip\x86\7-zip32.dll"
If @OSArch = "x64" Then $path7z = @ScriptDir & "\7-Zip\x64\7-zip64.dll"
Local $tOutBuffer = DllStructCreate("char[32768]")
DllCall($path7z, 'int', 'SevenZip', _
        'hwnd', 0, _
        'str', 'e "' & $chemin_complet & '" -aoa -o"' & $outdir & '"', _
        'ptr', DllStructGetPtr($tOutBuffer), _
        'int', DllStructGetSize($tOutBuffer))
EndFunc


Func _WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
 #forceref $hWnd, $Msg, $lParam
   $test = BitAND($wParam, 0xFFF0)
    If $test = 0xF060 Then
       $stop = 1
       Exit
   EndIf
    Return 'GUI_RUNDEFMSG'
EndFunc  

Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
 #forceref $hWnd, $Msg, $lParam
 Switch BitAND($wParam, 0x0000FFFF)
    Case $quitter_1
        $stop =  1  
 EndSwitch
  Return 'GUI_RUNDEFMSG'
EndFunc  

Func _SetProgress($ctrlId,$SizeFile,$SizeDownload)
    GUICtrlSetData($ctrlId,Int(($sizeDownload/$SizeFile)*100))
EndFunc

Func quitter()
   Exit
EndFunc

Func _Ischecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc
 

[greenkev]

J'ai essayé ton script mais la décompression ne fonctionne pas.

Je commence à être perdu dans tout ce code.

Je ne comprends pas pourquoi ça déconne punaise.

[greenkev]

J'ai regardé le script avec mon patron donc il m'a dit qu'il faudrait indiquer dans quel dossier on souhaite enregistrer le dossier compressé.

Y-a-t'il une fonction qui permet de faire ça ?

[mikell]

Oui, FileSelectFolder (mais pas sûr que ça change grand'chose)
Si le téléchargement marche mais pas la décompression, tu devrais mettre tout dans le même dossier (fichier, script, dll ) pour tester juste la décompression dans un script à part, du genre

► Afficher le texte

Code : Tout sélectionner

Global $chemin_complet = @scriptdir & "\fichier.zip"
Global $outdir = @scriptdir & "\test-decomp\"
If not FileExists($outdir) Then DirCreate($outdir)

_decompress()

Func _decompress()
Local $path7z
If @OSArch = "x86" Then $path7z = @ScriptDir & "\7-zip32.dll"
If @OSArch = "x64" Then $path7z = @ScriptDir & "\7-zip64.dll"
Local $tOutBuffer = DllStructCreate("char[32768]")
DllCall($path7z, 'int', 'SevenZip', _
        'hwnd', 0, _
        'str', 'e "' & $chemin_complet & '" -aoa -o"' & $outdir & '"', _
        'ptr', DllStructGetPtr($tOutBuffer), _
        'int', DllStructGetSize($tOutBuffer))
EndFunc
 

si ça marche c'est que c'est une histoire de chemin

[greenkev]

Comment combiner le FileSelectFolder avec le dossier compressé "CD-WEB2.zip" ?

Quand j'utilise le FileSelectFolder, je sélectionne mon répertoire de destination, ça télécharge bien mais le nom du dossier compressé prend le nom du répertoire de destination alors que je veux que ça prenne le nom "CD-WEB2.zip".

Peut-on arranger ça ?

[mikell]

Code : Tout sélectionner

$dossier_de destination = FileSelectFolder(...)
$fichier_de destination = $dossier_de destination & "\CD-WEB2.zip"