[R] Recherche si Office installé

[titou974]

Bonjour,

Je cherche un moyen simple de checké si Microsoft Office est installé.
Actuellement je lui demande de voir si le word.exe existe, c'est pas propre mais je ne sais pas faire autrement.

Comment faites vous ?

[GhostLine]

En cherchant dans la base de registre, par exemple ?

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office\Word (enfin vérifie que cette clef est ok pour toi aussi avant de te lancer)

[titou974]

Le problème est que meme quand office est desinstallé la clé de registre existe toujours.

[GhostLine]

Dans ce cas, à part chercher sa présence physique ... car malheureusement, en règle générale, un programme laisse toujours des traces (gros cochon !) de son installation. C'est particulièrement vrai si le répertoire du programme est effacé "à la sauvage", auquel cas Windows ne sait pas automatiquement dissocier ne serait ce que les types MIME.

Donc à mon sens, il faut vérifier l'existence de l'exécutable désiré sur la machine concernée.

Comment procèdes-tu pour ce faire ?

[jchd]

Créer un objet Office ; si erreur il est probable qu'il ne soit pas installé ou non fonctionnel.

[jguinch]

Perso, je regarderais dans la base de registre, là où on trouve la liste des programmes installés...

► Afficher le textePar la base de registre

Code : Tout sélectionner

Func _IsInstalledOffice()
    Local $sSubKey = "", $i = 0
    Local $sRootKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"

    While 1
        $i += 1
        $sSubKey = RegEnumKey($sRootKey, $i)
        If @error Then ExitLoop
        
        If StringRegExp( RegRead($sRootKey & "\" & $sSubKey, "DisplayName"), "(?i)^Microsoft Office" ) Then Return 1
    WEnd
    Return 0
EndFUnc

ou

► Afficher le textePar la base de registre

Code : Tout sélectionner

Func _IsInstalledOffice2()
    Local $sSubKey = "", $i = 0
    Local $sRootKey = "HKEY_CLASSES_ROOT\Installer\Products"

    While 1
        $i += 1
        $sSubKey = RegEnumKey($sRootKey, $i)
        If @error Then ExitLoop
        
        If StringRegExp( RegRead($sRootKey & "\" & $sSubKey, "ProductName"), "(?i)^Microsoft Office" ) Then Return 1
    WEnd
    Return 0
EndFUnc

Tuu peux aussi essayer avec une requête WMI, mais ça peut être un peut longuet :

► Afficher le textePar WMI

Code : Tout sélectionner

Func _IsInstalledOfficeWMI()
    Local $strComputer = "."
    Local $objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")
    Local $colSoft = $objWMIService.ExecQuery("SELECT * FROM Win32_Product WHERE Name Like 'Microsoft Office%'")
    If Not IsObj($colSoft) Then Return SetError(1, 0, 0)

    If $colSoft.Count = 0 Then Return 0
    Return 1
EndFunc

Autre façon de faire, regarder dans la base de registre les différentes clés qui sont crées à l'install, par exemple :
- HKCR\Excel.Application
- HKCR\Word.Application
- [...]

Edit : la solution de jchd permet en plus de tester si l'application fonctionne

[titou974]

Actuellement je fais un IfExists ..... en verifiant l'existance de l'executable

Apres pour les autres methode WMI, objet, suis pas assez à l'aise.

Je vais voir aussi pour attaquer la BDR comme dans vos exemples.



Merci à vous

[jchd]

Avec la dernière version, bien sûr :

Code : Tout sélectionner

Local $oWordTest = ObjCreate("Word.Application")
ConsoleWrite("Word " & (@error ? "non ") & "fonctionnel." & @LF)
 

[GhostLine]

Classe !