[R] Automatiser FileOpenDialog

[walkson]

Bonjour,
Je cherche à automatiser FileOpenDialog
J'ai essayé plusieurs méthodes sans succès, impossible de contrôler la fenêtre...

Code : Tout sélectionner

FileOpenDialog("Ouvrir", @DesktopDir & "\", "text (*.txt)")
    ControlSend("Ouvrir", "", "Edit1", @DesktopDir & "\monchemin.txt")
         ControlClick("Ouvrir", "", "Button1", "left")

FileOpenDialog semble arrêter le script dans l'attente d'une réponse (comme MsgBox). Y a t' il une solution ?
Merci de vous pencher sur mon problème.

[Tlem]

Pourquoi utilisez-vous un FileOpenDialog() si vous connaissez déjà le chemin à utiliser ?
FileOpenDialog() est une fonction bloquante. Comme il n'y a pas de timeout, vous ne pourrez lancer aucune action tant que celle-ci ne sera pas terminée.

[walkson]

Bonjour Tlem,
C'est le programme que je veux automatiser qui ouvre un FileOpenDialog()
A vous lire et comme je le craignais, il n' y a pas de solution à part de répondre à cette fenêtre.

[Hugues]

Salut,

Je ne sais pas si cela peu fonctionner, mais tu as pensé à AU3Info? Et tu utilises Finder Tool pour avoir infos sur ta fenêtre FileOpen.

[walkson]

Bonsoir Hugues,
Oui, j'ai utilisé AU3Info mais sans aucunes interactions.
Comme l'a dit Tlem, la fenêtre se met en attente d'une réponse et donc le script est en pause.
Le seul moyen de communiquer serait d'envoyer un message avant l’apparition de la fenêtre et qu'elle en tienne compte. Mais là, je crois que je suis en plein délire.....

[Hugues]

Bin là je peux pas t'aider plus... Désolé

[Tlem]

C'est le programme que je veux automatiser qui ouvre un FileOpenDialog()

la fenêtre se met en attente d'une réponse et donc le script est en pause

Heuu il y a un truc là !!!
Le programme/script que vous essayez d'automatiser est-il séparé du script qui doit faire l'automatisation ?

[walkson]

Bonsoir,
Le programme que je désire automatiser est TrueCrypt Format.exe
J'ai réussi à automatiser (avec Autoit) toutes les étapes mais je coince sur le FileOpenDialog concernant les Keyfiles que je suis obligé de désigner manuellement à travers ce FileOpenDialog
Le FileOpenDialog de TrueCrypt est identique à celui d'Autoit. Ce n'est pas la fenêtre que l'on peut trouver sur "ouvrir" de Notepad
Voici ce que me donne V3 Window info

► Afficher le texte

>>>> Window <<<<
Title: Select Keyfile
Class: #32770
Position: 253, 182
Size: 625, 480
Style: 0x96CC02C4
ExStyle: 0x00010101
Handle: 0x000402B6

>>>> Control <<<<
Class: Edit
Instance: 1
ClassnameNN: Edit1
Name:
Advanced (Class): [CLASS:Edit; INSTANCE:1]
ID: 1148
Text:
Position: 225, 380
Size: 147, 15
ControlClick Coords: 119, 10
Style: 0x54000080
ExStyle: 0x00000000
Handle: 0x00050260

>>>> Mouse <<<<
Position: 605, 602
Cursor ID: 0
Color: 0xFFFFFF

>>>> StatusBar <<<<

>>>> ToolsBar <<<<

>>>> Visible Text <<<<
Contrôle Arborescence d’espace de noms
Arborescence
ShellView
&Nom du fichier :
&Types de fichiers :
All Files (*.*)
Ou&vrir
Annuler
Adresse : C:\Users\Pc\Desktop\TrueCrypt


>>>> Hidden Text <<<<
Contrôle Arborescence d’espace de noms
Shell Preview Extension Host
&Aide

[mikell]

Heuu il y a un truc là !!!

+1 !
Le FileOpenDialog d'un programme externe n'est bloquant que pour le programme concerné
Les controles qu'il contient peuvent donc être gérés par un script ^^

[walkson]

Bonsoir Mikell,
J'en suis content, mais comment faire ?
J'ai bien tenté d'envoyer le chemin dans le combobox et que néni puis dans l'édit, pareil.
Voilà ce que j'ai fait:

Code : Tout sélectionner

;$hWnd_TC_Volume_Creation_Wizard >> handle de la fenêtre principale    
ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:7]') ;valide keyfile
        If ControlEnable($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:8]') Then
            ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:8]');fenêtre TrueCrypt - Keyfiles
        EndIf
    ControlClick("TrueCrypt - Keyfiles", '', '[CLASS:Button; INSTANCE:1]');ouvre filedialog
    ControlSetText("Select Keyfile", '', '[CLASS:Edit; INSTANCE:1]', "C:\Users\Pc\Documents\AUTOIT\PROJET\TC\TC\Test.tc", 1)
    ;aucun effet sur FileOpenDialog, idem si j'utilise Class:combobox
  While 1;attente listview soit rempli
    Local $aa1 = ControlListView("TrueCrypt - Keyfiles","",'SysListView321',"GetText", 0)
    If $aa1 > "" Then ExitLoop
    WEnd
    ControlClick("TrueCrypt - Keyfiles", '', '[CLASS:Button; INSTANCE:8]');valide
    WinWaitClose("TrueCrypt - Keyfiles","")

[Tlem]

Bonsoir.
Utilisez ceci :

Code : Tout sélectionner

ControlSetText("[CLASS:#32770]", 'Type', '[CLASS:Edit; INSTANCE:1]', "C:\Users\Pc\Documents\AUTOIT\PROJET\TC\TC\Test.tc", 1)

Si ça ne le fait pas, remplacez 'Type' par un autre mot qui se trouve en bas.
Dans ma version, j'ai "Nom du fichier :" ou "Type :", si vous avez une version étrangère, adaptez au besoin (il me semble que 'Type' est commun sur les OS Fr et Us).

[walkson]

Bonjour,
Tout d'abord, merci à Tlem pour son aide.
J'ai utilisé son scrypt, l'ai modifié et reremodifié sans résultat pour enfin m'apercevoir que mon problème était un problème de tempo. En effet, la commande était lancée avant l'ouverture de la fenêtre et forcément, plouf!
Voilà le bout de code qui fonctionne parfaitement

Code : Tout sélectionner

    ControlClick("TrueCrypt - Keyfiles", '', '[CLASS:Button; INSTANCE:1]');ouvre filedialog
    WinWait("[Title:    Select Keyfile]","",1);attente ouverture Fileopendialog
    ;entrer chemin keyfile
    ControlSetText("[CLASS:#32770]", '&Nom du fichier :', '[CLASS:Edit; INSTANCE:1]', "C:\Users\Pc\Documents\AUTOIT\PROJET\TC\TC\Test.tc", 1)
    ;button "OK"
    ControlClick("[CLASS:#32770]", '', '[CLASS:Button; INSTANCE:1]')

Voilà le code en entier pour TrueCrypt Format qui fonctionne mais qui mérite d'être encore travaillé (brut de brut)

► Afficher le texte

Code : Tout sélectionner

#include <File.au3>
#RequireAdmin
AutoItSetOption("WinDetectHiddenText", 1)
Opt("WinTitleMatchMode", 3)
Local $chemin = ""
    Local $aArray1 = StringSplit(@ScriptDir, '\')
    For $i = 1 To $aArray1[0] - 1
        $chemin &= $aArray1[$i] & "\"
    Next
;MsgBox(0,"",$chemin)
DirCreate($chemin & "Archives")
Local $TC_Container_Location = $chemin & "Archives\vol.tc"
Local $TC_Container_Encryption = "AES"
Local $TC_Container_Size = 10
Local $TC_Password = "motdepasse"
Local $TC_Format = "NTFS"
Local $TC_Dynamic = True
Local $TC_Keyfile = True

 $PID_TC_Format = Run('"' & @ScriptDir & '\TrueCrypt7\TrueCrypt Format.exe"', @ScriptDir, @SW_SHOW)
 ProcessWait($PID_TC_Format)
 $hWnd_TC_Volume_Creation_Wizard = WinGetHandle("[TITLE:TrueCrypt Volume Creation Wizard; CLASS:CustomDlg]", "")

 WinWait($hWnd_TC_Volume_Creation_Wizard,"TrueCrypt Volume Creation Wizard",1)
                $TC_Timer = TimerInit()

    ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')

 WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Type",1)
 ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
 WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Location",1)
 ControlSetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:1]', $TC_Container_Location, 1)
    If ControlGetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:1]') = $TC_Container_Location Then
        ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
    EndIf
 WinWait($hWnd_TC_Volume_Creation_Wizard,"Encryption Options",1)
    ControlCommand($hWnd_TC_Volume_Creation_Wizard, "", "[CLASS:ComboBox; INSTANCE:1]", "SelectString", $TC_Container_Encryption)
    If ControlCommand($hWnd_TC_Volume_Creation_Wizard, "", "[CLASS:ComboBox; INSTANCE:1]", "GetCurrentSelection", "") = $TC_Container_Encryption Then
            ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
    EndIf
WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Size",1)
$Format_Size = "Button7";Button6 7 8 >> Kb Mb Gb
ControlFocus($hWnd_TC_Volume_Creation_Wizard,"",$Format_Size)
ControlSetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:1]', $TC_Container_Size, 1)

    If ControlGetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:1]') = $TC_Container_Size Then
        ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
    EndIf
If $Format_Size = "Button7" Then $TC_Container_Size = $TC_Container_Size * 1024;en Mo >> Ko
If $Format_Size = "Button8" Then $TC_Container_Size = $TC_Container_Size * 1024 * 1024;en Go >> Ko
    If $TC_Container_Size < 275 Then $TC_Container_Size = 275
    If $TC_Container_Size < 2829 Then $TC_Format = "FAT"
WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Password",1)
;ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:6]');display password
If $TC_Keyfile = True Then
    ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:7]') ;valide keyfile
        If ControlEnable($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:8]') Then
            ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:8]');fenêtre TrueCrypt - Keyfiles
        EndIf
    ControlClick("TrueCrypt - Keyfiles", '', '[CLASS:Button; INSTANCE:1]');ouvre filedialog
    WinWait("[Title:    Select Keyfile]","",1);attente ouverture Fileopendialog
    ;entrer chemin keyfile
    ControlSetText("[CLASS:#32770]", '&Nom du fichier :', '[CLASS:Edit; INSTANCE:1]', "C:\Users\Pc\Documents\AUTOIT\PROJET\TC\TC\Test.tc", 1)
    ;button "OK"
    ControlClick("[CLASS:#32770]", '', '[CLASS:Button; INSTANCE:1]')
    WinWait("TrueCrypt - Keyfiles","",1)
Local $aa1 = ControlListView("TrueCrypt - Keyfiles","",'SysListView321',"GetText", 0)
    If $aa1 = "" Then
    MsgBox(0,"ERROR","Erreur keyfile: Exit")
    Exit
    EndIf
    ControlClick("TrueCrypt - Keyfiles", '', '[CLASS:Button; INSTANCE:8]');valide
    WinWaitClose("TrueCrypt - Keyfiles","")
    $cheminkey = StringSplit($aa1,"\")
    $KeyFile = "\" & $cheminkey[$cheminkey[0]]
EndIf
ControlSetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:1]', $TC_Password, 1)
ControlSetText($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Edit; INSTANCE:2]', $TC_Password, 1)


    If ControlEnable($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]') Then
        ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
    EndIf
 ControlClick("[TITLE:TrueCrypt Volume Creation Wizard; CLASS:#32770]", '', '[CLASS:Button; INSTANCE:1]');ferme alerte pour MP trop court
WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Format",1)
ControlCommand($hWnd_TC_Volume_Creation_Wizard, "", "[CLASS:ComboBox; INSTANCE:1]", "SelectString", $TC_Format)
    If $TC_Format = "NTFS" And $TC_Dynamic = True Then
        ControlClick($hWnd_TC_Volume_Creation_Wizard, '', "Button6");format dynamic
                        $fenetre = WinWait("[TITLE:TrueCrypt Volume Creation Wizard; CLASS:#32770]","")
                        WinSetState($fenetre,"",@SW_HIDE )
                        ControlClick($fenetre, '', "Button1")
    EndIf
ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:3]')
$fenetre = WinWait("[TITLE:TrueCrypt Volume Creation Wizard; CLASS:#32770]","The TrueCrypt volume has been successfully created.")
ControlClick($fenetre, '', "Button1")
Sleep(1000)
ControlClick("[TITLE:TrueCrypt Volume Creation Wizard; CLASS:#32770]", '', '[CLASS:Button; INSTANCE:1]')
WinWait($hWnd_TC_Volume_Creation_Wizard,"Volume Created",1)
ControlClick($hWnd_TC_Volume_Creation_Wizard, '', '[CLASS:Button; INSTANCE:4]')
 ;MsgBox(0,"","bon " )
If ProcessExists($PID_TC_Format) Then ProcessClose($PID_TC_Format)

Rmq: ce code est fortement inspiré d'un code du forum anglais en plus simple et plus complet

[jguinch]

Juste par curiosité, n'est-il pas possible d'utiliser TrueCrypt en ligne de commande ?
http://www.truecrypt.org/docs/command-line-usage

[walkson]

Bonjour jguinch
Pour gérer les containers, si c'est possible. Mais pour les créer, non.
C'est en projet à TrueCrypt mais depuis plusieurs années...
Un exemple pour monter un volume:

Code : Tout sélectionner

Local $exect = $chemin & "\TrueCrypt\TrueCrypt.exe"
ShellExecuteWait($exect, 'TrueCrypt /lv /v ' & $vol & ' /a /p ' & $MP & ' /m rm /e /q background')
Local $PID = ProcessExists("TrueCrypt.exe") ; Will return the PID or 0 if the process isn't found.

;/v path volume TC
;/l lettre disque
;/k keyfile
;/a automount
;/p mot de passe
;/m montage (rm removable)
;/e ouvre explorer
;/q Automatically perform requested actions and exit