[..] Changer compte Outlook par défaut ?

[davzell]

Bonjour à tous.

Je voulais savoir si quelqu'un connaît une technique pour changer le compte pip par défaut dans Outlook ?

Via le registre, udf ou objet com. J'ai un peu tout chercher mais je ne pense pas que ce soit possible.

Édit: et sans mouvement de souris ou raccourcis clavier par contre

Par exemple je voudrais que mon compte pop Test2 soit mis par défaut à la place du Test1



Merci d'avance

[orax]

- Le Kit de ressources Office ?
À première vue c'est la grosse artillerie et honnêtement je ne l'ai jamais utilisé donc je ne sais pas si c'est vraiment ce qu'il faut.

- Ou cet UDF https://www.autoitscript.com/forum/topi ... ookex-udf/

[davzell]

j'ai posté sur le post de la personne qui a codé cet udf et on ne peut pas

[jguinch]

J'ai regardé un peu avec RegShot pour voir ce qui changeait dans la base de registre.
Au final, voilà ce que j'ai trouvé :
Dans HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676 :
- Chaque compte est défini par un numéro, correspondant à une clé dans 9375CFF0413111d3B88A00104B2A6676 (par exemple, 00000004).
- La valeur {ED475418-B0D6-11D2-8C3B-00104B2A6676} contient l'ordre des comptes Outlook (dans la fenêtre dont tu as fait la capture d'écran)

Dans chaque clé correspondant à un compte (00000004), il y a la valeur Account Name, qui contient le nom du compte. Tu peux lire la valeur comme ça :

► Afficher le texte

Code : Tout sélectionner

$s = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676\00000004", "Account Name")
$s = BinaryToString(StringReplace($s, "00", ""))
MsgBox(0, "", $s)
 

Une fois que tu as le nom du compte du peux choisir l'ordre, sachant que le premier est celui par défaut.

Voilà donc 2 fonctions, qui fonctionnent chez moi (Office 2010) :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3> ; uniquement pour _ArrayDisplay

$aAccounts = _OutlookGetAccounts()
_ArrayDisplay($aAccounts)

_OutlookSetAccountDefault("NomDuCompte")


Func _OutlookSetAccountDefault($vAccount) ; $vAccount peut etre le nom du compte ou son identifiant dans la base de registre
    Local $aAccounts
    Local $sAccountID = $vAccount
    
    If Not Number($vAccount) Then
        $aAccounts = _OutlookGetAccounts()
        _ArrayDisplay($aAccounts)
        For $i = 1 To $aAccounts[0][0]
            If $aAccounts[$i][1] = $vAccount Then
                $sAccountID = $aAccounts[$i][0]
                ExitLoop
            EndIf
        Next
        If Not Number($sAccountID) Then Return SetError(1, 0, 0)
    EndIf
    
    Local $sOrder = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676", "{ED475418-B0D6-11D2-8C3B-00104B2A6676}")
    Local $sAccountReverse = StringRegExpReplace($sAccountID, "(\d{2})(\d{2})(\d{2})(\d{2})", "$4$3$2$1")
    Local $sNewOrder = StringRegExpReplace($sOrder, "^0x\K((?:\d{8})*)" & $sAccountReverse, $sAccountReverse & "$1")
    Local $iRet = RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676", "{ED475418-B0D6-11D2-8C3B-00104B2A6676}", "REG_BINARY", $sNewOrder)
    Return SetError(@error, 0, $iRet)
EndFunc


Func _OutlookGetAccounts()
    Local $sOrder = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676", "{ED475418-B0D6-11D2-8C3B-00104B2A6676}")
    Local $aNums = StringRegExp($sOrder, "\d{8}", 3)
    Local $aRet[UBound($aNums) + 1][2]
    
    For $i = 0 To UBound($aNums) - 1
        $aRet[$i + 1][0] = StringRegExpReplace($aNums[$i], "(\d{2})(\d{2})(\d{2})(\d{2})", "$4$3$2$1")
        $aRet[$i + 1][1] = BinaryToString(StringReplace(RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles\Outlook\9375CFF0413111d3B88A00104B2A6676\" & $aRet[$i + 1][0], "Account Name"), "00", ""))
    Next
    $aRet[0][0] = UBound($aNums)
    Return $aRet
EndFunc

 

[davzell]

Merci je vais essayer ça demain.

J'espère que le principe est le même pour Outlook 2013/2016 même si les clefs sont pas au même endroit.

[jguinch]

Pour Office 2013, il faudra regarder dans HKEY_CURRENT_USER\Software\Microsoft\Office\15.0\Outlook\Profiles.
J'ai qu'un Office 2010 sous la main, mais j'essaierai de jeter un œil demain au boulot sur 2013.

[davzell]

Oui il me semble que c'est ça.

Par contre quand on fait une migration d'un office 2010 vers 2013 par exemple, les profils sont tjr conservé dans l'ancienne arborescence.

Ce qui est plus chiant pour scripter car je comptais détecter la version d'outlook et chercher en fonction de ça dans tel ou tel clef de registre

Faudra que je trouve une autre idée

[jguinch]

Regarde d'abord dans la clé Office : si la valeur n'existe pas regarde dans Windows Messaging Subsystem

[davzell]

bon marche nickel avec du 2013 aussi.

Un grand merci.

Par hasard, après les modifications je voulais lancer un outlook masqué (ou au moins Minimisé) avec un shell execute

Code : Tout sélectionner

ShellExecuteWait ("outlook.exe", "", "", "", @SW_HIDE)
 

mais il reste affiché au premier plan.
Est ce qu'il y a des applications récalcitrantes pour ça ?

[Oversid3]

Pas trop le temps de fouillé mais rapidement 2 pistes :

https://support.microsoft.com/en-us/kb/251340

et

En VB :

Code : Tout sélectionner

wshshell.Run """C:\Program Files\Microsoft Office\Office12\OUTLOOK.EXE""",2,False

[jguinch]

Quel est le but de lancer Outlook caché ?

Un truc simple, mais comme je ne sais pas ce que tu comptes faire :

Code : Tout sélectionner

$oOutlook = ObjCreate("Outlook.Application")

[davzell]

Le but final de ce que j'essaye de faire est une sorte d'assistant pour configurer des comptes pop dans Outlook, pour des utilisateurs novices et sans toucher à la configuration déjà en place.

Pour ça j'utilise les fichiers .prf qui servent à déployer Une configuration d'outlook.

Pour charger le fichier prf il faut lancer Outlook avec un argument spécifique.
Le soucis est que le compte créé de cette manière ne sera pas le compte par défaut dans Outlook (d'où mon post)


1)Donc ce que je veux faire cest charger le fichier prf
2)Outlook sera donc lancé, je veux le masquer pour que l'utilisateur ne commence pas à s'en servir
3)Changer le compte par défaut via le script que tu m'as donné.
4) fermer et relancer Outlook pour que la modification du registre soit prise en compte.