[R] Vérification de la version d'un outil

[Amesamana]

Bonjour,

Je veux vérifier la version de mon outil est proposer le téléchargement si une nouvelle version est en ligne.

je me suis fait cette function :

► Afficher le texte

Code : Tout sélectionner

Global $VERSION = "2.0"
Func _VERIFIERVERSION()
    Local $TELCHARMENT
    InetGet("http://xxx/Version.txt", @TempDir & "\Version.txt") ; charge le fichier dans @temp@ / Version.txt affiche 2.0
        Local $VVERSION = FileRead(@TempDir & "\Version.txt") ; lire les caractères
        If $VVERSION > $VERSION Then ; comparer la lecture avec la version de l'outil et si version.txt est sup à $VERSION :
            $TELCHARMENT = MsgBox(64+4, "ToolsDiag", "Une nouvelle version est en ligne !" & @CRLF & _
             "Télécharger la nouvelle version.")
             If $TELCHARMENT = 6 Then ; si oui on affiche le lien et si non on affiche l'outil
                 ShellExecute("http://xxx")
                  Exit
              EndIf
          EndIf
      EndIf
  EndFunc
 

Je ne comprends pas pourquoi en ayant les mêmes caractères (2.0) sur version.txt et $VERSION j'ai $TELCHARMENT qui s'affiche, je ne devrait pas !
Si $VERSION passe à 2.1 $TELCHARMENT ne s'affiche pas, logique, mais pourquoi en 2.0 il s'affiche alors que nous avons la même valeur.
En le marquant ainsi je ne devrait pas avoir de soucis ?
If $VVERSION > $VERSION Then
Merci.

[jguinch]

Etonant, ce truc là fonctionne, normalement...

Code : Tout sélectionner

$version = "2.0.0.1"
$newVersion = "2.0.0.3"
If $newVersion > $version Then MsgBox(0, "", "Une nouvelle version est disponible")

Peut-être que tu as essayé ton script plusieurs fois en changeant la valeur dans le fichier Version.txt ?
Du coup, c'est possible que le téléchargement ne se fasse pas car il utilise le cache.
Tu peux forcer le téléchargement avec InetGet :

Code : Tout sélectionner

InetGet("http://xxx/Version.txt", @TempDir & "\Version.txt"[b], 1[/b])

Sinon, tu peux comparer les valeurs en spécifiant qu'il s'agît d'un nombre :

Code : Tout sélectionner

If Number($VVERSION) > Number($VERSION)

...mais du coup, tu ne pourras pas utiliser des versions du style 2.0.1.3

[Tlem]

mais du coup, tu ne pourras pas utiliser des versions du style 2.0.1.3

Il suffit de supprimer les points.

[jguinch]

@tlem : oui, mais non...
Si on doit comparer les versions 2.7.1 et 2.8, ça ne marche plus si on enlève les points.

Edit : si on respecte le même type de versioning, ça marchera

[Tlem]

Oui, mais ....

► Afficher le texte

Code : Tout sélectionner

$Version1 = "2.7.1"
$Version2 = "2.8"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))

$Version1 = "2.7.1"
$Version2 = "2"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))



Func _GreaterVersion($V1, $V2)
    Local $nV1 = StringLeft(StringReplace($V1, ".", "") & "0000",4)
    Local $nV2 = StringLeft(StringReplace($V2, ".", "") & "0000",4)
    If Number($nV1) > Number($nV2) Then
        Return $V1
    Else
        Return $V2
    EndIf
EndFunc

Edit : La fonction peut éventuellement être réduite à :

Code : Tout sélectionner

Func _GreaterVersion($V1, $V2)
    If Number(StringLeft(StringReplace($V1 & "0000", ".", ""),4)) > Number(StringLeft(StringReplace($V2 & "0000", ".", ""),4)) Then
        Return $V1
    Else
        Return $V2
    EndIf
EndFunc

[jguinch]

Oui mais... là ça marche plus :

Code : Tout sélectionner

$Version1 = "2.7.1"
$Version2 = "2.10"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))

On peut faire ça :

► Afficher le texte

Code : Tout sélectionner

Func _GreaterVersion($Version1, $Version2)
    If NOT StringRegExp($Version1, "^\d+(\.?\d+)*$") OR NOT StringRegExp($Version2, "^\d+(\.?\d+)*$") Then Return SetError(1, 0, 0)
    
    
    Local $aSplitV1 = StringSplit($Version1, ".")
    Local $aSplitV2 = StringSplit($Version2, ".")
    
    If $aSplitV1[0] > $aSplitV2[0] Then
        Redim $aSplitV2[ $aSplitV1[0] + 1 ]
        For $i = $aSplitV2[0] + 1 To $aSplitV1[0]
            $aSplitV2[$i] = "0"
        Next
        $aSplitV2[0] = $aSplitV1[0]
    ElseIf $aSplitV1[0] < $aSplitV2[0] Then
        Redim $aSplitV1[ $aSplitV2[0] + 1 ]
        For $i = $aSplitV1[0] + 1 To $aSplitV2[0]
            $aSplitV1[$i] = "0"
        Next
        $aSplitV1[0] = $aSplitV2[0]
    EndIf
    
    For $i = 1 To $aSplitV1[0]
        If Number($aSplitV1[$i]) > Number($aSplitV2[$i]) Then
            Return $Version1
        ElseIf Number($aSplitV2[$i]) > Number($aSplitV1[$i]) Then 
            Return $Version2
        EndIf
    Next
    Return 0
EndFunc

[Tlem]

Oui mais... là ça marche plus

Rhooo.
Mais effectivement.

Ton code semble ok, mais n'est-il pas judicieux de le simplifier à ceci :

► Afficher le texte

Code : Tout sélectionner

$Version1 = "2.7.1"
$Version2 = "2.8"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))

$Version1 = "2.7.1"
$Version2 = "2"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))

$Version1 = "2.10"
$Version2 = "2.1"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))

$Version1 = "0.1.10.106"
$Version2 = "0.1"
MsgBox(32, "La plus grande version", _GreaterVersion($Version1, $Version2))


Func _GreaterVersion($Version1, $Version2)
    If NOT StringRegExp($Version1, "^\d+(\.?\d+)*$") OR NOT StringRegExp($Version2, "^\d+(\.?\d+)*$") Then Return SetError(1, 0, 0)

    Local $aSplitV1 = StringSplit(StringLeft($Version1 & ".0.0.0.0", 7), ".")
    Local $aSplitV2 = StringSplit(StringLeft($Version2 & ".0.0.0.0", 7), ".")

    For $i = 1 To UBound($aSplitV1) - 1
        If $aSplitV1[$i] > $aSplitV2[$i] Then
            Return $Version1
        ElseIf $aSplitV2[$i] > $aSplitV1[$i] Then
            Return $Version2
        EndIf
    Next
    Return $Version1
EndFunc

[jchd]

Si on exclut les cas pathologiques où un développeur fou crée plus de 10000 versions à un niveau donné, on peut encore simplifier :

► Afficher le texte

Code : Tout sélectionner

Local $Version1, $Version2, $v1, $v2
$Version1 = "2.7.1"
$Version2 = "2.8"
$v1 = _PgmVersion($Version1)
$v2 = _PgmVersion($Version2)
MsgBox(32, "La plus grande version", $Version1 & @LF & $Version2 & @LF & @LF & ($v1 > $v2 ? $v1 : $v2))

$Version1 = "2.7.1"
$Version2 = "2"
$v1 = _PgmVersion($Version1)
$v2 = _PgmVersion($Version2)
MsgBox(32, "La plus grande version", $Version1 & @LF & $Version2 & @LF & @LF & ($v1 > $v2 ? $v1 : $v2))

$Version1 = "2.10"
$Version2 = "2.1"
$v1 = _PgmVersion($Version1)
$v2 = _PgmVersion($Version2)
MsgBox(32, "La plus grande version", $Version1 & @LF & $Version2 & @LF & @LF & ($v1 > $v2 ? $v1 : $v2))

$Version1 = "0.1.10.106"
$Version2 = "0.1"
$v1 = _PgmVersion($Version1)
$v2 = _PgmVersion($Version2)
MsgBox(32, "La plus grande version", $Version1 & @LF & $Version2 & @LF & @LF & ($v1 > $v2 ? $v1 : $v2))

Func _PgmVersion($s)
    Return(Execute(StringRegExpReplace($s, "(\d+)(\.)?", "StringFormat('%04u', \1) & ") & "''"))
EndFunc
 

[jguinch]

JC, tu m'as foutu la honte
Une seule ligne...

Bref, si Amesamana pouvait nous dire si ça lui va ?

[jchd]

Mais non, reste positif : j'ai soumis une idée qui pourra te servir dans d'autres contextes.

[Tlem]

JC, tu m'as foutu la honte

Je ne suis pas tout à fait d'accord. En fait JC triche légèrement puisqu'il utilise quelque chose qui n'est pas encore sorti en version finale !
De plus la fonction ne compare pas deux n° de version. Elle se contente de modifier une chaine. Il faut ensuite rajouter un traitement pour déterminer quel version est la plus élevée ...

Pour une fonction équivalente à celles proposées, ceci correspondrait mieux :

Code : Tout sélectionner

Func _PgmVersion($v1, $v2)
    Local $nv1 = (Execute(StringRegExpReplace($v1, "(\d+)(\.)?", "StringFormat('%04u', \1) & ") & "''"))
    Local $nv2 = (Execute(StringRegExpReplace($v2, "(\d+)(\.)?", "StringFormat('%04u', \1) & ") & "''"))
    Return ($nv1 > $nv2 ? $V1 : $V2)
EndFunc

Et là, ce n'est plus 1 lignes, mais 3. Bon, il faut saluer la performance quand même.

Ceci dit, non seulement pour utiliser ce code il faut une version minimale d'AutoIt qui gère l'opérateur ternaire, mais en plus ce n'est pas rétro-compatible.
Donc un "Require AutoIt version 3.9.x" aurait été bien vu.

[jchd]

A cette heure-là, tout est flou, hein !
Ceci dit, l'opérateur ternaire n'est là que pour l'affichage.

On peut aussi tout simplement employer _VersionCompare()

[Tlem]

On peut aussi tout simplement employer _VersionCompare()

Haaa ben voilà, il me semblait bien que je l'avais déjà vu ça quelque part celui-là !!!

[Mode mauvaise foi ON]
Bon, ceci dit, _VersionCompare() fait 31 lignes (19 lignes si on exclu la comparaison par chaîne et la gestion du séparateur) et oblige un Include ...
[Mode mauvaise foi OFF]

Ceci dit, l'opérateur ternaire n'est là que pour l'affichage.

Oui et non. Sans l'opérateur ternaire, tu ne peux déterminer lequel des arguments est plus grand.

[Amesamana]

Bonjour à tous,

Merci pour vos réponses, je vais regarder tout ça

Bon, ceci dit, _VersionCompare() fait 31 lignes (19 lignes si on exclu la comparaison par chaîne et la gestion du séparateur) et oblige un Include ...

Oblige un Include, est-ce un soucis ?
_VersionCompare() fait 31 lignes => je vais rechercher
Dans mon fichier de base j'ai ajouté :

Code : Tout sélectionner

#AutoIt3Wrapper_Res_Fileversion=2.0
#include <Version.au3>
_VERIFVERSION()

J'ai essayé d'inclure cette fi=unstion directement dans mon code de dase mais idem.
Mais tout de même pas logique car ma function ne devrait pas poser de soucis.
J'ai bien vidé mon cache, et vérifié si dans @Temp@ la version était bien celle désiré, mais idem.

Je me penche sur vos réponse est revient vers vous.

Merci.

[Tlem]

Pour _VersionCompare(), il faut inclure le fichier Misc.au3.
Ouvrez celui-ci et regardez comment fonctionne cette fonction car elle permet de comparer deux version en retournant des valeurs tel que 1, -1 ou 0.

[jguinch]

Tu as lu mon premier post à propos de InetGet ?

[Amesamana]

Oui j'ai rajouté le 1 pour forcer le téléchargement, mais idem
J'ai même essayé avec 2.0.0.0

Ces deux valeurs sont bien reconnus.
Pas logique tout ça car ma fonction devrait marcher.
J'ai vider le cache mais idem, je surveille bien mon version.txt dans @temp@ change quand je fais le modif mais idem ?

Je ne saisi pas vraiment pourquoi avec une valeur égale j'ai :

Même si je télécharge d'un autre PC.
Je regarde du côté de Misc.au3

[jguinch]

En partant du morceau de code (qui ne fonctionne pas ) que tu avais mis dans ton premier post, j'ai essayé de reproduire le problème : chez moi ça marche plutôt bien.
J'ai squeezé l'étape du InetGet et créé le fichier Version.txt dans le même répertoire que le script. Tout se passe normalement.

Est-ce que tu peux essayer ce code chez toi, avec le fichier Version.txt dans le répertoire du script ? Si tu n'as pas le problème avec ce code, c'est qu'il y a un problème dans ton script original.

► Afficher le texte

Code : Tout sélectionner

Global $VERSION = "2.0"

_VERIFIERVERSION()

Func _VERIFIERVERSION()
    Local $TELCHARMENT
    ;InetGet("http://xxx/Version.txt", @TempDir & "\Version.txt") ; charge le fichier dans @temp@ / Version.txt affiche 2.0
    Local $VVERSION = FileRead("Version.txt") ; lire les caractères
    If $VVERSION > $VERSION Then ; comparer la lecture avec la version de l'outil et si version.txt est sup à $VERSION :
        $TELCHARMENT = MsgBox(64+4, "ToolsDiag", "Une nouvelle version est en ligne !" & @CRLF & _
        "Télécharger la nouvelle version.")
        If $TELCHARMENT = 6 Then ; si oui on affiche le lien et si non on affiche l'outil
            ShellExecute("http://xxx")
            Exit
        EndIf
    EndIf
EndFunc

Edit (pour Thierry)

Ton code semble ok, mais n'est-il pas judicieux de le simplifier à ceci

Je rêve : Tlem m'a tutoyé ! Ils annoncent de la neige ces prochains jours ?
A+

[Amesamana]

Bonjour,

Désolé pour cette réponse tardive.

J'ai donc essayé sans inetGet mais idem !
J'ai bien un fichier version.txt dans mon répertoire de l'outil.

J'avoue ne pas comprendre pourquoi ce script ne marche pas !

Merci pour l'aide

[mikell]

Je ne saisi pas vraiment pourquoi avec une valeur égale j'ai ...

Attention, avec les codes précédents (même celui de jchd) si une version se termine par .0 la comparaison est faussée
Faut donc introduire un petit ajustement pour zapper les trailing zeros indésirables

► Afficher le texte

Code : Tout sélectionner

$Version1 = "2.7.1"
$Version2 = "2.8"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

$Version1 = "2.7.1"
$Version2 = "2"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

$Version1 = "2.10"
$Version2 = "2.1"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

$Version1 = "0.1.10.106"
$Version2 = "0.1"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

$Version1 = "2.01.8.0"
$Version2 = "2.0.8"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

$Version1 = "2.8.0.0.0"     [color=#FF0000];<<<<<<<<<<[/color]
$Version2 = "2.8"
MsgBox(32, "La plus grande version", _PgmVersion($Version1, $Version2))

Func _PgmVersion($v1, $v2)
    Local $nv1 = (Execute(StringRegExpReplace($v1, "(\d+)(\.)?", "StringFormat('%04u', \1) & ") & "''"))
      $nv1 = StringRegExpReplace($nv1, "(0{4})*$", "") 
    Local $nv2 = (Execute(StringRegExpReplace($v2, "(\d+)(\.)?", "StringFormat('%04u', \1) & ") & "''"))
      $nv2 = StringRegExpReplace($nv2, "(0{4})*$", "")
    If $nv1 > $nv2 Then 
       Return $v1
    ElseIf $nv1 < $nv2 Then 
       Return $v2
    Else
       Return "egal"
    EndIf
EndFunc