[..] Calcul entre 2 dates

[moons]

Bonjour
je début en programmation et je viens de trouver votre script autoit Age des rats je le trouve bien cependant pour ma part j'aurai besoin de juste faire le calcul entre 2 date et je n'arrive pas a comprendre quel est la partie du script qui me permettrais de récupérer que le calcul entre les 2 dates

merci par avance pour la réponse

[mikell]

Post déplacé dans un nouveau sujet
Pour une question comme ça faut poster dans l'aide générale, pas répondre à un exemple de script vieux de 4 ans

[TopXm]

Hello

Je te poste un exemple de calcul entre deux dates.

► Afficher le texteCalcul de date

Code : Tout sélectionner

#include <Date.au3>
;
; Calcul de date
;
Local $Date1 = '20/01/2013'
Local $Date2 = '31/05/2013'

; On convertit les dates au format YYYY/MM/DD
Local $Rev1 = _DateStandardToCalcDate($Date1)
If @error Then
    MsgBox(0, '', 'Erreur de Format de date : ' & $Date1)
    Exit
EndIf

Local $Rev2 = _DateStandardToCalcDate($Date2)
If @error Then
    MsgBox(0, '', 'Erreur de Format de date : ' & $Date2)
    Exit
EndIf

; Calcul de date : Nombre de jours entre les 2 dates
Local $Calc = _DateDiff('d', $Rev1, $Rev2)
ConsoleWrite('Nombre de jours entre les 2 dates : ' & $Calc & @CRLF)

; Calcul de date : Nombre de semaines entre les 2 dates
$Calc = _DateDiff('w', $Rev1, $Rev2)
ConsoleWrite('Nombre de semaines entre les 2 dates : ' & $Calc & @CRLF)

;  _ConvertFrenchToCalcDate() : Convert dd/mm/yyyy => yyyy/mm/dd        ;
Func _DateStandardToCalcDate($sDate)
    If Not StringRegExp($sDate, "^\d{2}\/\d{2}\/\d{4}$") Then Return SetError(1, 0)
    Local $ArrD = StringSplit($sDate, '/')
    If $ArrD[0] <> 3 Then Return SetError(2, 0)
    Return $ArrD[3] & '/' & $ArrD[2] & '/' & $ArrD[1]
EndFunc   ;==>_DateStandardToCalcDate
 

[moons]

merci pour la réponse elle va m’être très utile