[R] Voisinage réseau

[lamicaouette]

Bonjour,

Je cherche une technique , ou mieux un code pour obtenir les machine du voisinage réseau.
je n'ai rien trouvé dans l'aide ni les tutos
merci d'avance
cdt

lami caouette

[jguinch]

NetServerEnum pourrait fonctionner...
Je te laisse tester :

► Afficher le texteNetServerEnum()

Code : Tout sélectionner

#include <Array.au3>

$aCompList = _NetServerEnum()
_ArrayDisplay($aCompList)



Func _NetServerEnum ($sDomain = '')
    Local Const $MAX_PREFERRED_LENGTH = -1
    Local Const $SV_TYPE_WORKSTATION = 1
    
    Local $uBufPtr = DllStructCreate("ptr;int;int"), $res[1]=[0], $i
    Local $uRecord = DllStructCreate("dword;ptr"), $iRecLen = DllStructGetSize($uRecord)
    Local $uString = DllStructCreate("char[16]")
    Local $uDomain = DllStructCreate("byte[32]"), $pDomain = 0
    If Not ($sDomain='' Or $sDomain='*') Then
        DllStructSetData($uDomain, 1, StringToBinary($sDomain,2))
        $pDomain = DllStructGetPtr($uDomain)
    EndIf
    Local $ret = DllCall ("netapi32.dll", "int", "NetServerEnum", _
        "wstr", "", "dword", 100, _
        "ptr", DllStructGetPtr($uBufPtr,1), _
        "int", $MAX_PREFERRED_LENGTH, _
        "ptr", DllStructGetPtr($uBufPtr,2), _
        "ptr", DllStructGetPtr($uBufPtr,3), _
        "int", $SV_TYPE_WORKSTATION, _ 
        "wstr", Null, _
        "dword", 0 )
        
    If $ret[0] Then Return SetError(1, $ret[0], '')
    Local $iTotalEntries = DllStructGetData($uBufPtr,3)
    Local $aReturn[$iTotalEntries + 1] = [ $iTotalEntries ]
    
    For $i = 1 To $iTotalEntries
        Local $uRecord = DllStructCreate("dword;ptr", DllStructGetData($uBufPtr,1)+($i-1) * $iRecLen)
        Local $sNBName = DllStructCreate("byte[32]", DllStructGetData($uRecord,2))
        DllStructSetData($uString,1,BinaryToString(DllStructGetData($sNBName,1),2))
        $aReturn[$i] = DllStructGetData($uString,1)
    Next
    
    DllCall ("netapi32.dll", "int", "NetApiBufferFree", "ptr", DllStructGetData($uBufPtr,1))
    Return $aReturn
EndFunc
 

Post original : http://www.autoitscript.com/forum/topic ... /?p=566539

[jbnh]

Déplacé dans "Aide générale"

[lamicaouette]

Merci
ça fonctionne parfaitement
Cdt

Lami caouette