[R] Assembler code AutoIt et code Koda

[tinoudu01]

Bonjour,
J’essaye actuellement de réaliser un petit programme me permettant de renommer les extensions de plusieurs fichiers dans un même dossier.

Voici le code AutoIt : (Merci Timmalos ^^)

► Afficher le texte

Code : Tout sélectionner

 #include <file.au3>
#include <date.au3>
;


;$old_ext = ".jpg"
;$new_ext = ".bmp"

$old_ext = InputBox("Inserer l'extension des fichiers à modifier","Exemple : jpg")
$new_ext = InputBox("Inserer la nouvelle extension de vos fichiers","Exemple : bmp")
$dir = FileSelectFolder ( "Selectionnez le dossier", "" , 7 , @ScriptDir )


FileChangeDir ( $dir )
; Shows the filenames of all files in the current directory.
$search = FileFindFirstFile("*"&$old_ext)  

; Check if the search was successful
If $search = -1 Then
    MsgBox(0, "Erreur", "Aucun fichier trouvé")
    Exit
EndIf

While 1
    $file = FileFindNextFile($search) 
    If @error Then ExitLoop
    
    $file2 = StringReplace ( $file, $old_ext, $new_ext)
    
    $ok = FileMove($file,$file2)
    If $ok = 1 then _FileWriteLog(@ScriptDir & "\renommage.log",":: OK : "&$file)
    If $ok = 0 then _FileWriteLog(@ScriptDir & "\renommage.log",":: ECHEC : "&$file)
WEnd

; Close the search handle
FileClose($search)

Et voici l’interface que j’aimerais avoir :

► Afficher le texte

Code : Tout sélectionner

 #include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Modifext", 399, 261, 425, 207)
$Oldext = GUICtrlCreateLabel("Ancienne extension :", 24, 64, 103, 17)
$Newext = GUICtrlCreateLabel("Nouvelle extension :", 24, 96, 100, 17)
$Infolog = GUICtrlCreateLabel("Ce programme vous permet de modifier des extensions par lot.", 24, 16, 295, 17)
GUICtrlCreateInput("", 128, 56, 105, 21)
GUICtrlCreateInput("", 128, 88, 105, 21)
$infodos = GUICtrlCreateLabel("Dossier dans le quel ce trouve les fichiers a modifier :", 24, 152, 253, 17)
GUICtrlCreateInput("", 24, 176, 193, 25)
$Parcourir = GUICtrlCreateButton("Parcourir", 232, 176, 73, 25, 0)
$Quitter = GUICtrlCreateButton("Quitter", 296, 216, 75, 25, 0)
$Appliquer = GUICtrlCreateButton("Appliquer", 24, 216, 73, 25, 0)
$Annuler = GUICtrlCreateButton("Annuler", 160, 216, 73, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

Appliquer : Applique le changement si les zones de saisies sont bien rempli (message d’erreur si vide ou fichier inexistant dans le répertoire, confirmation du changement si réalisé)
Annuler : Vide les zones de saisie
Quitter : Comme son nom l’indique

Mon problème est que je n’y connaît pas grand chose et que je ne sais pas comment assembler mes deux codes.

Merci pour votre aide.

Antoine

[ani]

bonjour, y a un seul point que je n'ai pas réalisé c'est le bouton Annuler, pourriez vous expliquer sa fonction ?

alors vous devez juste entrée l'extension genre bmp,jpg pas de point devant

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <File.au3>
Dim $Form1, $Oldext, $iOldext, $Newext, $iNewext, $Infolog, $infodos, $Parcourir, $iParcourir, $QUitter, $Appliquer, $Annuler
$Form1 = GUICreate("Modifext", 399, 261, 425, 207)
$Oldext = GUICtrlCreateLabel("Ancienne extension :", 24, 64, 103, 17)
$Newext = GUICtrlCreateLabel("Nouvelle extension :", 24, 96, 100, 17)
$Infolog = GUICtrlCreateLabel("Ce programme vous permet de modifier des extensions par lot.", 24, 16, 295, 17)
$iOldext = GUICtrlCreateInput("", 128, 56, 105, 21)
$iNewext = GUICtrlCreateInput("", 128, 88, 105, 21)
$infodos = GUICtrlCreateLabel("Dossier dans lequel se trouve les fichiers à modifier :", 24, 152, 253, 17)
$iParcourir = GUICtrlCreateInput("", 24, 176, 193, 25)
$Parcourir = GUICtrlCreateButton("Parcourir", 232, 176, 73, 25, 0)
$Quitter = GUICtrlCreateButton("Quitter", 296, 216, 75, 25, 0)
$Appliquer = GUICtrlCreateButton("Appliquer", 24, 216, 73, 25, 0)
$Annuler = GUICtrlCreateButton("Annuler", 160, 216, 73, 25, 0)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $Quitter
            Exit
        Case $Parcourir
            $dir = FileSelectFolder ( "Selectionnez le dossier", "" , 7 , @ScriptDir )
            GUICtrlSetData($iParcourir,$dir)
        Case $Annuler
        Case $Appliquer
            Appliquer(GUICtrlRead($iParcourir),GUICtrlRead($iNewext),GUICtrlRead($iOldext))
    EndSwitch
WEnd
 
Func Appliquer($Rep,$New_ext,$Old_ext)
    FileChangeDir($Rep)
    $Search = FileFindFirstFile("*." & $Old_ext)  

    If $Search = -1 Then
        MsgBox(0, "Erreur", "Aucun fichier trouvé")
        Exit
    EndIf

    While 1
        $File = FileFindNextFile($search) 
        If @error Then ExitLoop
    
        $File2 = StringReplace($File,$Old_ext, $New_ext)
    
        $Ok = FileMove($File,$File2)
        If $Ok = 1 then _FileWriteLog(".\renommage.log", ":: OK : " & $File)
        If $Ok = 0 then _FileWriteLog(".\renommage.log", ":: ECHEC : " &$File)
    WEnd

    FileClose($Search)
    MsgBox(0, "Terminé", "Fini !!")

EndFunc

bonne continuation

[tinoudu01]

Merci beaucoup pour cette réponce très complette et surtout très rapide !

[timmalos]

Tu as tout ce que tu voulais ?

[tinoudu01]

Pour le moment oui, j'ai effectué les petite modifications que je désirai !
Merci pour cette aide qui ma été précieuse !

Antoine

[timmalos]

Je met le code final dans la partie Exemple, ca peut servir aux autres.

[tinoudu01]

Je met le code final dans la partie Exemple, ca peut servir aux autres.

Met plutôt ce code la, c’est le même mais il gère le cas ou un des champs est vide et il ne ferme pas le programme lorsqu’il n’y a pas de fichier à modifier.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <File.au3>
Dim $Form1, $Oldext, $iOldext, $Newext, $iNewext, $Infolog, $infodos, $Parcourir, $iParcourir, $QUitter, $Appliquer, $Annuler
$Form1 = GUICreate("Modifext", 346, 250, 311, 218)
$Oldext = GUICtrlCreateLabel("Ancienne extension :", 24, 64, 103, 17)
$Newext = GUICtrlCreateLabel("Nouvelle extension :", 24, 96, 100, 17)
$Infolog = GUICtrlCreateLabel("Ce programme vous permet de modifier des extensions par lot.", 24, 16, 295, 17)
$iOldext = GUICtrlCreateInput("", 128, 56, 105, 25)
$iNewext = GUICtrlCreateInput("", 128, 88, 105, 25)
$infodos = GUICtrlCreateLabel("Dossier dans lequel se trouve les fichiers à modifier :", 24, 152, 253, 17)
$iParcourir = GUICtrlCreateInput("", 24, 176, 193, 27)
$Parcourir = GUICtrlCreateButton("(Not allowed)", 224, 176, 96, 27, $BS_BITMAP)
GUICtrlSetImage(-1, "C:\Documents and Settings\Mick\Bureau\Koda\Parcourir.bmp", 0)
$Quitter = GUICtrlCreateButton("(Not allowed)", 192, 216, 96, 27, $BS_BITMAP)
GUICtrlSetImage(-1, "C:\Documents and Settings\Mick\Bureau\Koda\Quitter.bmp", 0)
$Appliquer = GUICtrlCreateButton("(Not allowed)", 56, 216, 94, 27, $BS_BITMAP)
GUICtrlSetImage(-1, "C:\Documents and Settings\Mick\Bureau\Koda\Appliquer.bmp", 0)
$Tab1 = GUICtrlCreateTab(8, 8, 329, 201)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $Quitter
            Exit
        Case $Parcourir
            $dir = FileSelectFolder ( "Selectionnez le dossier", "" , 7 , @ScriptDir )
            GUICtrlSetData($iParcourir,$dir)
        Case $Appliquer
                Appliquer(GUICtrlRead($iParcourir),GUICtrlRead($iNewext),GUICtrlRead($iOldext))
    EndSwitch
WEnd
 
Func Appliquer($Rep,$New_ext,$Old_ext)
    FileChangeDir($Rep)
    $Search = FileFindFirstFile("*." & $Old_ext)  

    If $Old_ext = "" or $New_ext= "" or $Rep = "" Then
        MsgBox(0, "Erreur", "Merci de remplir tous les champs.")
    Else
        If $Search = -1 Then
            MsgBox(0, "Erreur", "Aucun fichier n'a été trouvé.")
        Else
            While 1
            $File = FileFindNextFile($search) 
            If @error Then ExitLoop
            
            $File2 = StringReplace($File,$Old_ext, $New_ext)
            
            $Ok = FileMove($File,$File2)
            ; If $Ok = 1 then _FileWriteLog(".\renommage.log", ":: OK : " & $File)
            ; If $Ok = 0 then _FileWriteLog(".\renommage.log", ":: ECHEC : " &$File)
            WEnd
            
            FileClose($Search)
            MsgBox(0, "Opération terminé", "L’opération a été effectuée avec succès.")
        EndIf
    EndIf

EndFunc