[R] Listview élaborée multiselect avec icônes

[Julien]

Bonjour,

Une personne ayant plus d’expérience que moi pourrait il réaliser ceci (ou me dire que ce n'est pas du tout possible).

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GUIListView.au3>
#include <GuiImageList.au3>

Opt("GUIOnEventMode", 1)

Global $Array1[2][10] = [["Actif", "Check", "ID Text", "Nom", "Option1", "Option2", "Option3", "Autre1", "Autre2", "Autre3"], _
        ["True", "True", "Text1", "Text2", "True", "False", "True", "Text3", "Text4", "Text5"] _
    ]

Global $Array2[2][3] = [["ID Text", "Fichier", "Ico"], _
        ["Text1", @SystemDir & "\shell32.dll", -130] _
    ]

Global $Form = GUICreate("Form", 507, 166, 265, 161)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
Global $ListView = GUICtrlCreateListView("", 8, 8, 490, 150, $LVS_DEFAULT, $WS_EX_CLIENTEDGE)
$ListView = GUICtrlGetHandle(-1)
_GUICtrlListView_SetExtendedListViewStyle($ListView, BitOR($LVS_EX_CHECKBOXES, $LVS_EX_DOUBLEBUFFER, $LVS_EX_INFOTIP))

_GUICtrlListView_InsertColumn($ListView, 0, "Col1", 50)
_GUICtrlListView_InsertColumn($ListView, 1, "Array2", 50)
_GUICtrlListView_JustifyColumn($ListView, 1, 2)
_GUICtrlListView_InsertColumn($ListView, 2, "Col3", 100)
_GUICtrlListView_InsertColumn($ListView, 3, "Col4", 50)
_GUICtrlListView_JustifyColumn($ListView, 1, 2)
_GUICtrlListView_InsertColumn($ListView, 4, "Col5", 50)
_GUICtrlListView_JustifyColumn($ListView, 1, 2)
_GUICtrlListView_InsertColumn($ListView, 5, "Col6", 50)
_GUICtrlListView_JustifyColumn($ListView, 1, 2)

Global $ListViewImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 110)
_GUICtrlListView_SetImageList($ListView, $ListViewImage, 2)

;~ _GUICtrlListView_AddItem($ListView, "", 0) ; Ico1 ou Ico2 remplace la checkbox en fonction de $Array1[1][1] (True/False)
;~ _GUICtrlListView_AddSubItem($ListView, 0, "", 1) ; Icône correspondante : $Array1[1][2] = $Array2[1][0]
;~ _GUICtrlListView_AddSubItem($ListView, 0, "Text2", 2) ; $Array1[1][3]
;~ _GUICtrlListView_AddSubItem($ListView, 0, "", 3) ; Ico1 ou Ico2 en fonction de True/false
;~ _GUICtrlListView_AddSubItem($ListView, 0, "", 4) ; Ico1 ou Ico2 en fonction de True/false
;~ _GUICtrlListView_AddSubItem($ListView, 0, "", 5) ; Ico1 ou Ico2 en fonction de True/false

LoadData()

GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func LoadData()
    Local $iIndex
    Local $y = 0
    For $i = 1 To UBound($Array1) -1
        If $Array1[$i][0] = "True" Then
            If $Array1[$i][3] <> "" Then
                _AddRow($ListView, "||" & $Array1[$i][3] & "|||")
                If $Array1[$i][1] = "True" Then
                    _GUICtrlListView_SetItemChecked($ListView, $y, 1)
                Else
                    _GUICtrlListView_SetItemChecked($ListView, $y, 0)
                EndIf
                If $Array1[$i][2] <> "" Then
                    $iIndex = _ArraySearch($Array2, $Array1[$i][2], 0, -1, 1, 0, 1, 0)
                    If Not @error Then
                        ; ?
                    EndIf
                EndIf
;~              If $Array1[$i][4] = "True" Then
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 1, 3)
;~              Else
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 0, 3)
;~              EndIf
;~              If $Array1[$i][5] = "True" Then
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 1, 4)
;~              Else
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 0, 4)
;~              EndIf
;~              If $Array1[$i][6] = "True" Then
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 1, 5)
;~              Else
;~                  _GUICtrlListView_SetItemImage($ListView, $y, 0, 5)
;~              EndIf
                $y += 1
            EndIf
        EndIf
    Next
EndFunc

Func FormClose()
    Exit
EndFunc

Func _AddRow($hWnd, $sItem)
    Local $aItem = StringSplit($sItem, "|")
    Local $iIndex = _GUICtrlListView_AddItem($hWnd, $aItem[1], -1, _GUICtrlListView_GetItemCount($hWnd) + 9999)
    For $x = 2 To $aItem[0]
        _GUICtrlListView_AddSubItem($hWnd, $iIndex, $aItem[$x], $x - 1)
    Next
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $IDFrom, $Code, $tNMLISTVIEW, $iItem
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $Code = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $ListView
            Switch $Code
                Case $LVN_ITEMCHANGED
                    $tNMLISTVIEW = DllStructCreate($tagNMLISTVIEW, $lParam)
                    $iItem = DllStructGetData($tNMLISTVIEW, "Item")
                    If BitAND(DllStructGetData($tNMLISTVIEW, "Changed"), $LVIF_STATE) = $LVIF_STATE Then
                        Switch DllStructGetData($tNMLISTVIEW, "NewState")
                            Case 8192 ;item checked
                                ConsoleWrite('Item ' & $iItem & ' - ' & True & @CR)
                            Case 4096 ;item unchecked
                                ConsoleWrite('Item ' & $iItem & ' - ' & False & @CR)
                        EndSwitch
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 

Le fonctionnement
-----------------

J'aimerais centrer les icônes des colones 1, 2, 4, 5 et 6.

Un clic sur l'icône de la colone 1 change l'icône et met à jour "Check" dans $Array1 ($Array1[$x][1])
Si l'état est à False les autres colonnes ne peuvent pas être modifiées.

Le colonne 3 ("Nom" dans $Array1 ($Array1[$x][3])) doit être éditable et mettre à jour la valeur dans $Array1

Un clic sur l'icône dans les colonnes 4, 5 et 6 doivent inverser l'icône et respectivement mettre à jour les colonne 4, 5 et 6 de $Array1

Le Gui est en Mode Event activé.

J'espère avoir été assez clair dans mon explication. Pour l'accompagner un petit montage visuel pour à quoi cela pourrait ressembler en pièce jointe.

Je sais exactement ce que je veux mais je n'y parviens pas, j'y ai passé beaucoup de temps mais cela ne ressemble à rien.

D'avance merci à celui ou celle qui prendra du temps pour regarder cette demande.

[timmalos]

Utilisez les balises code , votre message est tellement un pavé indéchiffrable que peu de gens vont faire l'effort de le lire, et je n'en ferai pas parti.

[Julien]

J'ai édité mon premier message, cela suffit il ?

[mikell]

Le problème c'est que $LVS_EX_CHECKBOXES n'autorise qu'une seule checkbox par ligne de listview
Tu peux toujours faire des pseudo-checkboxes, comme ici
http://www.autoitscript.com/forum/topic ... ntry739616
Après, un clic sur un subitem peut à la fois changer d'image, basculer une variable true/false, mettre à jour une array, etc, le clic étant détecté par un GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY") => voir le détail dans l'exemple de l'aide pour _GUICtrlListView_Create

Pour rendre un subitem éditable, voilà un modèle qui vient du forum US

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstants.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("GuiCloseOnESC", 0)

Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)

$hGUI = GUICreate("ListView Subitems edit in place", 300, 200)
$hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems", 2, 2, 296, 196, BitOR($LVS_EDITLABELS, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_GRIDLINES)
For $i = 1 To 10
    _GUICtrlListView_AddItem($hListView, "Item " & $i)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem " & $i, 1)
Next

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE



Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
   
    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                        Local $aRect = _GUICtrlListView_GetItemRect($hListView, $Item)
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                    $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 3, $aRect[1], $iLen + 10, 17, $Style)
                    
                    _GUICtrlEdit_SetSel($hEdit, 0, -1)
                    _WinAPI_SetFocus($hEdit)
                    $hDC = _WinAPI_GetWindowDC($hEdit)
                    $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                    FrameRect($hDC, 0, 0, $iLen + 10 , 17, $hBrush)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc



Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    
                    $Item = -1
                    $SubItem = 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

En principe ça devrait suffire pour que tu puisses avancer dans ton script

[Julien]

Bonjour,

Merci pour ces sources.

Petite question, est il possible d'aligner (de centrer) une image dans une colonne ?

D'avance merci.

[Julien]

J'ai cherché plusieurs heures et il semblerait que changer l'alignement des images dans une listview soit impossible.

Voici mon résultat :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
#include <GuiConstants.au3>
#include <GuiEdit.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $Array1[3][10] = [["Actif", "Check", "ID Text", "Nom", "Option1", "Option2", "Option3", "Autre1", "Autre2", "Autre3"], _
        ["True", "False", "Text1", "Text2", "True", "False", "True", "Text3", "Text4", "Text5"], _
        ["True", "True", "Text11", "Text22", "False", "False", "True", "Text3", "Text4", "Text5"] _
    ]

Global $Array2[3][3] = [["ID Text", "Fichier", "Ico"], _
        ["Text1", @SystemDir & "\shell32.dll", 63], _
        ["Text11", @SystemDir & "\shell32.dll", 112] _
    ]

Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)



Global $hGUI = GUICreate("Form", 507, 220, 265, 161)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
Global $hListView = _GUICtrlListView_Create($hGUI, "", 8, 8, 490, 150, BitOR($LVS_EDITLABELS, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_SUBITEMIMAGES)
Local $ButtonArray1 = GUICtrlCreateButton("Affiche Array1", 8, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray1")
Local $ButtonArray2 = GUICtrlCreateButton("Affiche Array2", 88, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray2")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

; Load images
Global $ListViewImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 219) ; En cas d'erreur
_GUICtrlListView_SetImageList($hListView, $ListViewImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "", 50)
_GUICtrlListView_AddColumn($hListView, "", 50)
_GUICtrlListView_AddColumn($hListView, "Nom", 150)
_GUICtrlListView_AddColumn($hListView, "", 50)
_GUICtrlListView_AddColumn($hListView, "", 50)
_GUICtrlListView_AddColumn($hListView, "", 50)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Colonne cachée: $Array1[2]

LoadData()

While 1
    Sleep(100)
WEnd

Func LoadData()
    Local $iIndex
    Local $y = 1
    For $i = 1 To UBound($Array1) -1
        If $Array1[$i][0] = "True" Then
            If $Array1[$i][3] <> "" Then
                If $Array1[$i][1] = "True" Then
                    _GUICtrlListView_AddItem($hListView, "", 1)
                Else
                    _GUICtrlListView_AddItem($hListView, "", 0)
                EndIf
                $iIndex = _ArraySearch($Array2, $Array1[$i][2], 0, -1, 1, 0, 1, 0)
                If Not @error Then
                    Local $iIndexNewImg = _GUIImageList_AddIcon($ListViewImage, $Array2[$iIndex][1], $Array2[$iIndex][2])
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, $iIndexNewImg, $y)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 2, $y)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][3], $y + 1)
                If $Array1[$i][4] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 2)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 2)
                EndIf
                If $Array1[$i][5] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 3)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 3)
                EndIf
                If $Array1[$i][6] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 4)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 4)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][2], $y + 5)
            EndIf
        EndIf
    Next
EndFunc

Func FormClose()
    Exit
EndFunc

Func ButtonArray1()
    _ArrayDisplay($Array1)
EndFunc

Func ButtonArray2()
    _ArrayDisplay($Array2)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                        Local $aRect = _GUICtrlListView_GetItemRect($hListView, $Item)
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    If $iItemText <> "" And $SubItem = 2 Then
                        Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                        $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 12, $aRect[1] + 8, $iLen + 10, 17, $Style)
                        _GUICtrlEdit_SetSel($hEdit, 0, -1)
                        _WinAPI_SetFocus($hEdit)
                        $hDC = _WinAPI_GetWindowDC($hEdit)
                        $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                        FrameRect($hDC, 0, 0, $iLen + 10 , 17, $hBrush)
                    EndIf
                Case $NM_CLICK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    If $SubItem = 0 Or $SubItem = 3 Or $SubItem = 4 Or $SubItem = 5 Then
                        Local $iIndexImg = _GUICtrlListView_GetItemImage($hListView, $Item, $SubItem)
                        Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 6) ; Return le texte de la colonne 6
                        Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                        If Not @error Then
                            If $iIndexImg = 0 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 1, $SubItem)
                                Local $NewState = "True"
                            ElseIf $iIndexImg = 1 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 0, $SubItem)
                                Local $NewState = "False"
                            Else
                                _GUICtrlListView_SetItemImage($hListView, $Item, 2, $SubItem)
                                Local $NewState = "False"
                            EndIf
                            If $SubItem = 0 Then
                                $Array1[$iIndex][1] = $NewState
                            ElseIf $SubItem = 3 Then
                                $Array1[$iIndex][4] = $NewState
                            ElseIf $SubItem = 4 Then
                                $Array1[$iIndex][5] = $NewState
                            ElseIf $SubItem = 5 Then
                                $Array1[$iIndex][6] = $NewState
                            EndIf
                        EndIf
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 6) ; Return le texte de la colonne 6
                    Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                    If Not @error Then
                        $Array1[$iIndex][3] = $iText
                    EndIf
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    $Item = -1
                    $SubItem = 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc
 

Je n'arrive pas à corriger :

- l'alignement des contrôle Edit lors de la modification (corriger dans le code, merci)
- la latence sur le "click" des icônes (presque obligé de faire du double click)

Dans l'ensemble c'est fonctionnel mais je trouve cela assez moche.

Qu'en pensez-vous et pouvez-vous m'aider à corriger les défauts ?

D'avance merci.

[mikell]

- l'alignement des contrôle Edit lors de la modification

Ce positionnement se fait à la création des edits, dans la fonction WM_NOTIFY :

Code : Tout sélectionner

$hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] [color=#BF4000]+ 12[/color], $aRect[1][color=#BF4000] + 8[/color], $iLen + 10, 17, $Style)

Pour l'esthétique, si les colonnes doivent rester de largeur constante, pourquoi simplement ne pas afficher les headers ou "tricher" en mettant des labels à la place
Sinon je trouve pas que le temps de latence sur le clic est si long que ça, à partir du moment où la listview a le focus

[Julien]

Pour l'esthétique, si les colonnes doivent rester de largeur constante, pourquoi simplement ne pas afficher les headers ou "tricher" en mettant des labels à la place
Sinon je trouve pas que le temps de latence sur le clic est si long que ça, à partir du moment où la listview a le focus

Merci Mikell !
Pour la latence il s'agit bien d'une perte de focus.

Pour les labels formidable je n'y avait pas pensé du tout, du coup j'ai ajouté des colonnes pour palier à l'alignement.

Reste maintenant 2 petites choses :

- Cette histoire de focus, comment porter le focus sur la listview et l'enlever lors du passage de la souris dessus ?

J'ai rajouter ceci (dans la fonction WM_NOTIFY) :

Code : Tout sélectionner

Case -121
    ControlFocus("", "", $hWndFrom)

- Pour la première colonne je ne parviens pas à juste afficher l'image lors de la séléction à la souris j'ai un effet de surbrillance, comment l'annuler ?

Voila le code complet mis à jour :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
#include <GuiConstants.au3>
#include <GuiEdit.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $Array1[3][10] = [["Actif", "Check", "ID Text", "Nom", "Option1", "Option2", "Option3", "Autre1", "Autre2", "Autre3"], _
        ["True", "False", "Text1", "Text2", "True", "False", "True", "Text3", "Text4", "Text5"], _
        ["True", "True", "Text11", "Text22", "False", "False", "True", "Text3", "Text4", "Text5"] _
    ]

Global $Array2[3][3] = [["ID Text", "Fichier", "Ico"], _
        ["Text1", @SystemDir & "\shell32.dll", 63], _
        ["Text11", @SystemDir & "\shell32.dll", 112] _
    ]

Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)

Global $hGUI = GUICreate("Form", 507, 220, 265, 161)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
Local $Label1 = GUICtrlCreateLabel("Actif", 8, 10, 40, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $Label = GUICtrlCreateLabel("Nom", 85, 10, 200, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label3 = GUICtrlCreateLabel("Options 1", 288, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label4 = GUICtrlCreateLabel("Options 2", 360, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label5 = GUICtrlCreateLabel("Options 3", 432, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $hListView = _GUICtrlListView_Create($hGUI, "", 8, 25, 490, 150, BitOR($LVS_EDITLABELS, $LVS_REPORT, $LVS_NOCOLUMNHEADER, $WS_BORDER))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_SUBITEMIMAGES)
Local $ButtonArray1 = GUICtrlCreateButton("Array1", 8, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray1")
Local $ButtonArray2 = GUICtrlCreateButton("Array2", 88, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray2")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

; Load images
Global $ListViewImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 219) ; En cas d'erreur
_GUICtrlListView_SetImageList($hListView, $ListViewImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "", 40)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 10) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 200)
_GUICtrlListView_AddColumn($hListView, "", 30) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Colonne cachée: $Array1[2]

LoadData()

While 1
    Sleep(100)
WEnd

Func LoadData()
    Local $iIndex
    Local $y = 1
    For $i = 1 To UBound($Array1) -1
        If $Array1[$i][0] = "True" Then
            If $Array1[$i][3] <> "" Then
                If $Array1[$i][1] = "True" Then
                    _GUICtrlListView_AddItem($hListView, "", 1)
                Else
                    _GUICtrlListView_AddItem($hListView, "", 0)
                EndIf
                $iIndex = _ArraySearch($Array2, $Array1[$i][2], 0, -1, 1, 0, 1, 0)
                If Not @error Then
                    Local $iIndexNewImg = _GUIImageList_AddIcon($ListViewImage, $Array2[$iIndex][1], $Array2[$iIndex][2])
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, $iIndexNewImg, $y + 1)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 2, $y + 1)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][3], $y + 3)
                If $Array1[$i][4] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 5)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 5)
                EndIf
                If $Array1[$i][5] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 7)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 7)
                EndIf
                If $Array1[$i][6] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 9)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 9)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][2], $y + 10)
            EndIf
        EndIf
    Next
EndFunc

Func FormClose()
    Exit
EndFunc

Func ButtonArray1()
    _ArrayDisplay($Array1)
EndFunc

Func ButtonArray2()
    _ArrayDisplay($Array2)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                        Local $aRect = _GUICtrlListView_GetItemRect($hListView, $Item)
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    If $iItemText <> "" And $SubItem = 4 Then
                        Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                        $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 12, $aRect[1] + 26, $iLen + 10, 17, $Style)
                        _GUICtrlEdit_SetSel($hEdit, 0, -1)
                        _WinAPI_SetFocus($hEdit)
                        $hDC = _WinAPI_GetWindowDC($hEdit)
                        $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                        FrameRect($hDC, 0, 0, $iLen + 10 , 17, $hBrush)
                    EndIf
                Case $NM_CLICK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    If $SubItem = 0 Or $SubItem = 6 Or $SubItem = 8 Or $SubItem = 10 Then
                        Local $iIndexImg = _GUICtrlListView_GetItemImage($hListView, $Item, $SubItem)
                        Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 11) ; Return le texte caché de la colonne 11
                        Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                        If Not @error Then
                            If $iIndexImg = 0 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 1, $SubItem)
                                Local $NewState = "True"
                            ElseIf $iIndexImg = 1 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 0, $SubItem)
                                Local $NewState = "False"
                            Else
                                _GUICtrlListView_SetItemImage($hListView, $Item, 2, $SubItem)
                                Local $NewState = "False"
                            EndIf
                            If $SubItem = 0 Then
                                $Array1[$iIndex][1] = $NewState
                            ElseIf $SubItem = 6 Then
                                $Array1[$iIndex][4] = $NewState
                            ElseIf $SubItem = 8 Then
                                $Array1[$iIndex][5] = $NewState
                            ElseIf $SubItem = 10 Then
                                $Array1[$iIndex][6] = $NewState
                            EndIf
                        EndIf
                    EndIf
                Case -121
                    ControlFocus("", "", $hWndFrom)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 11) ; Return le texte caché de la colonne 11
                    Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                    If Not @error Then
                        $Array1[$iIndex][3] = $iText
                    EndIf
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    $Item = -1
                    $SubItem = 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc
 

[blacksoul305]

Salut,

- Cette histoire de focus, comment porter le focus sur la listview et l'enlever lors du passage de la souris dessus ?

Moi j'aurai bien vu un MouseGetPos() non ?

[mikell]

- Cette histoire de focus, comment porter le focus sur la listview et l'enlever lors du passage de la souris dessus ?

2 solutions
- le GUIRegisterMsg WM_MOUSEHOVER où tu surveilles les coordonnées du pointeur de la souris
- ou nettement plus simple, le GuiGetCursorInfo
avec un GUICtrlSetState($listview, $GUI_FOCUS) ou un ControlFocus() par exemple

Plutôt que de rajouter des colonnes pourquoi ne pas ajuster les largeurs avec _GUICtrlListView_SetColumnWidth ou GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, $index, $largeur)

En tout cas bien plus jolie ta gui

[Julien]

Correction du code, je n'ai pas trouvé comment intégrer GuiGetCursorInfo, j'ai utilisé la fonction WM_NOTIFY. Cela fonctionne à priori comme je le souhaite.

J'ai rajouté une première colonne pour mon premier problème.

Effectivement je trouve cela plutôt sympa.

Du coup je cherche maintenant trois améliorations qui pourrait être pratique :

- Lors de l'édition du "Nom" la souris disparait, j'ai un peu cherché mais je ne comprend pas pourquoi
- Lors de l'édition du "Nom" l’appuie sur la touche entrée (ou autre mais je préfère pouvoir la choisir) ne valide pas le changement, je vais regarder du coté de WM_COMMAND avec appuis sur une touche (je crois que c'est $NM_KEYDOWN)
- Lors de l'édition du nom le champ input encadré en rouge ne s'adapte pas au texte tapé (dans la limite de la largeur de la colonne)

Mais la je crois pas être capable de réaliser ces modifications.

Voila ce qui fonctionne :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
#include <GuiConstants.au3>
#include <GuiEdit.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $Array1[3][10] = [["Actif", "Check", "ID Text", "Nom", "Option1", "Option2", "Option3", "Autre1", "Autre2", "Autre3"], _
        ["True", "False", "Text1", "Text2", "True", "False", "True", "Text3", "Text4", "Text5"], _
        ["True", "True", "Text11", "Text22", "False", "False", "True", "Text3", "Text4", "Text5"] _
    ]

Global $Array2[3][3] = [["ID Text", "Fichier", "Ico"], _
        ["Text1", @SystemDir & "\shell32.dll", 63], _
        ["Text11", @SystemDir & "\shell32.dll", 112] _
    ]

Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)
Global $StateFocusListview = False

Global $hGUI = GUICreate("Form", 507, 220, 265, 161)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
Local $Label1 = GUICtrlCreateLabel("Actif", 8, 10, 40, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $Label = GUICtrlCreateLabel("Nom", 85, 10, 200, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label3 = GUICtrlCreateLabel("Options 1", 288, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label4 = GUICtrlCreateLabel("Options 2", 360, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label5 = GUICtrlCreateLabel("Options 3", 432, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $hListView = _GUICtrlListView_Create($hGUI, "", 8, 25, 490, 150, BitOR($LVS_EDITLABELS, $LVS_REPORT, $LVS_NOCOLUMNHEADER, $WS_BORDER))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_SUBITEMIMAGES)
Local $ButtonArray1 = GUICtrlCreateButton("Array1", 8, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray1")
Local $ButtonArray2 = GUICtrlCreateButton("Array2", 88, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray2")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

ConsoleWrite($hListView & @CRLF)

; Load images
Global $ListViewImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 219) ; En cas d'erreur
_GUICtrlListView_SetImageList($hListView, $ListViewImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "", 4) ; Première colonne pour palier à la séléction
_GUICtrlListView_AddColumn($hListView, "", 36)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 10) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 200)
_GUICtrlListView_AddColumn($hListView, "", 30) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Colonne cachée: $Array1[2]

LoadData()

While 1
    Sleep(100)
WEnd

Func LoadData()
    Local $iIndex
    Local $y = 1
    For $i = 1 To UBound($Array1) -1
        If $Array1[$i][0] = "True" Then
            If $Array1[$i][3] <> "" Then
                _GUICtrlListView_AddItem($hListView, "")
                If $Array1[$i][1] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y)
                EndIf
                $iIndex = _ArraySearch($Array2, $Array1[$i][2], 0, -1, 1, 0, 1, 0)
                If Not @error Then
                    Local $iIndexNewImg = _GUIImageList_AddIcon($ListViewImage, $Array2[$iIndex][1], $Array2[$iIndex][2])
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, $iIndexNewImg, $y + 2)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 2, $y + 2)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][3], $y + 4)
                If $Array1[$i][4] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 6)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 6)
                EndIf
                If $Array1[$i][5] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 8)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 8)
                EndIf
                If $Array1[$i][6] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 10)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 10)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][2], $y + 11)
            EndIf
        EndIf
    Next
EndFunc

Func FormClose()
    Exit
EndFunc

Func ButtonArray1()
    _ArrayDisplay($Array1)
EndFunc

Func ButtonArray2()
    _ArrayDisplay($Array2)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                        Local $aRect = _GUICtrlListView_GetItemRect($hListView, $Item)
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    If $iItemText <> "" And $SubItem = 5 Then
                        Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                        $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 12, $aRect[1] + 26, $iLen + 10, 17, $Style)
                        _GUICtrlEdit_SetSel($hEdit, 0, -1)
                        _WinAPI_SetFocus($hEdit)
                        $hDC = _WinAPI_GetWindowDC($hEdit)
                        $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                        FrameRect($hDC, 0, 0, $iLen + 10 , 17, $hBrush)
                    EndIf
                    $StateFocusListview = True
                Case $NM_CLICK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    If $SubItem = 1 Or $SubItem = 7 Or $SubItem = 9 Or $SubItem = 11 Then
                        Local $iIndexImg = _GUICtrlListView_GetItemImage($hListView, $Item, $SubItem)
                        Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 12) ; Return le texte caché de la colonne 12
                        Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                        If Not @error Then
                            If $iIndexImg = 0 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 1, $SubItem)
                                Local $NewState = "True"
                            ElseIf $iIndexImg = 1 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 0, $SubItem)
                                Local $NewState = "False"
                            Else
                                _GUICtrlListView_SetItemImage($hListView, $Item, 2, $SubItem)
                                Local $NewState = "False"
                            EndIf
                            If $SubItem = 1 Then
                                $Array1[$iIndex][1] = $NewState
                            ElseIf $SubItem = 7 Then
                                $Array1[$iIndex][4] = $NewState
                            ElseIf $SubItem = 9 Then
                                $Array1[$iIndex][5] = $NewState
                            ElseIf $SubItem = 11 Then
                                $Array1[$iIndex][6] = $NewState
                            EndIf
                        EndIf
                    EndIf
                Case -121 ; ???
                    If $StateFocusListview = False Then
                        ControlFocus("", "", $hListView)
                        $StateFocusListview = True
                    EndIf
                Case $NM_KILLFOCUS
                    $StateFocusListview = False
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 12) ; Return le texte caché de la colonne 12
                    Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                    If Not @error Then
                        $Array1[$iIndex][3] = $iText
                    EndIf
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    $Item = -1
                    $SubItem = 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc
 

Merci encore pour votre aide.

[mikell]

Code : Tout sélectionner

$a = GUIGetCursorInfo()
If $a[4] = $listview then...   " $array[4] = ID of the control that the mouse cursor is hovering over "

- Lors de l'édition du nom le champ input encadré en rouge ne s'adapte pas au texte tapé (dans la limite de la largeur de la colonne)

Faire un changement de taille dynamique de l'edit risque d'être compliqué et surtout terrible pour l'exécution du script, pourquoi ne pas juste donner directement à l'edit la largeur de la colonne ? (voir code ci-dessous)

Pour la touche, en théorie tu peux placer un $LVN_KEYDOWN dans le NOTIFY, en pratique tu vas interférer avec la saisie dans l'edit ^^
Avec la touche Enter la moins mauvaise solution semble être celle-là :
(j'utilise un HotkeySet mais un GuiSetAccelerators serait sans doute plus approprié)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>
#include <GuiConstants.au3>
#include <GuiEdit.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>
#include <Misc.au3>

HotKeySet("{ENTER}", "_Enregistre")

Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)

Global $Array1[3][10] = [["Actif", "Check", "ID Text", "Nom", "Option1", "Option2", "Option3", "Autre1", "Autre2", "Autre3"], _
        ["True", "False", "Text1", "Text2", "True", "False", "True", "Text3", "Text4", "Text5"], _
        ["True", "True", "Text11", "Text22", "False", "False", "True", "Text3", "Text4", "Text5"] _
    ]

Global $Array2[3][3] = [["ID Text", "Fichier", "Ico"], _
        ["Text1", @SystemDir & "\shell32.dll", 63], _
        ["Text11", @SystemDir & "\shell32.dll", 112] _
    ]

Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)
Global $StateFocusListview = False

Global $hGUI = GUICreate("Form", 507, 220, 265, 161)
GUISetOnEvent($GUI_EVENT_CLOSE, "FormClose")
Local $Label1 = GUICtrlCreateLabel("Actif", 8, 10, 40, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $Label = GUICtrlCreateLabel("Nom", 85, 10, 200, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label3 = GUICtrlCreateLabel("Options 1", 288, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label4 = GUICtrlCreateLabel("Options 2", 360, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Local $Label5 = GUICtrlCreateLabel("Options 3", 432, 10, 65, 15)
GUICtrlSetFont(-1, 8, 800, 2, "Verdana")
Global $hListView = _GUICtrlListView_Create($hGUI, "", 8, 25, 490, 150, BitOR($LVS_EDITLABELS, $LVS_REPORT, $LVS_NOCOLUMNHEADER, $WS_BORDER))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_SUBITEMIMAGES)
Local $ButtonArray1 = GUICtrlCreateButton("Array1", 8, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray1")
Local $ButtonArray2 = GUICtrlCreateButton("Array2", 88, 184, 75, 25)
GUICtrlSetOnEvent(-1, "ButtonArray2")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)

ConsoleWrite($hListView & @CRLF)

; Load images
Global $ListViewImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($ListViewImage, @SystemDir & "\shell32.dll", 219) ; En cas d'erreur
_GUICtrlListView_SetImageList($hListView, $ListViewImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "", 4) ; Première colonne pour palier à la séléction
_GUICtrlListView_AddColumn($hListView, "", 36)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 10) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 200)
_GUICtrlListView_AddColumn($hListView, "", 30) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 50) ; Séparation
_GUICtrlListView_AddColumn($hListView, "", 20)
_GUICtrlListView_AddColumn($hListView, "", 0) ; Colonne cachée: $Array1[2]

LoadData()

While 1
    Sleep(100)
WEnd

Func LoadData()
    Local $iIndex
    Local $y = 1
    For $i = 1 To UBound($Array1) -1
        If $Array1[$i][0] = "True" Then
            If $Array1[$i][3] <> "" Then
                _GUICtrlListView_AddItem($hListView, "")
                If $Array1[$i][1] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y)
                EndIf
                $iIndex = _ArraySearch($Array2, $Array1[$i][2], 0, -1, 1, 0, 1, 0)
                If Not @error Then
                    Local $iIndexNewImg = _GUIImageList_AddIcon($ListViewImage, $Array2[$iIndex][1], $Array2[$iIndex][2])
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, $iIndexNewImg, $y + 2)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 2, $y + 2)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][3], $y + 4)
                If $Array1[$i][4] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 6)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 6)
                EndIf
                If $Array1[$i][5] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 8)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 8)
                EndIf
                If $Array1[$i][6] = "True" Then
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 1, $y + 10)
                Else
                    _GUICtrlListView_SetItemImage($hListView, $i - 1, 0, $y + 10)
                EndIf
                _GUICtrlListView_AddSubItem($hListView, $i - 1, $Array1[$i][2], $y + 11)
            EndIf
        EndIf
    Next
EndFunc

Func FormClose()
    Exit
EndFunc

Func ButtonArray1()
    _ArrayDisplay($Array1)
EndFunc

Func ButtonArray2()
    _ArrayDisplay($Array2)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                        Local $aRect = _GUICtrlListView_GetItemRect($hListView, $Item)
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    If $iItemText <> "" And $SubItem = 5 Then
                      ;  Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                        $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 12, $aRect[1] + 26, 200 , 17, $Style)
                        _GUICtrlEdit_SetSel($hEdit, 0, -1)
                        _WinAPI_SetFocus($hEdit)
                        $hDC = _WinAPI_GetWindowDC($hEdit)
                        $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                        FrameRect($hDC, 0, 0, 200 , 17, $hBrush)
                    EndIf
                    $StateFocusListview = True
                Case $NM_CLICK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] = 0) Then
                        $Item = $aHit[0]
                        $SubItem = 0
                    ElseIf ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    If $SubItem = 1 Or $SubItem = 7 Or $SubItem = 9 Or $SubItem = 11 Then
                        Local $iIndexImg = _GUICtrlListView_GetItemImage($hListView, $Item, $SubItem)
                        Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 12) ; Return le texte caché de la colonne 12
                        Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                        If Not @error Then
                            If $iIndexImg = 0 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 1, $SubItem)
                                Local $NewState = "True"
                            ElseIf $iIndexImg = 1 Then
                                _GUICtrlListView_SetItemImage($hListView, $Item, 0, $SubItem)
                                Local $NewState = "False"
                            Else
                                _GUICtrlListView_SetItemImage($hListView, $Item, 2, $SubItem)
                                Local $NewState = "False"
                            EndIf
                            If $SubItem = 1 Then
                                $Array1[$iIndex][1] = $NewState
                            ElseIf $SubItem = 7 Then
                                $Array1[$iIndex][4] = $NewState
                            ElseIf $SubItem = 9 Then
                                $Array1[$iIndex][5] = $NewState
                            ElseIf $SubItem = 11 Then
                                $Array1[$iIndex][6] = $NewState
                            EndIf
                        EndIf
                    EndIf
                Case -121 ; ???
                    If $StateFocusListview = False Then
                       ControlFocus("", "", $hListView)
                       $StateFocusListview = True
                    EndIf
                Case $NM_KILLFOCUS
                    $StateFocusListview = False
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS 
                     _Enregistre()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc


Func _Enregistre()
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    Local $RefSearch = _GUICtrlListView_GetItemText($hListView, $Item, 12) ; Return le texte caché de la colonne 12
                    Local $iIndex = _ArraySearch($Array1, $RefSearch, 0, -1, 1, 0, 1, 2)
                    If Not @error Then
                        $Array1[$iIndex][3] = $iText
                    EndIf
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    $Item = -1
                    $SubItem = 0
EndFunc
 

Le pointeur de souris franchement on s'en fout puisque de toute façon à la validation de la saisie (par clic ou touche) il réapparaît

[Julien]

Merci beaucoup pour votre aide précieuse !

Le sujet est maintenant résolu.


Pour le GUIGetCursorInfo() en fait j'avais bien lu la doc mais je ne savais pas ou le placer (à priori en le déclarant en haut du code et en le surveillant dans le while ?)

Sinon je vais jeter un œil pour le HotkeySet.

Encore merci.

[sylvanie]

Bonjour,
dans ce cas, pensez à passer votre post en résolu [R] en éditant le sujet du premier post
merci