[R] Problème de remplissage array

[mikell]

Si je te le dis
Maintenant si je te suggère de regarder l'ancien script c'est pas pour des prunes
Par exemple si tous les controles à modifier sont dans une gui child, c'est quand même plus simple, surtout si tu fais des fonctions ^^

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListviewConstants.au3>
#Include <Array.au3>
Opt("MouseCoordMode", 2)
Opt("GUIOnEventMode", 1)

Global $Hcourbe = 400, $Wcourbe = 600, $left = 40 
Global $array[1][2], $a, $max_x, $max_y, $g, $my_file, $fichierOK = false
Global $hGui, $child, $bord_sup, $bord_D, $coeffV, $coeffH, $LV, $LVitem

_BuildZeMainGui()
_OpenAndLoadAllZeStuff()

While 1
   _Display()
   Sleep(10)
Wend


;============================================
Func _OpenAndLoadAllZeStuff()
   $my_file = _ChouzeFile()
   $fichierOK = false
   Dim $array[1][2] = [["", ""]]   
  _BuildZeArrays()
  _BuildZeChildGui()
EndFunc


Func _ReInitZeGrafik()
   If WinExists("courbe") Then GuiDelete($child)
   GUICtrlSetData($LVitem, " | | ")
  _OpenAndLoadAllZeStuff()
EndFunc


Func _ChouzeFile()
  Local $var = FileOpenDialog("Choisir un fichier...", @ScriptDir & "\", "TXT (*.txt)", 1)
  If @error Then Return
  Return $var
EndFunc


Func _BuildZeMainGui()
$hGui = GUICreate("Graph", $left+$Wcourbe+60, $Hcourbe+90, -1, 30)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$open = GuiCtrlCreateButton("ouvrir", $left+$Wcourbe+10, 20, 40, 20)
GUICtrlSetOnEvent(-1, "_ReInitZeGrafik")
;== listview
$LV = GuiCtrlCreateListview(" | | ", $left+100, $Hcourbe+40, 250, 35, _ 
                $LVS_NOCOLUMNHEADER, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 80)
GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 2, 80)
GuiCtrlCreateListViewItem("index|mm|kN|", $LV)
$LVitem = GuiCtrlCreateListViewItem(" | | ", $LV)
GUISetState()
EndFunc


Func _BuildZeArrays()
$file = FileRead($my_file)
$res = StringRegExp($file, '([\d.]+;\h*[\d.]+)', 3)
If not IsArray($res) Then 
   $fichierOK = false
   Return Msgbox(0,"", "mauvais fichier")
EndIf
$fichierOK = true
ReDim $array[UBound($res)][2]
For $i = 0 to UBound($res)-1
  $split = StringRegExp($res[$i], '[\d.]+', 3)
  $array[$i][0] = $split[0]
  $array[$i][1] = $split[1]
Next
;_ArrayDisplay($array)
;;== valeurs extrêmes
$max_x = _ArrayMaxOrMin($array, "max", 1)
; $min_x = _ArrayMaxOrMin($array, "min", 1)
$max_y = _ArrayMaxOrMin($array, "max", 2)
; $min_y = _ArrayMaxOrMin($array, "min", 2)
;msgbox(0,"", "$min_x = " & $min_x &@crlf& _ 
;       "$max_x = " & $max_x &@crlf&@crlf& _ 
;       "$min_y = " & $min_y &@crlf& _ 
;       "$max_y = " & $max_y ) 
;;== échelle verticale
; Local $bord_inf = 0
$na = Number(StringLen(Int($max_y))-1)
$b = 10^$na
$bord_sup = Ceiling($max_y/$b)*$b 
$middleV = $bord_sup/2  
$coeffV = $Hcourbe/$bord_sup
;;== échelle horizontale
; Local $bord_G = 0
$bord_D = Ceiling($max_x)
$middleH = ($bord_D)/2  
$coeffH = $Wcourbe/$bord_D
;;== array pour les coordonnées sur le graphique
Dim $a[UBound($res)][2]
For $i = 0 to UBound($res)-1   
  $a[$i][0] = $array[$i][0]*$coeffH
  $a[$i][1] = $Hcourbe - $array[$i][1]*$coeffV
Next
;_ArrayDisplay($a)
EndFunc


Func _BuildZeChildGui()
If $fichierOK = false Then Return
$child = GUICreate("courbe", $left+$Wcourbe+5, $Hcourbe+30, 0, 0, $WS_POPUP, _
              BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $hGui)
;== affichage de l'échelle y
Local $na = Number(StringLen(Int($bord_sup))-1)
Local $b = 10^$na
$n = 0
For $i = 0 to $bord_sup step $b/2     
  GuiCtrlCreateLabel("", 0, $Hcourbe-$i*$coeffV+3, $left, 17, 2)
  GuiCtrlSetFont(-1, 8, 400, 0, "Arial Unicode MS")
  GuiCtrlSetData(-1, Round($i, 2) & " " & ChrW(9472) )
  GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$n += 1
  If $i>0 AND $i<$bord_sup Then
     GuiCtrlCreateLabel("", $left, $Hcourbe-$i*$coeffV+10, $Wcourbe, 1)
     GUICtrlSetBkColor(-1, 0xaaaaff)
  EndIf
Next
;msgbox(0,"", $bord_sup &@crlf& $b/2 &@crlf& $n &@crlf& $bord_sup/($b/2)+1)

;== affichage du y maxi
For $i = 0 to UBound($array)-1     
  If $array[$i][1] = $max_y Then
    GuiCtrlCreateLabel("max_y = " &$array[$i][0] &" x "& $max_y, _ 
                    $left+10, $Hcourbe-$max_y*$coeffV-5, 120, 15)
    GUICtrlSetBkColor(-1, 0xeeeeff)
    GUICtrlSetColor(-1, 0xff0000)
    GuiCtrlCreateLabel("", $left, $Hcourbe-$max_y*$coeffV+9, $Wcourbe, 1)
    GUICtrlSetBkColor(-1, 0xffaaaa)
  EndIf
Next
;== affichage de l'échelle x
Local $na = Number(StringLen(Int($bord_D))-1)
Local $b = 10^$na
For $i = 0 to $bord_D step $b    
  GuiCtrlCreateLabel("I", $left+$i*$coeffH, $Hcourbe+10-1, 2, 10, 1)
  GuiCtrlCreateLabel($i, $left+$i*$coeffH-4, $Hcourbe+10+8, 10, 12, 1)
  GuiCtrlSetFont(-1, 8, 400, 0, "Arial Unicode MS")
  GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Next
;== graphique
$g = GUICtrlCreateGraphic($left, 10, $Wcourbe, $Hcourbe)
GUICtrlSetBkColor(-1, 0xeeeeff)
GUICtrlSetColor(-1, 0)
GUICtrlSetGraphic($g, $GUI_GR_MOVE, $a[0][0], $a[0][1])
GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 2)
For $i = 0 to UBound($a)-1
   GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
   GUICtrlSetGraphic($g, $GUI_GR_LINE, $a[$i][0], $a[$i][1])
Next
GUISetState()
EndFunc


Func _Exit()
  Exit
EndFunc


Func _Display()
If $fichierOK = false Then Return
Local $j = "", $tolerance = 2  
Local $b = GUIGetCursorInfo($child)
;If @error Then Return
If $b[4] = $g Then
  Local $pos = MouseGetPos()
  For $i = 0 to UBound($a)-1
     If $pos[0]-$left>$a[$i][0]-$tolerance AND $pos[0]-$left<$a[$i][0]+$tolerance AND _ 
        $pos[1]-10>$a[$i][1]-$tolerance AND $pos[1]-10<$a[$i][1]+$tolerance Then 
         Do
              $pos2 = MouseGetPos()
              If $array[$i][0]<>$j Then
                  ToolTip($array[$i][0] &" x "& $array[$i][1])
                  GUICtrlSetData($LVitem, $i &"|"& $array[$i][0] &"|"& $array[$i][1])
                  $j = $array[$i][0]
             EndIf
         Until $pos[0]<$pos2[0]-$tolerance OR $pos[0]>$pos2[0]+$tolerance OR  _
            $pos[1]<$pos2[1]-$tolerance OR $pos[1]>$pos2[1]+$tolerance 
         ToolTip("")
    EndIf
  Next
EndIf
EndFunc


Func _ArrayMaxOrMin($avArray, $op = "max", $iCol = 1)
Local $iIndex = 0, $iRows = UBound($avArray), $iDims = UBound($avArray, 0)
If $op = "max" Then $op = "<"
If $op = "min" Then $op = ">"
Switch $iDims
   Case 1   ; 1D
    For $i = 0 To $iRows-1
        If Execute(Number($avArray[$iIndex]) &$op& Number($avArray[$i])) Then $iIndex = $i
    Next
    Return $avArray[$iIndex]
   Case 2  ; 2D
    For $i = 0 To $iRows-1
        If Execute(Number($avArray[$iIndex][$iCol-1]) &$op& _ 
                Number($avArray[$i][$iCol-1])) Then $iIndex = $i
    Next
    ;Local $Ret[2]
    ;$Ret[0] = $avArray[$iIndex][0]
    ;$Ret[1] = $avArray[$iIndex][$iCol-1]
    ;Return $Ret
    Return $avArray[$iIndex][$iCol-1]
EndSwitch
EndFunc 
 

[Hugues]

Je te joins mon code (en partie) fonction principal qui ouvre et trace le graphique, car je n'utilise plus l'autre, je suis parti sur une base differente... Ca évitera trop de messages ^^

► Afficher le texte

Code : Tout sélectionner

Func _FileOpen()
    $Open = _FTP_Open("MyAutoItFTP")
    $Conn = _FTP_Connect($Open, $server, $sLogin, $sPassword, 1, $iPortHelp)
    If $conn = 0 Then
        MsgBox(0,"Retour de connexion:", @error & @LF & @extended)
    EndIf

    Local $h_File = _FTP_FileOpen($Conn, "/Caulking/" & $IDLine & "/" & $Sxx_xx & "/" & $FileToOpen)
    $Size = 10000000
    $HEX = _FTP_FileRead($h_File, $Size)
    $preread = _HexToString($HEX)
    _FTP_Close($Conn)

;==[Lecture du fichier]==================================================================================================
    $n = 0
    $res = StringRegExp($preread, "(-?\d+(?:[.,]\d*)?\h*);\h*(-?\d+(?:[.,]\d*)?)", 3, StringInStr($preread, "'mm';'kN'"))
    $Display = $preread
    ;_RemplissageEdit()
    If NOT IsArray($res) OR IsFloat(Ubound($res)) Then
        MsgBox(16, "Erreur", "Pas de données pour tracer une courbe.")
        Return
    EndIf

    Global $array[UBound($res)][2]
    For $i = 0 to UBound($res)-1 Step 2
        $array[$n][0] = $res[$i]
        $array[$n][1] = $res[$i + 1]
    $n += 1
    Next

    ;==[Valeurs extrêmes]====================
    $max_x = _ArrayMaxOrMin($array, "max", 1)
    $max_y = _ArrayMaxOrMin($array, "max", 2)

    ;Global $Hcourbe = 400
    ;Global $Wcourbe = 600
    ;Global $left = 30

    ;==[Echelle verticale]================
    $na = Number(StringLen(Int($max_y))-1)
    $b = 10^$na
    $bord_sup = Ceiling($max_y/$b)*$b   ;Local $bord_sup
    $middleV = $bord_sup/2
    $coeffV = $Hcourbe/$bord_sup

    ;==[Echelle horizontale]=======
    $bord_D = Ceiling($max_x)   ;Local $bord_D
    $middleH = ($bord_D)/2
    $coeffH = $Wcourbe/$bord_D

    ;==[Array pour les coordonnées sur le graphique]====
    Dim $a[UBound($res)/2][2]

    For $i = 0 to (UBound($res)/2)-1
        $a[$i][0] = $array[$i][0]*$coeffH
        $a[$i][1] = $Hcourbe - $array[$i][1]*$coeffV
    Next
    ;_ArrayDisplay($a)

    ;==[Affichage de l'échelle y]==================
    $na = Number(StringLen(Int($bord_sup))-1)   ;Local $na
    $b = 10^$na ;Local $b

    For $i = 0 to $bord_sup step $b/2
        GuiCtrlCreateLabel("", 0, $Hcourbe-$i*$coeffV+3, $left, 20, 2)
        GuiCtrlSetFont(-1, 8, 400, 0, "Tahoma")
        GuiCtrlSetData(-1, Round($i, 2) & " " & ChrW(9472) )
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        If $i>0 AND $i<$bord_sup Then
            GuiCtrlCreateLabel("", $left, $Hcourbe-$i*$coeffV+10, $Wcourbe, 1)
            GUICtrlSetBkColor(-1, 0xaaaaff)
        EndIf
    Next

    ;==[Affichage du y maxi]======
    For $i = 0 to UBound($array)-1
        If $array[$i][1] = $max_y Then
            $MaxXY = GuiCtrlCreateLabel("Course: " & $array[$i][0] & "mm | Effort MAXI: " & $max_y, $left+10, $Hcourbe-$max_y*$coeffV-5, 220, 15)
                GUICtrlSetBkColor($MaxXY, 0xeeeeff)
                GUICtrlSetColor($MaxXY, 0xff0000)
            $aMaxXY = GuiCtrlCreateLabel("", $left, $Hcourbe-$max_y*$coeffV+9, $Wcourbe, 1)
                GUICtrlSetBkColor($aMaxXY, 0xffaaaa)
        EndIf
    Next

    ;==[Affichage de l'échelle x]================
    $na = Number(StringLen(Int($bord_D))-1);Local
    $b = 10^$na ;Local

Dim $aEchxM[$bord_D]

    For $i = 0 to $bord_D Step $b
        $aEchxM = GuiCtrlCreateLabel("I", $left+$i*$coeffH, $Hcourbe+10-1, 2, 10, 1)
        $aEchx = GuiCtrlCreateLabel($i, $left+$i*$coeffH-4, $Hcourbe+10+8, 15, 15, 1)
        $aEchxSF = GuiCtrlSetFont($aEchx, 8, 400, 0, "Tahoma")
        $aEchxSBC = GUICtrlSetBkColor($aEchx, $GUI_BKCOLOR_TRANSPARENT)
    Next

    ;==[Graphique]====
    $g = GUICtrlCreateGraphic($left, 10, $Wcourbe, $Hcourbe)
    GUICtrlSetBkColor(-1, 0xffffff)
    GUICtrlSetColor(-1, 0)
    GUICtrlSetGraphic($g, $GUI_GR_MOVE, $a[0][0], $a[0][1])
    GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 2)

    For $i = 0 to UBound($a)-1
        GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
        GUICtrlSetGraphic($g, $GUI_GR_LINE, $a[$i][0], $a[$i][1])
    Next

    ;==[Listview]=====
    $LV = GuiCtrlCreateListview(" | ", $left+100, $Hcourbe+40, 180, 55, $LVS_NOCOLUMNHEADER, $LVS_EX_GRIDLINES)
    GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 80)
    GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 80)
    GuiCtrlCreateListViewItem("Course|Effort", $LV)
    $LVitem = GuiCtrlCreateListViewItem(" | ", $LV)
    GUISetState()
EndFunc

Func _ArrayMaxOrMin($avArray, $op = "max", $iCol = 1)
    Local $iIndex = 0, $iRows = UBound($avArray), $iDims = UBound($avArray, 0)
    If $op = "max" Then $op = "<"
    If $op = "min" Then $op = ">"
    Switch $iDims
        Case 1   ; 1D
        For $i = 0 To $iRows-1
            If Execute(Number($avArray[$iIndex]) &$op& Number($avArray[$i])) Then $iIndex = $i
        Next
        Return $avArray[$iIndex]
        Case 2  ; 2D
        For $i = 0 To $iRows-1
            If Execute(Number($avArray[$iIndex][$iCol-1]) &$op& Number($avArray[$i][$iCol-1])) Then $iIndex = $i
        Next
        ;Local $Ret[2]
        ;$Ret[0] = $avArray[$iIndex][0]
        ;$Ret[1] = $avArray[$iIndex][$iCol-1]
        ;Return $Ret
        Return $avArray[$iIndex][$iCol-1]
    EndSwitch
EndFunc
 

[mikell]

Heu tu comprends bien que je vais pas me taper un nouveau script à chaque fois que tu modifies la mise en forme, eh ?
Ton problème est très simple, c'est juste une question d'organisation (et de boulot) :
- ou tu mets tous les controles dans une gui child dédiée à l'affichage ce qui permet de tout détruire/recréer d'un coup (comme dans mon code précédent)
- ou tu mets tout dans une seule gui mais dans ce cas tu dois gérer la destruction/recréation des controles, par exemple avec des arrays comme ça

Code : Tout sélectionner

;== création échelle v
Dim $labels_echelle_v[$bord_sup/($b/2)+1]
$n = 0
For $i = 0 to $bord_sup step $b/2     
    $labels_echelle_v[$n] = GuiCtrlCreateLabel("", 0, $Hcourbe-$i*$coeffV+3, $left, 20, 2)
    ;....
    $n += 1
Next
;== destruction
For $i = 0 to UBound($labels_echelle_v)-1
   GuiCtrlDelete($labels_echelle_v[$i])
Next

[Hugues]

Oui c'est sûr que tu n'as pas à te taper un script différent à chaque fois... Et c'est bien normal, à moi de chercher un p'tit peu

Je vais essayer avec les 2 versions ça va m'occuper

Merci de ton aide!

A bientôt...

[Hugues]

Coucou, me revoilà...

Alors j'ai remanié mon programme comme tu me l'a vivement conseillé

Par contre, je n'arrive pas à effacer le GUI "Child" sur lequel est tracé la courbe pfff

J'ai mon GUI principal:

► Afficher le texte

Code : Tout sélectionner

Func _BuildTheMainGui()
        Global $MainGUI = GUICreate("Mon GUI PRINCIPAL", 1201, 861, 195, 70)
......
......
EndFunc

Mon GUI Graphique:

► Afficher le texte

Code : Tout sélectionner

Func _BuildTheCurve()
Global $child = GUICreate("", 169, 68, 20, 20, $WS_POPUP, BitOR($WS_POPUP, $WS_CLIPSIBLINGS), $MainGUI)
.....
.....
EndFunc
 

Alors pour effacer le graphique, je fais:

► Afficher le texte

Code : Tout sélectionner

Func _ClearTheCurve()
If WinExists($child) Then GUIDelete($child)
EndFunc
 

Mais ça me ferme le GUI principal???

[mikell]

Vaut mieux déclarer les variables en Global en tête de script et en-dehors des fonctions
Et si tu mets des styles à la place des exstyles tu peux avoir des 'unexpected results'

Code : Tout sélectionner

$child = GUICreate("", 169, 68, 20, 20, $WS_POPUP, [color=#FF0000]BitOR($WS_POPUP, $WS_CLIPSIBLINGS)[/color], $MainGUI)
$child = GUICreate("courbe", 169, 68, 20, 20, $WS_POPUP, BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $MainGUI)

Difficile d'en dire plus sans voir le reste du script (par exemple une possible erreur ailleurs qui peut entrainer un Exit) mais si tu suis l'architecture du code de mon post précédent (en haut de la page) tu ne devrais pas avoir de problème

[Tlem]

Basé sur vos informations, ce script fonctionne :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $MainGUI, $child

TrayTip("", "Affichage de la GUI principale.", 3)
_BuildTheMainGui()
Sleep(3000)
TrayTip("", "Affichage de la GUI fille.", 3)
_BuildTheCurve()
Sleep(2000)
TrayTip("", "Suppression de la GUI fille.", 3)
_ClearTheCurve()
Sleep(2000)
TrayTip("", "Fermeture du script.", 3)
Sleep(3000)
Exit

Func _BuildTheMainGui()
    $MainGUI = GUICreate("Mon GUI PRINCIPAL", 400, 400, -1, -1)
    GUICtrlCreateLabel("GUI Principale", 25, 5, 186, 27)
    GUICtrlSetFont(-1, 16, 800, 0, "Courier New")
    GUISetState(@SW_SHOW)
EndFunc

Func _BuildTheCurve()
    ;Global $child = GUICreate("", 200, 100, -1, -1,  $WS_POPUP, BitOR($WS_POPUP, $WS_CLIPSIBLINGS), $MainGUI)
    $child = GUICreate("", 200, 100, -1, -1, BitOR($WS_POPUP, $WS_CLIPSIBLINGS), -1, $MainGUI)
    GUISetBkColor(0xFF00FF)
    GUICtrlCreateLabel("GUI Fille", 25, 5, 186, 27)
    GUICtrlSetFont(-1, 16, 800, 0, "Courier New")
    GUISetState(@SW_SHOW)
EndFunc

Func _ClearTheCurve()
    If WinExists($child) Then GUIDelete($child)
EndFunc

Regardez si votre problème ne vient pas des styles affectés à votre GUI fille. Le $WS_POPUP en trop peut être.
Et déclarez vos variables globales en tête de script et non dans des fonctions => risque de message d'erreur et gestion moins simple.

Edit : Grillé par Michel. :'(

[Hugues]

Merci pour vos réponses, mais je dois vraiment être idiot...
J'ai beau y tourner dans tout les sens, il y a toujours quelque chose qui ne fonctionne pas...

Je vous joint mon code "presque complet" car j'ai enlevé une partie du code qui contient des données sensibles ^^, mais la structure est complète.

Je suis vraiment désolé de vous faire perdre votre temps...

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Include <File.au3>
#include <Array.au3>
#include <SliderConstants.au3>
#include <ListviewConstants.au3>
#include <ScreenCapture.au3>
#include <GuiTreeView.au3>
#include <FTPEx.au3>
#include <String.au3>
#include <Date.au3>
#include <GuiListView.au3>
#include <ArrayEx.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Opt("MouseCoordMode", 2)
$Debug_LV = False ;

;==[Définition variables Globales]==================================
Global $MainGUI, $child, $IDLine, $Sxx_xx, $server, $aFTPFileList, $sRemotePath, $sHost, $iFlag, $sLogin, $sPassword, $iPassive, $iPort, $iPortHelp, $aFind, $CellName, $FileToOpen, $hConnect
Global $g, $a, $LVitem, $hGUI, $aItems, $IndexItemListView, $Display, $hImage, $Sxx_xx, $MaxXY, $aMaxXY, $aEchx, $aEchxSF , $aEchxSBC, $aEchxM, $na, $b, $bord_D, $bord_sup
Global $Hcourbe = 400, $Wcourbe = 600, $left = 30, $coeffH, $Path, $Open, $conn, $pos2, $preread, $Label8, $Child, $coeffV, $array, $max_y, $NoCurveToTrace = False
Global $echx, $echx2, $HelpEff, $HelpEff2,  $MON_CHEMIN, $MON_FICHIER_FTP_A_LIRE

_BuildTheMainGui()

Func _BuildTheMainGui() ;==[Construction du GUI principal]====
    $MainGUI = GUICreate("Mon GUI General", 1201, 861, 195, 70)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Global $Group1 = GUICtrlCreateGroup("Infos:", 1016, 0, 177, 129)
    Global $Group2 = GUICtrlCreateGroup("Selection:", 1016, 136, 177, 401)
    Global $Group3 = GUICtrlCreateGroup("Etat connexion:", 1016, 744, 177, 105)
    Global $Group4 = GUICtrlCreateGroup("Description:", 664, 536, 337, 313)
    Global $Label1 = GUICtrlCreateLabel("Nom PC:", 1024, 24, 56, 20)
    Global $Label2 = GUICtrlCreateLabel(@ComputerName, 1024, 40, 161, 20, $SS_CENTER)
    Global $Label3 = GUICtrlCreateLabel("Adresse IP PC:", 1024, 56, 100, 20)
    Global $Label4 = GUICtrlCreateLabel(@IPAddress1, 1024, 72, 160, 20, $SS_CENTER)
    Global $Label5 = GUICtrlCreateLabel("User:", 1024, 88, 38, 20)
    Global $Label6 = GUICtrlCreateLabel(@UserName, 1024, 104, 163, 20, $SS_CENTER)
    Global $Label7 = GUICtrlCreateLabel("Nom serveur:", 1024, 768, 91, 20)
    Global $Label10 = GUICtrlCreateLabel("", 672, 568, 320, 35)
    Global $Edit1 = GUICtrlCreateEdit("", 664, 8, 337, 529, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_READONLY, $ES_WANTRETURN))

;==[Définition arborescence TreeView (Potentiellement améliorable par une architecture auto du serveur]======
    Global $TreeView1 = GUICtrlCreateTreeView(1024, 160, 161, 337)
    Global $TreeView1_0 = GUICtrlCreateTreeViewItem("Dossier", $TreeView1)
    Global $TreeView1_1 = GUICtrlCreateTreeViewItem("Dossier1", $TreeView1_0)
    Global $TreeView1_2 = GUICtrlCreateTreeViewItem("Dossier2", $TreeView1_1)
    ;etc....
    Global $TreeView1_24 = GUICtrlCreateTreeViewItem("Dossier3", $TreeView1)
    Global $TreeView1_25 = GUICtrlCreateTreeViewItem("Dossier4", $TreeView1_24)
    Global $TreeView1_26 = GUICtrlCreateTreeViewItem("Dossier5", $TreeView1_25)
    ;etc...

    Global $Valider = GUICtrlCreateButton("Valider", 1024, 504, 161, 25)
    GUICtrlSetOnEvent($Valider, "_FindTheFiles")

;==[ListView]=====================
    Global $ListView1 = GUICtrlCreateListView("Nom|Date|Taille (Octet)", 8, 544, 649, 305, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($ListView1, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    _GUICtrlListView_SetColumnWidth($ListView1, 0, 200)
    _GUICtrlListView_SetColumnWidth($ListView1, 1, 200)
    _GUICtrlListView_SetColumnWidth($ListView1, 2, 200)
    GUICtrlSetCursor ($ListView1, 0)
    GUICtrlSetCursor ($TreeView1, 0)
    GUICtrlSetCursor ($Valider, 0)

;==[Définition des Polices et Fonts]===================================
    GUICtrlSetFont($Group1, 8, 400, 0, "Tahoma")
    GUICtrlSetFont($Label1, 8, 800, 0, "Tahoma")
    GUICtrlSetFont($Label3, 8, 800, 0, "Tahoma")
    GUICtrlSetFont($Label5, 8, 800, 0, "Tahoma")
    GUICtrlSetFont($Group2, 8, 400, 0, "Tahoma")
    GUICtrlSetFont($Group3, 8, 400, 0, "Tahoma")
    GUICtrlSetFont($Label7, 8, 800, 0, "Tahoma")
    GUICtrlSetFont($ListView1, 8, 400, 0, "Tahoma")
    GUICtrlSetFont($Group4, 8, 400, 0, "Tahoma")
    GUISetState(@SW_SHOW, $MainGUI)

    _CreateNormalImageList()
    _GUICtrlTreeView_SetNormalImageList($TreeView1, $hImage)
EndFunc

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Func _FindTheFiles()
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListView1))
    Global $item = GUICtrlRead($TreeView1) ; Get the controlID of the current selected treeview item
    If $item = 0 Then
        MsgBox(64, "", "Selectionner le produit.")
    Else
        Global $text = GUICtrlRead($item, 1) ; Get the text of the treeview item
        If $text == "" Then
            MsgBox(16, "Erreur", "Erreur sur retour info Item")
        Else
            Global $toto = _GUICtrlTreeView_GetTree($TreeView1, $item)
            Global $DecomposeTreeView = StringSplit($toto, '|', 1)
            If $DecomposeTreeView[0] = 1 Then
                    MsgBox(16, "Administrateur", "Veuillez selectionner une ligne!")
                ElseIf $DecomposeTreeView[0] = 2 And $DecomposeTreeView[1] <> "Courbes OK" Then
                    MsgBox(16, "Administrateur", "Veuillez selectionner une station!")
                ElseIf $DecomposeTreeView[0] = 2 And $DecomposeTreeView[1] = "Courbes OK" Then
                    _DefinitionChemin()
                    $Label8 = GUICtrlCreateLabel($server, 1024, 784, 161, 20, $SS_CENTER)
                ElseIf $DecomposeTreeView[0] = 3 And $DecomposeTreeView[1] <> "Courbes OK" Then
                    _DefinitionChemin()
                    $Label8 = GUICtrlCreateLabel($server, 1024, 784, 161, 20, $SS_CENTER)
            EndIf
        EndIf
    EndIf
EndFunc

Func _DefinitionChemin() ;==[Définition du chemin en fonction du choix dans le TreeView]=====
    
    ;Ici la concordance entre l'architecture de ma TreeView et celle des dossiers sur mon serveur....
    ;Je n'ai rien mis ici car données privées ^^

GUICtrlSetData($Label10, $DecomposeTreeView[1] & " " & $DecomposeTreeView[2] & " " & $DecomposeTreeView[3] & " - " & $CellName)
_Connexion()
EndFunc

Func _Connexion()
Global $aListFTP[1][4], $Output, $aFile
    _FTP_Download($aListFTP, $MON_CHEMIN, $server, 1)

;==[ Remplissage des champs "Station", "Nom" et "Date" de la ListView $ListView1 ]====
Local $NbreFichier =  UBound($aListFTP) - 1
If $NbreFichier = 0 Then
    MsgBox(64, "", "Aucune courbe disponible.")
Else

Dim $aItems[$NbreFichier][3]
For $iI = 0 To UBound($aItems)-1
    $aItems[$iI][0] = $aListFTP[$iI+1][1]
    $aItems[$iI][1] = $aListFTP[$iI+1][2]
    $aItems[$iI][2] = $aListFTP[$iI+1][3]
Next
_GUICtrlListView_AddArray($ListView1, $aItems)
EndIF

;==[ On charge le(s) image(s) ]====
$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 0)

;==[On affecte le(s) image(s) }====
_GUICtrlListView_SetImageList($ListView1, $hImage, 1)

If UBound($aFTPFileList) - 1 <> "0" then
GUICtrlSetData(GUICtrlCreateLabel("", 672, 600, 320, 20), UBound($aListFTP) - 1 & " fichier(s) trouvé(s)")
Else
GUICtrlSetData(GUICtrlCreateLabel("", 672, 600, 320, 20), "Aucun fichier trouvé")
Endif
EndFunc

Func _FTP_Download(ByRef $aFTPFileList, $sRemotePath, $sHost, $iFlag, $sLogin = "LOGIN", $sPassword = "PASSWORD", $iPassive = 1, $iPort = $iPortHelp)
    Local $hFtp, $hSession, $aFind, $hFind, $Result = 1
    $hFtp = _FTP_Open("MyAutoItFTP")
    $hSession = _FTP_Connect($hFtp, $sHost, $sLogin, $sPassword, $iPassive, $iPort)
    $aFind = _FTP_FindFileFirst($hSession, $sRemotePath, $hFind)

    While Not @error
        $Path = $sRemotePath & '/' & $aFind[10]
        If BitAND($aFind[1], $FILE_ATTRIBUTE_DIRECTORY) Then
            If Not _FTP_Download($aFTPFileList, $sRemotePath & '/' & $aFind[10], $sHost, $sLogin, $sPassword, $iPassive, $iPort) Then
                Return 0
            EndIf
            If $iFlag = 0 Or $iFlag = 2 Then
                Local $iUBound = UBound($aFTPFileList)
                ReDim $aFTPFileList[$iUBound + 1][4]
                $aFTPFileList[$iUBound][0] = $sRemotePath & '/' & $aFind[10] & '/'
                $aFTPFileList[$iUBound][0] = $aFind[10]; & '/'
            EndIf
        Else
            If $iFlag = 0 Or $iFlag = 1 Then
                Local $iUBound = UBound($aFTPFileList)
                ReDim $aFTPFileList[$iUBound + 1][4]
                $aFTPFileList[$iUBound][1] = $aFind[10]; & '/'
                $aFTPFileList[$iUBound][2] = _FTPFileTimeLoHiToStr($aFind[6], $aFind[7])
                $aFTPFileList[$iUBound][3] = _FTPFileSizeLoHi($aFind[8], $aFind[9])
            EndIf
        EndIf
        $aFind = _FTP_FindFileNext($hFind)
    WEnd
    _FTP_FindFileClose($hFind)
    _FTP_Close($hFtp)
    $aFTPFileList[0][0] = UBound($aFTPFileList) - 1
    Return $Result
EndFunc   ;==>_FTP_Download

Func _FTPFileTimeLoHiToStr($LoDWORD, $HiDWORD)
    Local $FileTime = DllStructCreate("dword;dword")
    If Not $LoDWORD And Not $HiDWORD Then Return SetError(1, 0, "")
    DllStructSetData($FileTime, 1, $LoDWORD)
    DllStructSetData($FileTime, 2, $HiDWORD)
    Local $date = _Date_Time_FileTimeToStr($FileTime,1)
    Return SetError(@error, @extended, $date)
EndFunc

Func _FTPFileSizeLoHi($LoDWORD, $HiDWORD)
    Return BitOR(BitShift($LoDWORD, -32), BitAND($HiDWORD, 0xFFFFFFFF))
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    Local $tBuffer
    $hWndListView = $ListView1
    If Not IsHWnd($ListView1) Then $hWndListView = GUICtrlGetHandle($ListView1)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    $NoCurveToTrace = False
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    _EffacementEdit()
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    If _GUICtrlListView_GetNextItem($ListView1) = -1 Then
                        Return
                    Else
                        $IndexItemListView = _GUICtrlListView_GetNextItem($ListView1)
                        $FileToOpen = _GUICtrlListView_GetItemText($ListView1, $IndexItemListView)
                        _OpenAndLoadAll()
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _EffacementEdit() ;==[Effacement contenu de l'Edit (Aperçu de mon fichier)]====
    GUICtrlSetData($Edit1, "")
EndFunc

Func _OpenAndLoadAll()
    _BuildTheArrays() ;== Construction des mes Arrays

    If $NoCurveToTrace = False Then ;Si courbe à tracer alors car données trouvées dans le fichier lu
        _BuildTheCurve()
    Else
        _ClearTheCurve() ;J'efface l'ancienne courbe...
        Return
    EndIf
EndFunc

Func _BuildTheArrays()
    $Open = _FTP_Open("MyAutoItFTP")
    $Conn = _FTP_Connect($Open, $server, $sLogin, $sPassword, 1, $iPortHelp)
    If $conn = 0 Then
        MsgBox(0,"Retour de connexion:", @error & @LF & @extended)
    EndIf

    Local $h_File = _FTP_FileOpen($Conn, $MON_FICHIER_FTP_A_LIRE)
    Local $Size = 10000000
    Local $HEX = _FTP_FileRead($h_File, $Size)
    $preread = _HexToString($HEX)
    _FTP_Close($Conn)

;==[Lecture du fichier]==================================================================================================
    Global $res = StringRegExp($preread, "(-?\d+(?:[.,]\d*)?\h*);\h*(-?\d+(?:[.,]\d*)?)", 3, StringInStr($preread, "'mm';'kN'"))
    $Display = $preread

    If NOT IsArray($res) OR IsFloat(Ubound($res)) Then
        MsgBox(16, "", "Pas de données pour tracer une courbe.")
        $NoCurveToTrace = True
        _RemplissageEdit() ;Je remplis mon Edit avec les données avant la ligne 'mm';'kN' de mon fichier...
        Return
    EndIf

    Local $n = 0
    Global $array[UBound($res)][2]
    For $i = 0 to UBound($res)-1 Step 2
        $array[$n][0] = $res[$i]
        $array[$n][1] = $res[$i + 1]
    $n += 1
    Next

;==[Valeurs extrêmes]====================
    Global $max_x = _ArrayMaxOrMin($array, "max", 1)
    Global $max_y = _ArrayMaxOrMin($array, "max", 2)

;==[Echelle verticale]================
    $na = Number(StringLen(Int($max_y))-1)
    $b = 10^$na
    $bord_sup = Ceiling($max_y/$b)*$b   ;Local $bord_sup
    Local $middleV = $bord_sup/2
    $coeffV = $Hcourbe/$bord_sup

;==[Echelle horizontale]=======
    $bord_D = Ceiling($max_x)   ;Local $bord_D
    Local $middleH = ($bord_D)/2
    $coeffH = $Wcourbe/$bord_D

;==[Array pour les coordonnées sur le graphique]====
    Dim $a[UBound($res)/2][2]

    For $i = 0 to (UBound($res)/2)-1
        $a[$i][0] = $array[$i][0]*$coeffH
        $a[$i][1] = $Hcourbe - $array[$i][1]*$coeffV
    Next
_RemplissageEdit()
EndFunc

Func _BuildTheCurve() ;==[Création de mon Graphique]====
    $child = GUICreate("Curve", $Wcourbe+$left, $Hcourbe+100, 0, 0, $WS_POPUP, BitOR($WS_EX_MDICHILD, $WS_EX_COMPOSITED), $MainGUI)
;==[Affichage de l'échelle y]==================
    $na = Number(StringLen(Int($bord_sup))-1)   ;Local $na
    $b = 10^$na ;Local $b

    For $i = 0 to $bord_sup step $b/2
        $HelpEff = GuiCtrlCreateLabel("", 0, $Hcourbe-$i*$coeffV+3, $left, 20, 2)
        GuiCtrlSetFont($HelpEff, 8, 400, 0, "Tahoma")
        GuiCtrlSetData($HelpEff, Round($i, 2) & " " & ChrW(9472) )
        GUICtrlSetBkColor($HelpEff, $GUI_BKCOLOR_TRANSPARENT)
        If $i>0 AND $i<$bord_sup Then
        $HelpEff2 = GuiCtrlCreateLabel("", $left, $Hcourbe-$i*$coeffV+10, $Wcourbe, 1)
        GUICtrlSetBkColor($HelpEff2, 0xaaaaff)
        EndIf
    Next

;==[Affichage du y maxi]======
    For $i = 0 to UBound($array)-1
        If $array[$i][1] = $max_y Then
            $MaxXY = GuiCtrlCreateLabel("Course: " & $array[$i][0] & "mm | Effort MAXI: " & $max_y, $left+10, $Hcourbe-$max_y*$coeffV-5, 250, 15)
                GUICtrlSetBkColor($MaxXY, 0xeeeeff)
                GUICtrlSetColor($MaxXY, 0xff0000)
            $aMaxXY = GuiCtrlCreateLabel("", $left, $Hcourbe-$max_y*$coeffV+9, $Wcourbe, 1)
                GUICtrlSetBkColor($aMaxXY, 0xffaaaa)
        EndIf
    Next

;==[Affichage de l'échelle x]================
    $na = Number(StringLen(Int($bord_D))-1);Local
    $b = 10^$na ;Local

    For $i = 0 to $bord_D Step $b
        $echx = GuiCtrlCreateLabel("I", $left+$i*$coeffH, $Hcourbe+10-1, 2, 10, 1)
        $echx2 = GuiCtrlCreateLabel($i, $left+$i*$coeffH-4, $Hcourbe+10+8, 15, 15, 1)
        GuiCtrlSetFont(-1, 8, 400, 0, "Tahoma")
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    Next

;==[Graphique]====
    $g = GUICtrlCreateGraphic($left, 10, $Wcourbe, $Hcourbe)
    GUICtrlSetBkColor($g, 0xffffff)
    GUICtrlSetColor($g, 0)
    GUICtrlSetGraphic($g, $GUI_GR_MOVE, $a[0][0], $a[0][1])
    GUICtrlSetGraphic($g, $GUI_GR_PENSIZE, 2)

    For $i = 0 to UBound($a)-1
        GUICtrlSetGraphic($g, $GUI_GR_COLOR, 0xff)
        GUICtrlSetGraphic($g, $GUI_GR_LINE, $a[$i][0], $a[$i][1])
    Next

;==[Listview]=====
    Local $LV = GuiCtrlCreateListview(" | ", $left+100, $Hcourbe+40, 170, 60, BitOR($GUI_SS_DEFAULT_LISTVIEW,$LVS_NOCOLUMNHEADER,$WS_BORDER), BitOR($WS_EX_CLIENTEDGE,$LVS_EX_GRIDLINES))

    GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 0, 80)
    GUICtrlSendMsg($LV, $LVM_SETCOLUMNWIDTH, 1, 80)
    GuiCtrlCreateListViewItem("Course|Effort", $LV)
    $LVitem = GuiCtrlCreateListViewItem(" | ", $LV)
GUISetState()
EndFunc

Func _RemplissageEdit()
    Local $aString = _StringToArray2D($Display, @CRLF, ";", 1)
    ;UBound($aString) -> Nombre de ligne de $aString
    Local $l = 0
    local $sSearch = "'mm'"
    Local $iIndex = _ArraySearch($aString, $sSearch, 0, 0, 0, 1)

    For $i = 0 to $iIndex - 1
        GUICtrlSetData($Edit1, $aString[$i][0] & $aString[$i][1] & $aString[$i][2] & @CRLF, $Edit1)
    Next

EndFunc

Func _ArrayMaxOrMin($avArray, $op = "max", $iCol = 1)
    Local $iIndex = 0, $iRows = UBound($avArray), $iDims = UBound($avArray, 0)
    If $op = "max" Then $op = "<"
    If $op = "min" Then $op = ">"
    Switch $iDims
        Case 1   ; 1D
        For $i = 0 To $iRows-1
            If Execute(Number($avArray[$iIndex]) &$op& Number($avArray[$i])) Then $iIndex = $i
        Next
        Return $avArray[$iIndex]
        Case 2  ; 2D
        For $i = 0 To $iRows-1
            If Execute(Number($avArray[$iIndex][$iCol-1]) &$op& Number($avArray[$i][$iCol-1])) Then $iIndex = $i
        Next
        Return $avArray[$iIndex][$iCol-1]
    EndSwitch
EndFunc

Do
    If WinExists($child) And $NoCurveToTrace = False Then
    _Display()
    Sleep(10)
Else
    EndIf
Until GUIGetMsg($MainGUI) = $GUI_EVENT_CLOSE

Func _CreateNormalImageList()   ;==[Définition des images pour dossier(s) TreeView]====
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 3)
EndFunc   ;==>_CreateNormalImageList

Func _Exit();==[Fonction Exit]====
    Exit
EndFunc

Func _Display()
If $NoCurveToTrace = False And WinExists($child) Then
    Local $j = "", $tolerance = 2
    Local $b = GUIGetCursorInfo($child)
    If $b[4] = $g Then
    Local $pos = MouseGetPos()
    For $i = 0 to UBound($a)-1
        If $pos[0]-$left>$a[$i][0]-$tolerance AND $pos[0]-$left<$a[$i][0]+$tolerance AND _
            $pos[1]-10>$a[$i][1]-$tolerance AND $pos[1]-10<$a[$i][1]+$tolerance Then
            Do
                $pos2 = MouseGetPos()
                If $array[$i][0]<>$j Then
                    ToolTip($array[$i][0] & " x " & $array[$i][1])
                    GUICtrlSetData($LVitem, $array[$i][0] & "|" & $array[$i][1])
                    $j = $array[$i][0]
                EndIf
            Until $pos[0]<$pos2[0]-$tolerance OR $pos[0]>$pos2[0]+$tolerance OR  _
                $pos[1]<$pos2[1]-$tolerance OR $pos[1]>$pos2[1]+$tolerance
            ToolTip("")
        EndIf
    Next
EndIf
EndIf
EndFunc

Func _ClearTheCurve() ;==[Effacement du GUI Courbe]====
    If (WinExists($child) And $NoCurveToTrace = False) Then GUIDelete($child)
EndFunc

[mikell]

Tu aurais pas le même qui fonctionnerait avec un fichier local ? c'est pas testable là
BTW en mode onevent GUIGetMsg ne marche pas (j'ai fait la même erreur dans mon code, faut mettre un While)

Code : Tout sélectionner

While 1
    If WinExists($child) And $NoCurveToTrace = False Then
    _Display()
    Sleep(10)
  EndIf
Wend

[Hugues]

Je comprends plus rien ^^.

Si j'ouvre un fichier et qu'il n'y a pas de données pour tracer une courbe avec

Code : Tout sélectionner

If WinExists($child) Then GUIDelete($child)

ça ferme mon GUI général, mais pas l'application...

Si j'ouvre un fichier avec des données, ma courbe est bien tracé cooool,
Si j'ouvre après un fichier qui n'a pas de données pour tracer des courbes, ça supprime bien mon ancien graphique...

En fait je crois et suis sur que les graphique se superposent ^^ car quand j'ouvre de fichier avec données ca me trace bien mes courbes et si dans la foulée j'ouvre un fichier sans données ça me réaffiche mon grahique precedent...

Je sais pas si je me suis bien exprimé...

[mikell]

Tes problèmes ont plusieurs causes
- si la gui fille n'est pas créée, $child = "", ta condition devient 'If WinExists("") Then ...' ce qui est toujours vrai et dans ce cas le GuiDelete va fermer la dernière gui utilisée, la principale (default is the previous used)
Un petit test marrant

Code : Tout sélectionner

Local $var = WinList(), $n = 0
For $i = 1 To $var[0][0]
    If $var[$i][0] = "" Then $n += 1
Next
MsgBox(0, "Details", "Il y a actuellement " & $n & " fenêtres sans titre ouvertes")

solution : If WinExists("titre_de_la_gui_fille") Then GUIDelete($child)
- gestion d'erreur et réinitialisation : le script conserve des données et les réutilise même en cas d'erreur
solution : penser à vider l'array de données, et introduire un booléen pour valider la reconstruction de l'array et de la gui après lecture du fichier

Pour info... j'ai édité le code ici http://www.autoitscript.fr/forum/viewto ... 013#p81013 pour y mettre la gestion d'erreur adéquate (variable-test $fichierOK et vidage de l'ancienne array) que j'avoue n'avoir pas faite initialement vu que ce n'était qu'un code de démo

[Hugues]

YES! J'ai fais un joli "pot pourri" et ça fonctionne. Le graphique s'efface bien maintenant!
Un grand merci à toi et à Tlem (normalement je n'ai oublié personne ^^)
Je peux dire RESOLU.

UN GRAND MERCI