[R] Pb compatibilité de script entre win 32 bits et w 64

[fred39]

Bonjour,
Il y a 2 ans, javais fait un script qui permettait aux utilisateurs du réseau de sauvegarder et restaurer la disposition des icônes sur le bureau.
une partie du code:

Code : Tout sélectionner

#include <GuiListView.au3>



; récupération du handle du bureau
$H_desktop = ControlGetHandle("[CLASS:Progman]", "", "SysListView321")
MsgBox(0,@ScriptName,$H_desktop)
MsgBox(0,@scriptname,_GUICtrlListView_GetItemCount($H_desktop))
; liste des éléments, et sauvegarde  de leur position dans le fichier ini.
        For $nIdx = 0 To _GUICtrlListView_GetItemCount($H_desktop) - 1
            $sIconText = _GUICtrlListView_GetItemText($H_desktop, $nIdx)
            if @error Then MsgBox(0, @scriptname, "pb lecturetexte icone" & $sIconText)
            $aPos = _GUICtrlListView_GetItemPosition($H_desktop, $nIdx)
            If @error Then MsgBox(0, @ScriptName, "Il y a eu une erreur lors de la lecture la position de l'icône " & $sIconText)
MsgBox(0,@ScriptName,$nIdx&@crlf&$sIconText&@crlf&$aPos[0]&":"&$aPos[1])

        Next

le problème, c'est que pour faire fonctionner ce script sur les Windows 7 64bits, il faut que je le compile en 64 bits.
Le parc Stations étant hétérogène 32 et 64, il est beaucoup plus simple d'avoir un seul exécutable, qui test l'archi de l'os et envois les commandes en fonction.

la fonction _GUICtrlListView_GetItemText renvois un champs vide sur le 64 quand le script est compilé en 32.
Sur les 64, le handle du bureau est
0x00010164 compilé en 32
0x0000000000010164 compilé en 64

Dans les 2 cas, on compte bien le bon nombre d'icones.

Si vous avez une idée....
merci

[jguinch]

Salut
Dans la doc de la fonction ControlListView :

Some commands may fail when using a 32-bit AutoIt process to read from a 64-bit process. Likewise commands may fail when using a 64-bit AutoIt process to read from a 32-bit process.

Donc à priori, pas d'autre solution avec _GUICtrlListView_GetItemText

En tout cas, j'adore l'idée : je vais te la piquer...


Edit : j'ai essayé avec ControlListView, ça plante l'explorer.
C'est pas gagné l'affaire : http://www.autoitscript.com/forum/topic ... windows-7/

[mikell]

En tout cas, j'adore l'idée : je vais te la piquer...

Intéressante mais pas nouvelle l'idée
http://www.autoitscript.fr/forum/viewto ... f=6&t=7999
Quoique avec w7 ...

[fred39]

à l'époque j'étais parti de ça:
http://www.autoitscript.com/forum/topic ... ntry397684

J'aimerais plutôt trouver une solution compatible 32 et 64....
++
Fred

[mikell]

Moi aussi j'étais parti de là, c'est mentionné dans le texte de mon post

Pour un code unique qui marcherait aussi bien en 32 qu'en 64 bits, c'est mal barré
En effet sur le forum US après Melba23 c'est KaFu qui s'est le plus penché sur la question
http://www.autoitscript.com/forum/topic ... ntry937982
Donc j'ai foncé consulter la source de son soft, et de suite on tombe sur ça :

Code : Tout sélectionner

If @OSArch = "X64" And Not @AutoItX64 Then
_39("Fatal Error" & @CRLF & "This version of ICU is 32bit compiled and will not run correctly with a 64bit OS.")
ElseIf @OSArch <> "X64" And @AutoItX64 Then
_39("Fatal Error" & @CRLF & "This version of ICU is 64bit compiled and will not run correctly with a 32bit OS.")
EndIf

Ce qui si je sais encore lire l'autoit dans le texte, veut dire en gros : "si tu compiles en 32 et utilises sur du 64 (et réciproquement), t'es marron"
Donc 2 exe ...

PS : apparemment le pb n'est pas nouveau (et impossible)
http://social.msdn.microsoft.com/Forums ... 8360968a1/

[fred39]

OK,
dommage, c'est un petit exe utilisé sur les serveurs en établissements. Appelé avec 2 arguments, Il permet aux utilisateurs de sauvegarder la disposition de leurs icônes, et qu'elle soit restaurée à chaque fois qu'ils se connectent sur une station.
Je ferai un petit prog en amont qui aiguillera vers le bon exe.
Je vais faire un bond vers la version 2
Pour ceux que ça intéresse, voici le code actuel

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.0
 Author:         Fred39
;~ frederic.lamy@ac-besancon.fr
 Script Function:      Sauvegarde et restauration de la disposition des icones sur le bureau dans un environneemnt scribe
 Script adapté de celui de "JamesBrooks" iconmap layout
 http://www.autoitscript.com/forum/topic/52575-iconmap/page__p__397684#entry397684


#ce ----------------------------------------------------------------------------
#include <GuiListView.au3>

; Paramètres d'appel du script
    Switch $CmdLine[0]
        Case 2
            $sMode = ($CmdLine[1]); /SAVE or /RESTORE
            $sINI = StringReplace($CmdLine[2],"/","",1); le fichier ini (on enlève un éventuel "/" avant le second paramètre)
        Case Else
            msgbox (0,@ScriptName, "Erreur :  le programme doit être appelé avec les paramètres suivants"&@CRLF& @CRLF & @ScriptName & " /save fichier.ini"&@CRLF & @ScriptName & " /restore fichier.ini")
        Exit
    EndSwitch


; Définition du flag indiquant qu'aucune sauvegarde de disposition icone n'a été faite
$nosINI = $sINI&".no.txt"

; récupération du handle du bureau
$H_desktop = ControlGetHandle("[CLASS:Progman]", "", "SysListView321")

; Save ou Restore?
Switch StringUpper($sMode)
    Case "/SAVE"
    ; suppression du flag   $nosINI
    if FileExists ($nosINI) then FileDelete ($nosINI)
    ; suppression de l'ancienne section dans le fichier ini et on controle si on a les droits d'écriture pour le fichier ini
    if FileExists ($sINI) Then
        $Flag_write_ini=FileDelete($sINI)
        if $Flag_write_ini=0 then
            MsgBox(0,@ScriptName, "Erreur: impossible d'écrire le fichier :" & @CRLF & $sINI & @CRLF & @CRLF & "Veuillez vérifier les droits sur le répertoire concerné.")
            Exit; en cas d'erreur on quitte
        EndIf
    EndIf
    ; liste des éléments, et sauvegarde  de leur position dans le fichier ini.
        For $nIdx = 0 To _GUICtrlListView_GetItemCount($H_desktop) - 1
            $sIconText = _GUICtrlListView_GetItemText($H_desktop, $nIdx)
            $aPos = _GUICtrlListView_GetItemPosition($H_desktop, $nIdx)
            If @error Then MsgBox(32, StringTrimRight(@ScriptName, 4), "Il y a eu une erreur lors de la lecture la position de l'icône " & $sIconText)
      $Flag_write_ini=IniWrite($sINI, "Icones", $sIconText, Round ($aPos[0]*100/@DesktopWidth) & ":" & Round($aPos[1]*100/@DesktopHeight))
        Next
        Beep(1500, 100)
        Beep(1000, 100)
        Beep(500, 100)
        if $Flag_write_ini=0 then
            MsgBox(0,@ScriptName, "Erreur: impossible d'écrire le fichier :" & @CRLF & $sINI & @CRLF & @CRLF & "Veuillez vérifier les droits sur le répertoire concerné.")
        Else
            MsgBox(0,@ScriptName, "La disposition des icônes a été sauvegardée.")
        EndIf


    Case "/RESTORE"
        if FileExists($sINI) then  ; on test si le fichier ini existe
        ; liste des éléments, et remise en position à partir du fichier ini.
            For $nIdx = 0 To _GUICtrlListView_GetItemCount($H_desktop) - 1
                $sIconText = _GUICtrlListView_GetItemText($H_desktop, $nIdx)
                $aPos = StringSplit(IniRead($sINI, "Icones", $sIconText, "0:0"), ":")
                If $aPos[0] <> 2 Then
                    MsgBox(0, StringTrimRight(@ScriptName, 4), "Erreur: Les coordonnées sont invalides pour l'icône: " & @LF & @LF & $sIconText)
                    Exit
                EndIf
                ; On ne déplace l'icone si et seulement si il a des coordonnées.
                ; on déplace les icones une première fois à coté de l'ecran  pour éviter les problèmes de chevauchement
                If String($aPos[1]&":"&$aPos[2])<>"0:0" Then  _GUICtrlListView_SetItemPosition($H_desktop, $nIdx, Round($aPos[1]*@DesktopWidth/100+@DesktopWidth), Round($aPos[2]*@DesktopHeight/100))
            Next

            For $nIdx = 0 To _GUICtrlListView_GetItemCount($H_desktop) - 1
                $sIconText = _GUICtrlListView_GetItemText($H_desktop, $nIdx)
                $aPos = StringSplit(IniRead($sINI, "Icones", $sIconText, "0:0"), ":")
                If $aPos[0] <> 2 Then
                    MsgBox(0, StringTrimRight(@ScriptName, 4), "Erreur: Les coordonnées sont invalides pour l'icône: " & @LF & @LF & $sIconText)
                    Exit
                EndIf
                If String($aPos[1]&":"&$aPos[2])<>"0:0" Then _GUICtrlListView_SetItemPosition($H_desktop, $nIdx, Round($aPos[1]*@DesktopWidth/100), Round($aPos[2]*@DesktopHeight/100))
            Next

        Else
            if Not FileExists   ($nosINI) Then
                FileWrite ($nosINI, "Il n'y a pas de fichier "&$sINI)
            EndIf
        EndIf
    Case Else
        msgbox (0,@ScriptName, "Erreur :  le programme doit être appelé avec les paramètres suivants"&@CRLF& @CRLF & @ScriptName & " /save fichier.ini"&@CRLF & @ScriptName & " /restore fichier.ini")
EndSwitch

Le projet complet est ici :
http://dev-eole.ac-dijon.fr/attachments ... es.1.3.zip
Merci pour vos réponses.

[jguinch]

J'ai testé, j'ai eu un petit pb car sur mon bureau j'ai deux icônes qui ont le même nom (une dans mon profil\bureau et une dans le AllUsers\Bureau).

A part ça c'est c'est sympa.