[R] Problème GUICtrlCreateContextMenu + icone

[Ghost911]

bonjour alors voila mon problème du menu avec icône enfaîte tout marche le problème c'est que cela crée un bug que je cherche à résoudre quand je clique sur Le Windows1 que je fais clique droit ça marche on voit les menus le problème c'est quand je ferme Windows1 que je clique sur Le Windows2 que je fais ensuite clique droit pour voir les menus cela m'affiche les icônes de Windows1 sur Windows2 tous rentre en conflit des fois les menus se mélange c'est un peu le bordel j'ai mis le script à télécharger si quelqu'un a une petite idée pour résoudre ce problème

[kalvine]

bonjour de mon coter j'ai le même problème que toi sinon il faudrait trouver un autre udf pour les icônes ou trouver une méthode pour mettre plusieurs icone au context menu

[GaRydelaMer]

Bonjour

d’où l'intérêt de déclarer les variables !!!

► Afficher le texte

Code : Tout sélectionner

#include "ModernMenuRaw.au3"
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
;#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
Global $Form, $Menu, $Form1, $Menu1, $Form2, $Menu2, $Form3, $Menu3

gui()

While 1
    Sleep(10)
WEnd

Func Guiclose()
    Switch @GUI_WinHandle
        Case $Form1
            _GUICtrlODMenuItemDelete($Menu1)
        Case $Form2
            _GUICtrlODMenuItemDelete($Menu2)
        Case $Form3
            _GUICtrlODMenuItemDelete($Menu3)
    EndSwitch


    GUIDelete(@GUI_WinHandle)
    If @GUI_WinHandle = $Form Then Exit
EndFunc   ;==>Guiclose

Func gui()
    $Form = GUICreate("Form", 607, 418, 403, 199)

    Local $ListView1 = GUICtrlCreateListView("", 8, 8, 586, 398)
    $Menu = GUICtrlCreateContextMenu($ListView1)

    _GUICtrlCreateODMenuItem("Menu :", $Menu, @ScriptDir & "\Ico\Menu.ico")
    _GUICtrlCreateODMenuItem("", $Menu)
    _GUICtrlCreateODMenuItem("Windows 1", $Menu, @ScriptDir & "\Ico\S1.ico")
    GUICtrlSetOnEvent(-1, "Gui1")
    _GUICtrlCreateODMenuItem("Windows 2", $Menu, @ScriptDir & "\Ico\S2.ico")
    GUICtrlSetOnEvent(-1, "Gui2")
    _GUICtrlCreateODMenuItem("Windows 3", $Menu, @ScriptDir & "\Ico\S3.ico")
    GUICtrlSetOnEvent(-1, "Gui3")

    GUISetOnEvent($GUI_EVENT_CLOSE, "Guiclose")
    GUISetState(@SW_SHOW)
EndFunc   ;==>gui

Func gui1()
    $Form1 = GUICreate("Form1", 607, 418, 403, 199)

    Local $ListView1 = GUICtrlCreateListView("", 8, 8, 586, 398)
    $Menu1 = GUICtrlCreateContextMenu($ListView1)
    _GUICtrlCreateODMenuItem("Menu F1:", $Menu1, @ScriptDir & "\Ico\S4.ico")
    _GUICtrlCreateODMenuItem("", $Menu1)
    _GUICtrlCreateODMenuItem("test1", $Menu1, @ScriptDir & "\Ico\S5.ico")
    _GUICtrlCreateODMenuItem("test2", $Menu1, @ScriptDir & "\Ico\S6.ico")
    _GUICtrlCreateODMenuItem("test3", $Menu1, @ScriptDir & "\Ico\S7.ico")

    GUISetOnEvent($GUI_EVENT_CLOSE, "Guiclose")
    GUISetState(@SW_SHOW)
EndFunc   ;==>gui1

Func gui2()
    $Form2 = GUICreate("Form2", 607, 418, 403, 199)

    Local $ListView1 = GUICtrlCreateListView("", 8, 8, 586, 398)
    $Menu2 = GUICtrlCreateContextMenu($ListView1)
    _GUICtrlCreateODMenuItem("Menu F2:", $Menu2, @ScriptDir & "\Ico\S8.ico")
    _GUICtrlCreateODMenuItem("", $Menu2)
    _GUICtrlCreateODMenuItem("test1", $Menu2, @ScriptDir & "\Ico\S9.ico")
    _GUICtrlCreateODMenuItem("test2", $Menu2, @ScriptDir & "\Ico\S10.ico")
    _GUICtrlCreateODMenuItem("test3", $Menu2, @ScriptDir & "\Ico\S11.ico")

    GUISetOnEvent($GUI_EVENT_CLOSE, "Guiclose")
    GUISetState(@SW_SHOW)
EndFunc   ;==>gui2

Func gui3()
    $Form3 = GUICreate("Form3", 607, 418, 403, 199)

    Local $ListView1 = GUICtrlCreateListView("", 8, 8, 586, 398)
    $Menu3 = GUICtrlCreateContextMenu($ListView1)
    _GUICtrlCreateODMenuItem("Menu F3:", $Menu3, @ScriptDir & "\Ico\S12.ico")
    _GUICtrlCreateODMenuItem("", $Menu3)
    _GUICtrlCreateODMenuItem("test1", $Menu3, @ScriptDir & "\Ico\S13.ico")
    _GUICtrlCreateODMenuItem("test2", $Menu3, @ScriptDir & "\Ico\S14.ico")
    _GUICtrlCreateODMenuItem("test3", $Menu3, @ScriptDir & "\Ico\S15.ico")

    GUISetOnEvent($GUI_EVENT_CLOSE, "Guiclose")
    GUISetState(@SW_SHOW)
EndFunc   ;==>gui3

[Ghost911]

bonjour désolé de te dire ça mais ça marche toujours pas :s le même bug est présent si tu click sur Windows1 tu fermes la fenêtre après tu Click sur Windows2 ta le menu de Windows1 sur Windows2 pareil pour Windows3

[GaRydelaMer]

Bonjour

j'ai éditer le code qui corrige le problème. Il te faut détruire le menu, en fait mettre à jour le tableau qu'utilise l'UDF, avec la fonction _GUICtrlODMenuItemDelete($nMemuID).

[Ghost911]

Cela marche très bien tu as été genial sur ce coup-là j'étais vraiment coincé avec ça merci beaucoup

[Tlem]

N'oubliez pas la balise [R] dans le titre de votre premier message si votre sujet est résolu.

[Ghost911]

merci Tlem désolé j'ai oublié