[R] modifier la taille d'une Checkbox

[nounours]

Bonjour,

Voila ce qui m'amène , je trouve la taille standard de la case à cocher d'une checkbox un peu petite , j'aurais voulu la modifier , mais après de veine recherche je viens voir si quelqu'un aurait le code ?

J'utilise cette fonction pour la faire :
GUICtrlCreateCheckbox ( "text", left, top [, width [, height [, style [, exStyle]]]] )

mais rien dans les options ne me permet de grossir la case à coser .

[ani]

Il est sans doute possible de grossir la case à cocher,
mais n'étant pas expert, il faudra surement passer par la structure du control.

Sinon la cmd que vous citée n'est juste que standart. (paramètre par défault).

ps: je ne dispose pas sous les yeux autoit et comme il est dit plus je ne suis pas expert surtout au niveau des structures :p

[nounours]

Merci de ta réponse ,

Oui , je vais peut etre me plonger dans les includes #include <GUIConstants.au3>
j'ai trouverai peut etre quelque chose.

[SagePourpre]

Voilà un moyen simple de contourner le problème.....

Mais bon, la taille n'est toujours pas réglable mais elle est déjà pas mal
plus grosse (et personnalisable... puisqu'en fait tu peux mettre les deux
images que tu veux.


Checkbox.dll doit être dans le même dossier que le script.

checkbox.rar

(3.87 Kio) Téléchargé 129 fois

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Opt('MustDeclareVars', 1)

Local $CheckBox, $CheckBox_LBL


GUICreate("test", 240, 180)

;FileInstall("C:\Users\Sage Pourpre\Desktop\agif\checkbox.dll", @ScriptDir & "\checkbox.dll")



$CheckBox = GUICtrlCreateCheckbox("1", 200, 90, 40, 40, $BS_ICON + $BS_PUSHLIKE)
GUICtrlSetImage($CheckBox, "checkbox.dll", 2)
$CheckBox_LBL = GUICtrlCreateLabel("Please Press Checkbox", 10, 100, 190, 40)
GUICtrlSetFont(-1, 12, 700)
GUISetState()

; Run the GUI until the dialog is closed
While 1

Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
; FileDelete(@ScriptDir & "\checkbox.dll")
ExitLoop
Case $CheckBox
If BitAND(GUICtrlRead($CheckBox), $GUI_CHECKED) = $GUI_CHECKED Then
GUICtrlSetImage($CheckBox, "checkbox.dll", 1)
Else
GUICtrlSetImage($CheckBox, "checkbox.dll", 2)
EndIf
Case Else
EndSwitch
WEnd

[nounours]

Merci pour ta réponse SagePourpre,

J'ai regardé mais cela n'a pas fonctionné , pas d'image affichée .

Je me suis donc penché sur les boutons et j'ai fais ça :

Code : Tout sélectionner

; Version AutoIt :    3.2.10.0
; Langue     :        Francais
; Plateforme :        Win9x/XP/Vista
; Autheur    :        Cyril
;
; Fonction du script : checkbox de taille 32*32
;
; Version 1.0 : 04.08.2008
;           - Première Version.
; ----------------------------------------------------
; -------------------- Section III --------------------
; ----------------------------------------------------
; Déclarations Diverses.
#include <GUIConstants.au3>
Global $wintitle="Checkbox de taille 32*32"
; ----------------------------------------------------
; -------------------- Section IV --------------------
; ----------------------------------------------------
; Fenetre principale.
$GUI_MAIN2 = GUICreate($wintitle,250,100,400,400)

$Box_Message=GUICtrlCreateEdit("testez la checkbox",20,34,160,32,$ES_READONLY+$ES_CENTER  )
GUICtrlSetFont (-1,12, 800, 2, "Arial")    
GUICtrlSetBkColor (-1,0xFF8040)

$box_check = GUICtrlCreateButton ("1",208,34,32,32,$BS_ICON )
;GUICtrlSetImage (-1, @ScriptDir & "\images\box_check.ico")
GUICtrlSetState($box_check,$GUI_SHOW)
$box_Uncheck = GUICtrlCreateButton ("0",208,34,32,32,$BS_ICON )
;GUICtrlSetImage (-1, @ScriptDir & "\images\box_Uncheck.ico")
GUICtrlSetState($box_Uncheck,$GUI_HIDE)

GUISetState(@SW_SHOW)
; ----------------------------------------------------
; -------------------- Section V --------------------
; ----------------------------------------------------
While 1
    $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE  
                Exit
            Case $msg = $box_check
                GUICtrlSetState($box_Uncheck,$GUI_SHOW)
                GUICtrlSetState($box_check,$GUI_HIDE)
                MsgBox(0,"Etat de la checkbox","Non validée")
            Case $msg = $box_Uncheck
                GUICtrlSetState($box_Uncheck,$GUI_HIDE)
                GUICtrlSetState($box_check,$GUI_SHOW)
                MsgBox(0,"Etat de la checkbox","validée")
          EndSelect
WEnd
 

après j'y ai rajoutez les image que j'ai créé en .ico de taille 32*32

[SagePourpre]

Merci pour ta réponse SagePourpre,

J'ai regardé mais cela n'a pas fonctionné , pas d'image affichée .

Il te fallait la dll dans le checkbox.rar que j'ai joint ( les images sont à l'intérieur )


Mais bon... t'es parvenu à tes fins autrement

[Tlem]

Ceci me parait plus simple :

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>

Global $wintitle="Checkbox de taille 32*32"

$GUI_MAIN2 = GUICreate($wintitle,250,100,400,400)

$Box_Message=GUICtrlCreateEdit("testez la checkbox",20,34,160,32,$ES_READONLY+$ES_CENTER  )
GUICtrlSetFont (-1,12, 800, 2, "Arial")    
GUICtrlSetBkColor (-1,0xFF8040)

$BigCheckBox = GUICtrlCreateButton ("",208,34,32,32,$BS_ICON )

GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE  
                Exit
            Case $msg = $BigCheckBox
                If GUICtrlRead($BigCheckBox) = "" Then
                    GUICtrlSetData($BigCheckBox, "V")
                    GUICtrlSetFont(-1, 14, 800)
                Else
                    GUICtrlSetData($BigCheckBox, "")
                EndIf
          EndSelect
WEnd

[nounours]

Merci Tlem,

J'ai adapté ça pour y intégrer les images

Code : Tout sélectionner

#include <GUIConstants.au3>
Global $wintitle="Checkbox de taille 32*32"

; Fenetre principale.
$GUI_MAIN2 = GUICreate($wintitle,250,100,400,400)

$Box_Message=GUICtrlCreateEdit("testez la checkbox",20,34,160,32,$ES_READONLY+$ES_CENTER  )
GUICtrlSetFont (-1,12, 800, 2, "Arial")    
GUICtrlSetBkColor (-1,0xFF8040)

$box_check = GUICtrlCreateButton ("1",208,34,32,32,$BS_ICON )
GUICtrlSetImage (-1, @ScriptDir & "\images\box_check.ico")


GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
        Select
        
            Case $msg = $GUI_EVENT_CLOSE  
                Exit
            Case $msg = $box_check
                If GUICtrlRead($box_check) = "1" Then
                    GUICtrlSetData($box_check, "0")
                    GUICtrlSetImage ($box_check, @ScriptDir & "\images\box_Uncheck.ico")
                Else
                    GUICtrlSetData($box_check, "1")
                    GUICtrlSetImage ($box_check, @ScriptDir & "\images\box_check.ico")
                EndIf
         
         
         
         EndSelect
WEnd

 

[SagePourpre]

hmmm... Pourquoi un "V".... Ça m'a fait tout drole... un "X" aurait été moins
dépaysant.


(Commentaire inutile # 8263 )


Bon ok ... J'me tais, du moins pour l'instant