[R] Modifier dynamiquement la valeur d'un champ de saisie

[Sachadee]

Bonjour,

j'ai créé un formulaire type :

Code : Tout sélectionner

...
#CEP
$label11 = GUICtrlCreateLabel("CEP - [ Só N° ]", 812, 195, 100, 33)
$CEP = GUICtrlCreateInput("CEP", 810, 210, 100, 21)
#Endereço
$label8 = GUICtrlCreateLabel("Endereço", 26, 150, 100, 33)
$Endereco = GUICtrlCreateInput("Endereço", 24, 165, 780, 21, 0x0008)
#Bairro
$label12 = GUICtrlCreateLabel("Bairro", 26, 240, 100, 33)
$Bairro = GUICtrlCreateInput("Bairro", 24, 255, 400, 21, 0x0008)
#Cidade
$label13 = GUICtrlCreateLabel("Cidade", 432, 240, 100, 33)
$Cidade = GUICtrlCreateInput("Cidade", 430, 255, 400, 21, 0x0008)
#UF
$label4 = GUICtrlCreateLabel("UF", 860, 240, 30, 33)
$UF = GUICtrlCreateCombo("UF", 862, 255, 50, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "AC|AL|AP|AM|BA|CE|DF|ES|GO|MA|MT|MS|MG|PA|PB|PR|PE|PI|RJ|RN|RS|RO|RR|SC|SP|SE|TO")
$Gerar = GUICtrlCreateButton("Gerar Cadastro", 410, 348, 105, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
      Case $GUI_EVENT_CLOSE
            Exit    
      Case $Gerar
      suite...
    EndSwitch
WEnd

J'aimerais que lorsque l'utilisateur remplie le champ CEP et fasse un tab ou passe sur un autre champ avec la souris le script me lançe automatiquement ma fonction de recuperation de l'adresse et remplisse les champs dynamiquement (endereco, bairro, cidade, Uf).

Est-ce possible ?

D'avance merci

[mikell]

Bien sûr, mais vaudrait mieux un bouton + GUISetAccelerators (pour la touche, mais je déconseille la touche TAB qui est une touche système de navigation dans la gui)
Le hover sur un autre champ c'est pas génial (mais ça peut se faire)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>

GuiCreate("test", 1000, 500)
#CEP
$label11 = GUICtrlCreateLabel("CEP - [ Só N° ]", 812, 195, 100, 23)
$CEP = GUICtrlCreateInput("CEP", 810, 210, 100, 21)
#Endereço
$label8 = GUICtrlCreateLabel("Endereço", 26, 150, 100, 23)
$Endereco = GUICtrlCreateInput("Endereço", 24, 165, 780, 21, 0x0008)
GUICtrlSetState(-1, $GUI_DISABLE)
#Bairro
$label12 = GUICtrlCreateLabel("Bairro", 26, 240, 100, 23)
$Bairro = GUICtrlCreateInput("Bairro", 24, 255, 400, 21, 0x0008)
GUICtrlSetState(-1, $GUI_DISABLE)
#Cidade
$label13 = GUICtrlCreateLabel("Cidade", 432, 240, 100, 23)
$Cidade = GUICtrlCreateInput("Cidade", 430, 255, 400, 21, 0x0008)
GUICtrlSetState(-1, $GUI_DISABLE)
#UF
$label4 = GUICtrlCreateLabel("UF", 860, 240, 30, 33)
$UF = GUICtrlCreateCombo("UF", 862, 255, 50, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "AC|AL|AP|AM|BA|CE|DF|ES|GO|MA|MT|MS|MG|PA|PB|PR|PE|PI|RJ|RN|RS|RO|RR|SC|SP|SE|TO")
GUICtrlSetState(-1, $GUI_DISABLE)
$Gerar = GUICtrlCreateButton("Gerar Cadastro", 410, 348, 105, 33)
GUISetState(@SW_SHOW)

Local $AccelKeys[1][2] = [["{tab}", $Gerar]]
GUISetAccelerators($AccelKeys)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
      Case $GUI_EVENT_CLOSE
            Exit   
      Case $Gerar
         _test()
    ;  suite...
    EndSwitch
WEnd


Func _test()
Local $str = _
'  <td> <span itemprop="postalCode">53131200</span></td>'  &@crlf& _
'  <td> <span itemprop="streetAddress"> Avenida Antonio Castro  - até 715/716</span></td>' &@crlf& _
'  <td> Cajueiro</td>' &@crlf& _
'  <td> <span itemprop="addressLocality">Vitoria</span></td>' &@crlf& _
'  <td> <span itemprop="addressRegion">PE</span></td>'

$res = StringRegExp($str, '<td>\s*(?:<span.*?>)?([^<-]+)', 3)
If IsArray($res) Then
    GUICtrlSetState($Endereco, $GUI_ENABLE)
    GUICtrlSetState($Bairro, $GUI_ENABLE)
    GUICtrlSetState($Cidade, $GUI_ENABLE)
    GUICtrlSetState($UF, $GUI_ENABLE)
    ;$cep=$res[0]
    GuiCtrlSetData($Endereco, StringStripWS($res[1], 3))
    GuiCtrlSetData($Bairro, $res[2])
    GuiCtrlSetData($Cidade, $res[3])
    GuiCtrlSetData($UF, $res[4])
EndIf
EndFunc
 

[Sachadee]

Excellent,

Un grand merci à toi, je commence vraiment à être impressioné par Autoit3 et par
tes compètences.

Je vais adapter mon code en conséquence.


A+

[TommyDDR]

Ou si vous voulez vous amuser avec les Messages Windows :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

Global $Input[2]

Global $Gui = GUICreate("test", 300, 55)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $Gui)
$Input[0] = GUICtrlCreateInput("", 5, 5, 290, 20)
$Input[1] = GUICtrlCreateInput("", 5, 30, 290, 20)
GUICtrlSetState($Input[1], $GUI_DISABLE)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While(True)
    Sleep(10)
WEnd

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
;~  768 = onChange (input)
;~  512 = onBlur (changement de champ)
;~  256 = (un)checked (checkbox)
;~  1 = onChange (combo)
;~  0 = (un)checked (radio)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    If($nNotifyCode = 768) Then
        Switch $nID
            Case $Input[0]
                Local $Texte = GUICtrlRead($Input[0])
;~              On peut faire ce qu'on veut ici
;~              exemple :
                $Texte = StringUpper($Texte)

                GUICtrlSetData($Input[1], $Texte)
        EndSwitch
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Func quit()
    Exit
EndFunc

[Sachadee]

Ou si vous voulez vous amuser avec les Messages Windows :

Merci TommyDDR,
C'est du super dynamique.

Avec la solution de mikell, j'ai mis un bouton [Chercher] qui va lancer ma recherche (Le TAB étant effectivement pas recommandé dans mon cas).

Je vais faire un test avec ta méthode en testant la taille du string [$tesxte] et lancer ma recherche lorsque j'ai la bonne taille,
je pourrai ainsi supprimer le bouton [Chercher].

Encore un grand merci à vous !