[R] Image sous forme d'astuce

[Eyyon]

Salut, j'ai vraiment besoin d'aide pour créer une image sous forme d'astuce...
Je ne sais pas trop comment le formuler mais en gros, je voudrais que lorsque je passe le curseur sur une image, elle apparaît directement sous forme agrandie, comme une boîte d'astuce.
Je pourrais donner l'exemple de Pipix qui affiche une image lorsque je passe le curseur sur une radio.
Merci de vos futures réponses!

[mikell]

Un très bel exemple ici
http://www.autoitscript.com/forum/topic ... try1041041

[Eyyon]

Euh... J'ai pas trop compris son script ^^"
Vous pourriez me faire une breve explication? Merci d'avance
PS: c'est effectivement le résultat que je cherche, mais sans la bande noire sous l'image, celle qui indique quelques propriétés de l'image

[mikell]

OK
J'ai simplifié le script
L'idée c'est de surveiller la position du curseur avec GuiGetCursorInfo, et de montrer la gui qui affiche l'image quand le curseur passe sur l'input
Le script est complexe parce que UEZ a choisi une image au format png, avec un jpg ou bmp ou gif le script serait *beaucoup* plus simple

► Afficher le texte

Code : Tout sélectionner

;coded by UEZ 2012
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()

Global $sPathKey = "HKLM64\SOFTWARE\AutoIt v3\AutoIt\"
If @OSArch = "x64" Then $sPathKey = "HKLM\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt\"
Global $sImage2 = RegRead($sPathKey, "InstallDir") & "\Examples\GUI\Torus.png"

Global $aMouseInfo, $aPosCtrl, $aPosWin, $hBmp_Tmp, $sFile, $bShow = False, $bHide = False
Global $hGui_PreviewSize = 200, $iBGColor = 0xF0F0F0

$hGUI = GUICreate("Test", 300, 100)
$iInput = GUICtrlCreateInput($sImage2, 20, 60, 200, 20)
$iBtn = GUICtrlCreateButton("Exit", 240, 26, 50, 50)

$hGui_Preview = GUICreate("", $hGui_PreviewSize, $hGui_PreviewSize, -1, -1, $WS_POPUP + $WS_BORDER, $WS_EX_TOPMOST, $hGUI)
$idPic = GUICtrlCreatePic("", 0, 0, $hGui_PreviewSize, $hGui_PreviewSize)
GUISetState(@SW_HIDE, $hGui_Preview)
GUISetState(@SW_SHOW, $hGUI)
ControlFocus($hGUI, "", $iBtn)

Do
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $iBtn
            If $hBmp_Tmp Then _WinAPI_DeleteObject($hBmp_Tmp)
            _GDIPlus_Shutdown()
            GUIDelete($hGui_Preview)
            GUIDelete($hGUI)
            Exit
    EndSwitch
    If WinActive($hGUI) Then
        $aMouseInfo = GUIGetCursorInfo($hGUI)
        Switch $aMouseInfo[4]
            Case $iInput
                $sFile = GUICtrlRead($iInput)
                If FileExists($sFile) And Not $bShow Then
                    ShowPreview($sFile, $iInput)
                    $bShow = True
                    $bHide = False
                EndIf
            Case Else
                If Not $bHide Then
                    GUISetState(@SW_HIDE, $hGui_Preview)
                    $bHide = True
                EndIf
                $bShow = False
        EndSwitch
    EndIf
Until False

Func ShowPreview($sFile, $iCtrl)
    $aPosWin = WinGetPos($hGUI)
    $aPosCtrl = ControlGetPos($hGUI, "", $iCtrl)
    WinMove($hGui_Preview, "", $aPosWin[0] + $aPosCtrl[0] + $aPosCtrl[2], $aPosWin[1] + $aPosCtrl[1] + $aPosCtrl[3])
    $hBmp_Tmp = _GetImage($sFile, $hGui_PreviewSize, $iBGColor)
    _hBmpToPicControl($idPic, $hBmp_Tmp, 1)
    GUISetState(@SW_SHOWNOACTIVATE, $hGui_Preview)
EndFunc   ;==>ShowPreview

Func _GetImage($sFile, $iWH, $iBkClr = 0xFFFFFF)
    Local $hBmp1, $hBitmap, $hGraphic, $hImage, $iW, $iH, $aGS, $hBmp2
    If @error Then Return SetError(1, 0, 0)
    $hBmp1 = _WinAPI_CreateBitmap($iWH, $iWH, 1, 32)
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp1)
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _WinAPI_DeleteObject($hBmp1)
    _GDIPlus_GraphicsClear($hGraphic, BitOR(0xFF000000, $iBkClr))
    $hImage = _GDIPlus_ImageLoadFromFile($sFile)
    $iW = _GDIPlus_ImageGetWidth($hImage)
    $iH = _GDIPlus_ImageGetHeight($hImage)
    $aGS = _GetScale($iW, $iH, $iWH)
    _GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, $aGS[0], $aGS[1], $aGS[2], $aGS[3])
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphic)
    $hBmp2 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
    _GDIPlus_BitmapDispose($hBitmap)
    Return $hBmp2
EndFunc   ;==>_GetImage

Func _GetScale($iW, $iH, $iWH)
    Local $aRet[4]
    If $iW <= $iWH And $iH <= $iWH Then
        $aRet[2] = $iW
        $aRet[3] = $iH
        $aRet[0] = ($iWH - $aRet[2]) / 2
        $aRet[1] = ($iWH - $aRet[3]) / 2
    ElseIf $iW > $iH Then
        $aRet[2] = $iWH
        $aRet[3] = $iH / ($iW / $iWH)
        $aRet[0] = 0
        $aRet[1] = ($iWH - $aRet[3]) / 2
    ElseIf $iW < $iH Then
        $aRet[2] = $iW / ($iH / $iWH)
        $aRet[3] = $iWH
        $aRet[0] = ($iWH - $aRet[2]) / 2
        $aRet[1] = 0
    ElseIf $iW = $iH Then
        $aRet[2] = $iWH
        $aRet[3] = $iWH
        $aRet[0] = 0
        $aRet[1] = 0
    EndIf
    Return $aRet
EndFunc   ;==>_GetScale

Func _hBmpToPicControl($iCID, ByRef $hBmp, $iFlag = 0)
    Local Const $STM_SETIMAGE = 0x0172
    Local Const $IMAGE_BITMAP = 0
    Local $hOldBmp
    $hOldBmp = GUICtrlSendMsg($iCID, $STM_SETIMAGE, $IMAGE_BITMAP, $hBmp)
    If $hOldBmp Then _WinAPI_DeleteObject($hOldBmp)
    If $iFlag Then _WinAPI_DeleteObject($hBmp)
EndFunc   ;==>_hBmpToPicControl

[Eyyon]

Merci pour l'aide^^ mais...
Il y a besoin de tout ce script entier juste pour faire apparaître et disparaître une image?
Et l'input est remplaçable par une picture?

[mikell]

On peut faire ça sur n'importe quel controle, et un script volumineux n'est pas un problème

[Eyyon]

oké merci, sujet résulute