[R] Tableau qui ne se remplit pas dans une boucle FOR

[losutak]

Bonjour,
Je voudrais faire ceci :

Code : Tout sélectionner

    For $i = 1 to $liste[0] ;boucle pour lire tous les fichiers avec la bonne extension
        $txt = "" ;On vide la variable pour ne pas se retrouver avec plusieurs fois la même liste
        $txt &= $liste[$i] & "|" ;on les met dans une varibale pour ensuite les rangés dans une combobox
        load_macro_liste($file_load_macro);on charge les fichier un à un en mémoire
        MsgBox(0,"","Key1 = "&$Array_return_Load[3]&@CRLF&"I = "&$i)
        Dim $Key1[$i] = [$Array_return_Load[3]]
        Dim $Key2[$i] = [$Array_return_Load[4]]
Next

C'est à dire, une variable, ici $i qui ajoute 1 à chaque fois qu'elle passe dans la boucle bon ici ça fait 4 fois car $liste vaut 4 au maximum. Le problème c'esr que quand j'utilise

Code : Tout sélectionner

_ArrayDisplay($Key1)

Il n'y a que la première ligne qui change, seule la première valeur est sauvegrder
Merci d'avance

[mikell]

Si tu vides la variable $txt à chaque tour de boucle faut pas t'étonner qu'elle ne contienne qu'une seule valeur à la fin ^^
Et enlève les Dim

[losutak]

Oui mais la variable $txt est sauvegarder dans le tableau non ? après la ligne change, or ici on dirais que la ligne ne change pas
Edit : Au passage c'est les diffèrentes valeurs de $Array_return_Load[3] que je veut sauvegarder dans mon tableau.
A chaque tour de boucle les valeurs de cette ligne change et je veut les sauvegarder dans $Key1 pour ensuite les affichés (pour le moment)

[mikell]

Alors faut écrire

Code : Tout sélectionner

$Key1[$i] = $Array_return_Load[3]

[losutak]

J'obtient cette erreur :

Code : Tout sélectionner

C:\Users\lucas\Desktop\Programmes\AutoIt\MacroMan\MacroMan Tests ².au3 (95) : ==> Subscript used with non-Array variable.:
$Key1[$i] = $Array_return_Load[3]
$Key1^ ERROR

Tous mes tableaux sont ici :

Code : Tout sélectionner

Dim $Array_return_Load[5] = [0,0,0,0,0]
Dim $Key1[10]
Dim $Key2[10]

Enfaîte seule la première ligne change

[TT22]

Et comme ça :

Code : Tout sélectionner

Dim $Array_return_Load[5] = [0,0,0,0,0]
Dim $Key1[10]
Dim $Key2[10]
For $i =1 to $liste[0] ;boucle pour lire tous les fichiers avec la bonne extension
        $txt &= $liste[$i] & "|" ;on les met dans une variable pour ensuite les ranger dans une combobox
        load_macro_liste($file_load_macro);on charge les fichier un à un en mémoire
        MsgBox(0,"","Key1 = "&$Array_return_Load[3]&@CRLF&"I = "&$i)
        $Key1[$i-1] = $Array_return_Load[3]
        $Key2[$i-1] = $Array_return_Load[4]
Next

Mais attention, si $liste[0] est supérieur à 10 alors ça va poser problème
Il faudra dans ce cas utiliser des ReDim.

[losutak]

Nouveau message d'erreur :

C:\Users\lucas\Desktop\Programmes\AutoIt\MacroMan\MacroMan Tests ².au3 (94) : ==> Array variable subscript badly formatted.:
Dim $Key1[$i-1] = [$Array_return_Load[3]]
Dim $Key1[^ ERROR

avec juste ça :

Code : Tout sélectionner

Dim $Key1[$i-1] = [$Array_return_Load[3]]

je suis obliger de metre Dim et d'entouré $Array_return_Load[3] de crochet sinon j'ai ça comme erreur :

C:\Users\lucas\Desktop\Programmes\AutoIt\MacroMan\MacroMan Tests ².au3 (95) : ==> Subscript used with non-Array variable.:
$Key1[$i] = $Array_return_Load[3]
$Key1^ ERROR

Et techniquement liste ne dépasse même pas 4 donc ej voit pas comment il peut être supérieur à 10
franchement depuis le début de cette aprem' je galère, ça me saoule un peu
Merci pour vos réponses, j'espère pouvoir résoudre ça avant Lundi

[TT22]

Tu peux pas nous donner toute la partie de ton code qui pose problème ?
Parce que là tu nous donne que des petits bouts donc on ne peut pas savoir si tu déclare bien les variables, si tu ne mélange pas plusieurs réponses, etc.

[mikell]

je suis obliger de metre Dim et d'entouré $Array_return_Load[3] de crochet

ça ne veut plus dire la même chose ! avec Dim tu recrées une array

The Dim/Local/Global keywords perform similar functions:
1. Declare a variable before you use it (similar to VBScript)
2. Create an array

Donc écrire ça

Code : Tout sélectionner

Dim $Key1[$i-1] = [$Array_return_Load[3]]

revient à dire : je crée une array $Key1 qui contient $i-1 éléments dont le 1er est $Array_return_Load[3] ^^

[losutak]

D'accord au pire je peut vous passer tous le code :

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version : 3.3.8.1
 Auteur:         Lucas

 Fonction du Script :
    Création de raccourci clavier

#ce ----------------------------------------------------------------------------
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Misc.au3>
#include <Array.au3>
#include <ComboConstants.au3>


#Region ### START Koda GUI section ### Form=c:\users\lucas\desktop\programmes\autoit\macroman\form1.kxf
Global $Form1_1 = GUICreate("MacroMan", 300, 175, 192, 124)
Global $MenuItem3 = GUICtrlCreateMenu("&Fichier")
Global $MenuItem1 = GUICtrlCreateMenuItem("Ouvrir Macro", $MenuItem3)
Global $MenuItem2 = GUICtrlCreateMenuItem("Ouvrir Macro Liste", $MenuItem3)
Global $MenuItem4 = GUICtrlCreateMenuItem("Sauvegrde", $MenuItem3)
Global $MenuItem5 = GUICtrlCreateMenuItem("Quitter", $MenuItem3)
Global $version = GUICtrlCreateLabel("Version 0.1", 240, 120, 57, 17)
Global $Auteur = GUICtrlCreateLabel("Créer par Lucas", 216, 136, 79, 17)
Global $Name_Input_Macro = GUICtrlCreateInput("Macro1", 72, 8, 121, 21)
Global $LBL_Name_Macro = GUICtrlCreateLabel("Nom Macro :", 8, 10, 65, 17)
Global $LBL_Raccourci_Keyboard = GUICtrlCreateLabel("Raccourci clavier :", 8, 34, 93, 17)
Global $and = GUICtrlCreateLabel("et", 170, 34, 30, 17)
Global $LBL_TXT = GUICtrlCreateLabel("Texte :", 8, 58, 37, 17)
Global $Macro_Input_TXT = GUICtrlCreateInput("Texte", 48, 56, 121, 21)
Global $CMB_Key1 = GUICtrlCreateCombo("", 104, 32, 49, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Ctrl|Alt")
Global $Input2 = GUICtrlCreateInput("", 200, 32, 49, 21)
Global $CMB_Macro_liste = GUICtrlCreateCombo("", 100, 80, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
Global $Label1 = GUICtrlCreateLabel("Liste des macros :", 8, 82, 89, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$docs = @MyDocumentsDir
$file_open_macro = ""
$file_line = ""
Dim $Array_return_Load[5] = [0,0,0,0,0]
Dim $Key1[10]
Dim $Key2[10]
While 1

    $Name_Macro = GUICtrlRead("10")
;~  $Key1 = GUICtrlRead("16")
;~  $Key2 = GUICtrlRead("17")
    $Name_TXT = GUICtrlRead("15")
    $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
   Exit
    Case $MenuItem5
    $exit = MsgBox(4,"Quitter ?","Si vous quittez le logiciel vos macro ne marcheront plus."&@CRLF&"Continuer ?")
    If $exit = 6 Then
        Exit
    Else
    EndIf
;================================CHARGEMENT======================
    Case $MenuItem1 ;CHARGEMENT D'UNE MACRO
    $file_open_macro = FileOpenDialog ( "Selectionner une macro",""&$docs,"Macro (*.mco)", 2); Ouverture d'un boite de dialoge pour ouvrir une macro
    If @error Then; On test si il y a une erreur, si ce n'est pas le cas on continue
        MsgBox(4096, "", "Aucun fichier n'a pas était ouvert.")
    Else
    Load($file_open_macro)
    EndIf

;==========================================CHARGEMENT LISTE================================
    Case $MenuItem2
        $select_folder = FileSelectFolder("Choisissez un dossier comportenant des macros pour créer une macro liste",@DesktopDir)
        $liste = _FileListToArray($select_folder,"*.mco")
        If @error = 1 Then
    MsgBox(0, "Erreur", "Aucun dossier trouvé !")
        ElseIf @error = 4 Then
    MsgBox(0, "Erreur", "Aucun fichier au format .mco trouvé, création de la macro liste impossible !")
        Else
    For $i = 1 to $liste[0] ;boucle pour lire tous les fichiers avec la bonne extension
        $txt = "" ;On vide la variable pour ne pas se retrouver avec plusieurs fois la même liste
        $txt_load ="" ;on la vide pour ne pas qu'il y est de problème de chargement de fichiers
        $txt &= $liste[$i] & "|" ;on les met dans une varibale pour ensuite les rangés dans une combobox
        GuiCtrlSetData("18", $txt) ;on les range dans une combobox
        $txt_load &= $liste[$i] ;on les met dans une variable pour les chargés
        $file_load_macro = $select_folder &"\"& $txt_load ;on charge grâce au répertoire + nom du fichier (ligne au dessus)
        load_macro_liste($file_load_macro);on charge les fichier un à un en mémoire
        MsgBox(0,"","txt = "&$Array_return_Load[3]&@CRLF&"I = "&$i)
        Dim $Key1[$i] = [$Array_return_Load[3]]

    Next
EndIf
_ArrayDisplay($Key1)


    Case $CMB_Macro_liste
        $combo = GUICtrlRead ( "18" )
        $file_open_macro = $select_folder &"\"& $combo ;Lire la combo box
        Load($file_open_macro)




;=========================SAVE===========================
        Case $MenuItem4
    $path = FileSaveDialog("Sauvegrder la Macro",""&$docs,"Macro (*.mco)", 2, $Name_Macro)
If @error Then
    MsgBox(4096, "", "Le fichier n'a pas était sauvegrder.")
    Else
    save($path)
    EndIf






EndSwitch

;~ $Key2 = StringUpper ( $Key2 ) ;transforme la chaine en MAJUSCULE
;~ $Key2 = __StringToHex($Key2) ; transforme la 2e chaine en hexa
;~ $cursor = GUICtrlRead ("16")
;~ If StringCompare($Key1,"Ctrl")=0 Then
;~ $Key1 = "11"
;~ ElseIf StringCompare($Key1,"Alt")=0 Then
;~ $Key1 = "12"
;~ EndIf


;~ Macro($Key1,$Key2)
WEnd




;=======================================FONCTIONS=========================================;
;Utilisation des macros
Func Macro($Key1,$Key2)
    If _IsPressed($Key1) and _IsPressed($Key2) Then
    send($Name_TXT)
EndIf
EndFunc

;Converti du texte en hexadecimal
Func __StringToHex($sString)
    Return Hex(StringToBinary($sString))
EndFunc

;Converti de l'hexadecimal en texte
Func __HexToString($sString)
    If StringLeft($sString, 2) <> "0x" Then $sString = "0x" & $sString
    Return BinaryToString($sString)
EndFunc

Func Load($file_open_macro) ;FONCTION CHARGEMENT MACRO
        $file_line = _FileCountLines($file_open_macro)
        $Name_Macro = FileReadLine($file_open_macro,1)
        GUICtrlSetData ( "10", $Name_Macro )
        $Key1 = FileReadLine($file_open_macro,2)
        GUICtrlSetData ( "16", $Key1 )
        $Key2 = FileReadLine($file_open_macro,3)
        GUICtrlSetData ( "17", $Key2 )
        $Name_TXT = FileReadLine($file_open_macro,4)
        GUICtrlSetData ( "15", $Name_TXT )
        Return
    EndFunc


Func load_macro_liste($file_load_macro) ;FONCTION CHARGEMENT MACRO
        $file_line = _FileCountLines($file_load_macro)
        $Name_Macro = FileReadLine($file_load_macro,1)
        GUICtrlSetData ( "10", $Name_Macro )
        $Key1 = FileReadLine($file_load_macro,2)
        GUICtrlSetData ( "16", $Key1 )
        $Key2 = FileReadLine($file_load_macro,3)
        GUICtrlSetData ( "17", $Key2 )
        $Name_TXT = FileReadLine($file_load_macro,4)
        GUICtrlSetData ( "15", $Name_TXT )

        Dim $Array_return_Load[5] = [$file_line,$Name_Macro,$Key1,$Key2,$Name_TXT]

        Return $Array_return_Load
    EndFunc


Func Save($path) ;FONCTION SAUVEGRDE MACRO
        MsgBox(4096, "", "Sauvegarde réussi.")
        _FileCreate($path&".mco")
        FileWrite ( $path&".mco",""&$Name_Macro&@CRLF&$Key1&@CRLF&$Key2&@CRLF&$Name_TXT&@CRLF )
EndFunc

 

Il est un peut massif
Je pense que l'erreur vient de la fonction Load() c'est à partit de là que le premier 1rray est remplis

[mikell]

Bon alors, je suis pas rentré dans le détail mais c'est normal que $Key1 merdoie si tu utilises ce nom de variable pour des tas de choses différentes
Ya du boulot... par exemple ya 2 fonctions 'load' qui font exactement la même chose donc y en a une de trop
Oublie aussi les trucs du genre GuiCtrlSetData("18", $txt) et utilise GuiCtrlSetData($CMB_Macro_liste, $txt) si tu veux t'y retrouver
etc
Enfin ça ça marche déjà mieux

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Misc.au3>
#include <Array.au3>
#include <ComboConstants.au3>


#Region ### START Koda GUI section ### Form=c:\users\lucas\desktop\programmes\autoit\macroman\form1.kxf
Global $Form1_1 = GUICreate("MacroMan", 300, 175, 192, 124)
Global $MenuItem3 = GUICtrlCreateMenu("&Fichier")
Global $MenuItem1 = GUICtrlCreateMenuItem("Ouvrir Macro", $MenuItem3)
Global $MenuItem2 = GUICtrlCreateMenuItem("Ouvrir Macro Liste", $MenuItem3)
Global $MenuItem4 = GUICtrlCreateMenuItem("Sauvegrde", $MenuItem3)
Global $MenuItem5 = GUICtrlCreateMenuItem("Quitter", $MenuItem3)
Global $version = GUICtrlCreateLabel("Version 0.1", 240, 120, 57, 17)
Global $Auteur = GUICtrlCreateLabel("Créer par Lucas", 216, 136, 79, 17)
Global $Name_Input_Macro = GUICtrlCreateInput("Macro1", 72, 8, 121, 21)
Global $LBL_Name_Macro = GUICtrlCreateLabel("Nom Macro :", 8, 10, 65, 17)
Global $LBL_Raccourci_Keyboard = GUICtrlCreateLabel("Raccourci clavier :", 8, 34, 93, 17)
Global $and = GUICtrlCreateLabel("et", 170, 34, 30, 17)
Global $LBL_TXT = GUICtrlCreateLabel("Texte :", 8, 58, 37, 17)
Global $Macro_Input_TXT = GUICtrlCreateInput("Texte", 48, 56, 121, 21)
Global $CMB_Key1 = GUICtrlCreateCombo("", 104, 32, 49, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Ctrl|Alt")
Global $Input2 = GUICtrlCreateInput("", 200, 32, 49, 21)
Global $CMB_Macro_liste = GUICtrlCreateCombo("", 100, 80, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
Global $Label1 = GUICtrlCreateLabel("Liste des macros :", 8, 82, 89, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$docs = @desktopDir
$file_open_macro = ""
$file_line = ""

While 1

    $Name_Macro = GUICtrlRead("10")
;~  $Key1 = GUICtrlRead("16")
;~  $Key2 = GUICtrlRead("17")
    $Name_TXT = GUICtrlRead("15")
    $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
   Exit
    Case $MenuItem5
    $exit = MsgBox(4,"Quitter ?","Si vous quittez le logiciel vos macro ne marcheront plus."&@CRLF&"Continuer ?")
    If $exit = 6 Then
        Exit
    Else
    EndIf
;================================CHARGEMENT======================
    Case $MenuItem1 ;CHARGEMENT D'UNE MACRO
    $file_open_macro = FileOpenDialog ( "Selectionner une macro",""&$docs,"Macro (*.mco)", 2); Ouverture d'un boite de dialoge pour ouvrir une macro
    If @error Then; On test si il y a une erreur, si ce n'est pas le cas on continue
        MsgBox(4096, "", "Aucun fichier n'a pas était ouvert.")
    Else
    Load($file_open_macro)
    EndIf

;==========================================CHARGEMENT LISTE================================
    Case $MenuItem2
        $select_folder = FileSelectFolder("Choisissez un dossier comportenant des macros pour créer une macro liste",@DesktopDir)
        $liste = _FileListToArray($select_folder,"*.mco")
        If @error = 1 Then
    MsgBox(0, "Erreur", "Aucun dossier trouvé !")
        ElseIf @error = 4 Then
    MsgBox(0, "Erreur", "Aucun fichier au format .mco trouvé, création de la macro liste impossible !")
        Else
          Dim $Key1[$liste[0]+1]
          Dim $Key2[$liste[0]+1]
          $txt = "" 
      For $i = 1 to $liste[0]
         $txt &= $liste[$i] & "|"
         $Array_return_Load = load_macro_liste($select_folder &"\"& $liste[$i])
         $Key1[$i] = $Array_return_Load[3]
      Next
        GuiCtrlSetData("18", $txt, $liste[1]) ; combobox

EndIf
_ArrayDisplay($Key1)


    Case $CMB_Macro_liste
        $combo = GUICtrlRead ( "18" )
        $file_open_macro = $select_folder &"\"& $combo ;Lire la combo box
        Load($file_open_macro)




;=========================SAVE===========================
        Case $MenuItem4
    $path = FileSaveDialog("Sauvegrder la Macro",""&$docs,"Macro (*.mco)", 2, $Name_Macro)
If @error Then
    MsgBox(4096, "", "Le fichier n'a pas était sauvegrder.")
    Else
    save($path)
    EndIf






EndSwitch

;~ $Key2 = StringUpper ( $Key2 ) ;transforme la chaine en MAJUSCULE
;~ $Key2 = __StringToHex($Key2) ; transforme la 2e chaine en hexa
;~ $cursor = GUICtrlRead ("16")
;~ If StringCompare($Key1,"Ctrl")=0 Then
;~ $Key1 = "11"
;~ ElseIf StringCompare($Key1,"Alt")=0 Then
;~ $Key1 = "12"
;~ EndIf


;~ Macro($Key1,$Key2)
WEnd




;=======================================FONCTIONS=========================================;
;Utilisation des macros
Func Macro($_Key1,$_Key2)
    If _IsPressed($_Key1) and _IsPressed($_Key2) Then
    send($Name_TXT)
EndIf
EndFunc

;Converti du texte en hexadecimal
Func __StringToHex($sString)
    Return Hex(StringToBinary($sString))
EndFunc

;Converti de l'hexadecimal en texte
Func __HexToString($sString)
    If StringLeft($sString, 2) <> "0x" Then $sString = "0x" & $sString
    Return BinaryToString($sString)
EndFunc

Func Load($file_open_macro) ;FONCTION CHARGEMENT MACRO
        $file_line = _FileCountLines($file_open_macro)
        $Name_Macro = FileReadLine($file_open_macro,1)
        GUICtrlSetData ( "10", $Name_Macro )
        $__Key1 = FileReadLine($file_open_macro,2)
        GUICtrlSetData ( "16", $__Key1 )
        $__Key2 = FileReadLine($file_open_macro,3)
        GUICtrlSetData ( "17", $__Key2 )
        $Name_TXT = FileReadLine($file_open_macro,4)
        GUICtrlSetData ( "15", $Name_TXT )
        Return
    EndFunc


Func load_macro_liste($file_load_macro) ;FONCTION CHARGEMENT MACRO
        $file_line = _FileCountLines($file_load_macro)
        $Name_Macro = FileReadLine($file_load_macro,1)
        GUICtrlSetData ( "10", $Name_Macro )
        $sKey1 = FileReadLine($file_load_macro,2)
        GUICtrlSetData ( "16", $sKey1 )
        $sKey2 = FileReadLine($file_load_macro,3)
        GUICtrlSetData ( "17", $sKey2 )
        $Name_TXT = FileReadLine($file_load_macro,4)
        GUICtrlSetData ( "15", $Name_TXT )

        Local $Array[5] = [$file_line,$Name_Macro,$sKey1,$sKey2,$Name_TXT]
        Return $Array
    EndFunc


Func Save($path) ;FONCTION SAUVEGRDE MACRO
        MsgBox(4096, "", "Sauvegarde réussi.")
        _FileCreate($path&".mco")
        FileWrite ( $path&".mco",""&$Name_Macro&@CRLF&$Key1&@CRLF&$Key2&@CRLF&$Name_TXT&@CRLF )
EndFunc
 

[losutak]

J'essaye ça cette aprem, et en effet la variable jeu était utiliser pour stocker autre chose, pas pour un tableau
Et oui en effet il y a deux fois une fonction load à cause de problème avec les variables de chemin.
Bref, j'essaye ça dans la mâtiné en tous cas Merci !