[R] Fixer la taille de la police de caractère dans un gui

[Laddy]

Bonjour à tous,
ça fait un ti moment que je n'avais pas codé
Mes salutations à ZeShrek
j'ai un ti soucis avec mon chromeManager.
J'ai travaillé dessus le week end passé, double clic sur la listview, suppression de pepperflash, et autres choses, mais ce n'est pas le problème qui existe depuis la version précédante.

Si je change de PC qui a un fort zoom (pc relié à la tv en hdmi) au niveau résolution.

J'ai ma police d'écriture qui déborde et la taille de ma gui bizarre.

Je voudrais savoir comment je peux fixer la taille de la police d'écriture sans avoir ce problème :

Gui de mon interface.
Ja'i pourtant utiliser GuiCtrlSetFont, y a t il un autre moyen ?

Code : Tout sélectionner

Global $ChromeManager = GUICreate("Google Chrome - Choisissez un profil utilisateur", 345, 218, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE, "Sortie")
$backgroundColor = GUISetBkColor($color, $ChromeManager)
Global $ListProfil = GUICtrlCreateList("", 168, 48, 169, 73)
Global $StartChrome = GUICtrlCreateButton("Demarrer Chrome", 144, 168, 97, 33, $WS_GROUP)
GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
GUICtrlSetOnEvent($StartChrome, "Start") ; *****
Global $Quit = GUICtrlCreateButton("Quitter", 249, 168, 87, 33, $WS_GROUP)
GUICtrlSetOnEvent($Quit, "Sortie") ; *****
Global $CreateProfil = GUICtrlCreateButton("Créer un profil", 8, 32, 145, 33, $WS_GROUP)
GUICtrlSetOnEvent($CreateProfil, "CreateProfil") ; *****
GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
Global $Label1 = GUICtrlCreateLabel(" Chrome conserve vos préférences et paramètres dans votre profil", 8, 8, 324, 17)
GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
Global $Delete = GUICtrlCreateButton("Supprimer un profil", 8, 80, 145, 33, $WS_GROUP)
GUICtrlSetOnEvent($Delete, "Delete") ; *****
GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
Global $Backup = GUICtrlCreateButton("Sauvegarder Profil", 8, 128, 147, 33, $WS_GROUP)
GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
GUICtrlSetOnEvent($Backup, "Backup") ; *****
GUISetState(@SW_SHOW, $ChromeManager)
#EndRegion ### END Koda GUI section ###
 

voici une capture d'écran fait sur mon pc xp pro :

là on voit déja des soucis et sur mon pc branché à la tv , la police ne tient pas dans les boutons.
Je ferai une capture ce week end
C'est ennuyeux....

Merci à ceux qui me répondront.

Laddy

[TommyDDR]

Content de vous revoir laddy ^^

Pouvez vous poster une image de cette police débordante ?

[Laddy]

Bonjour TommyDDR
ah super je vois que tout le monde est là, moi de meme espere que vous allez bien.
Moi super

je ferai une capture d'écran ce soir ou demain à partir de ma tv

mERCI

[zeshrek]

Hello Laddy, content de te revoir.
Ici, j'ai pas acces aux PJ (si la mision se finissait pas dans 8 jours, je mettrai un proxy a la maison pour bypasser les restrictions... !), donc je peux pas trop regarder ce que tu fais, mais je regarderai ca ce soir

[mikell]

La fonction StringSize de Melba23 pourrait peut-être aider
Cette fonction calcule l'espace nécessaire dans un controle pour loger une string en fonction du texte et de la police utilisés
Mais on pourrait très bien l'employer pour faire l'inverse, càd calculer la taille de la police pour que la string rentre dans le controle en fonction du texte et de la place disponible

[Laddy]

Hello Zeshrek
contente d'avoir de tes nouvelles, je vois que tu es toujours au poste

mikell > merci je regarde dès que j'aurai un moment et surtout du temps pour tester car c'est ce qu'il ma manque le plus...et à la lecture des exemples ça m'air compliqué.

Edit : si je retire : GUICtrlSetFont(8, 10, 400, 0, "MS Sans Serif")
Ma police d'écriture est normal sous xp



Blop

[mikell]

à la lecture des exemples ça m'air compliqué

Pas vraiment...
C'est vrai que c'est peut-être un peu lourd pour ce que tu veux mais ça fonctionne
Ce script ajuste la taille de la police en fonction de la taille du bouton

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <SendMessage.au3>
#include <WinAPI.au3>

$txt  = "Test de police"
$gui = GUICreate("Test", 300, 300)
$btn1 = GUICtrlCreateButton($txt, 10, 10, 120, 40)
$btn2 = GUICtrlCreateButton($txt, 10, 60, 170, 45)
$btn3 = GUICtrlCreateButton($txt, 10, 115, 220, 50)
$btn4 = GUICtrlCreateButton($txt, 10, 175, 270, 55)
GUISetState()
    
$sFont = "Comic Sans MS"
$iWeight = 400
$iAttrib = 0

For $b = $btn1 To $btn4
    $pos = ControlGetPos ($gui, "", $b)
    For $i = 24 To 8 step -2
        $aMsgReturn = _StringSize($txt, $i, $iWeight, $iAttrib, $sFont) 
        If $aMsgReturn[2]<$pos[2] AND $aMsgReturn[3]<$pos[3] Then ExitLoop
    Next
    $iSize = $i
    GUICtrlSetFont($b, $iSize, $iWeight, $iAttrib, $sFont)
Next
    
While GUIGetMsg()<>-3  
WEnd

;-----------------------------------------------------------------------

Func _StringSize($sText, $iSize = Default, $iWeight = Default, $iAttrib = Default, $sName = Default, $iWidth = 0)
    
    Local $hWnd, $hFont, $hDC, $oFont, $tSize, $hGUI, $hText_Label, $sTest_Line
    Local $iLine_Width, $iWrap_Count, $iLast_Word, $iLine_Count 
    Local $asLines[1], $avSize_Info[4], $aiPos[4]
    If Not IsString($sText) Then Return SetError(1, 1, 0)
    If Not IsNumber($iSize) And $iSize <> Default   Then Return SetError(1, 2, 0)
    If Not IsInt($iWeight)  And $iWeight <> Default Then Return SetError(1, 3, 0)
    If Not IsInt($iAttrib)  And $iAttrib <> Default Then Return SetError(1, 4, 0)
    If Not IsString($sName) And $sName <> Default   Then Return SetError(1, 5, 0)
    If Not IsNumber($iWidth) Then Return SetError(1, 6, 0)

    $hGUI = GUICreate("", 1200, 500, 10, 10)
        If $hGUI = 0 Then Return SetError(2, 0, 0)
        GUISetFont($iSize, $iWeight, $iAttrib, $sName)
    $avSize_Info[0] = $sText
    If StringInStr($sText, @CRLF) = 0 Then StringRegExpReplace($sText, "[x0a|x0d]", @CRLF)
    $asLines = StringSplit($sText, @CRLF, 1)
    $hText_Label = GUICtrlCreateLabel($sText, 10, 10)
    $aiPos = ControlGetPos($hGUI, "", $hText_Label)
    GUICtrlDelete($hText_Label)
    $avSize_Info[1] = ($aiPos[3] - 8)/ $asLines[0]
    $avSize_Info[2] = $aiPos[2]
    $avSize_Info[3] = $aiPos[3] - 4; Reduce margin
    If $aiPos[2] > $iWidth And $iWidth > 0 Then
         $avSize_Info[0] = ""
        $avSize_Info[2] = $iWidth
         $iLine_Count = 0
         For $j = 1 To $asLines[0]
             $hText_Label = GUICtrlCreateLabel($asLines[$j], 10, 10)
            $aiPos = ControlGetPos($hGUI, "", $hText_Label)
            GUICtrlDelete($hText_Label)
            If $aiPos[2] < $iWidth Then
                 $iLine_Count += 1
                $avSize_Info[0] &= $asLines[$j] & @CRLF
            Else
                $hText_Label = GUICtrlCreateLabel("", 0, 0)
                $hWnd = ControlGetHandle($hGui, "", $hText_Label)
                $hFont = _SendMessage($hWnd, $WM_GETFONT)
                $hDC = _WinAPI_GetDC($hWnd)
                $oFont = _WinAPI_SelectObject($hDC, $hFont)
                If $oFont = 0 Then Return SetError(3, 0, 0)
                $iWrap_Count = 0

                While 1
                     $iLine_Width = 0
                     $iLast_Word = 0
                    For $i = 1 To StringLen($asLines[$j])
                        If StringMid($asLines[$j], $i, 1) = " " Then $iLast_Word = $i - 1
                         $sTest_Line = StringMid($asLines[$j], 1, $i)
                        GUICtrlSetData($hText_Label, $sTest_Line)
                        $tSize = _WinAPI_GetTextExtentPoint32($hDC, $sTest_Line)
                        $iLine_Width = DllStructGetData($tSize, "X")
                        If $iLine_Width >= $iWidth - Int($iSize / 2) Then ExitLoop
                    Next
                     If $i > StringLen($asLines[$j]) Then
                        $iWrap_Count += 1
                        $avSize_Info[0] &= $sTest_Line & @CRLF
                        ExitLoop
                    Else
                        $iWrap_Count += 1
                        If $iLast_Word = 0 Then
                            GUIDelete($hGUI)
                            Return SetError(4, 0, 0)
                        EndIf
                        $avSize_Info[0] &= StringLeft($sTest_Line, $iLast_Word) & @CRLF
                        $asLines[$j] = StringTrimLeft($asLines[$j], $iLast_Word)
                        $asLines[$j] = StringStripWS($asLines[$j], 1)
                    EndIf
                WEnd
                $iLine_Count += $iWrap_Count
                _WinAPI_ReleaseDC($hWnd, $hDC)
                GUICtrlDelete($hText_Label)
            EndIf
        Next
        $avSize_Info[3] = ($iLine_Count * $avSize_Info[1]) + 4
    EndIf
    GUIDelete($hGUI)
    Return $avSize_Info
EndFunc; => _StringSize
 

EDIT
et m... autant pour moi j'avais pas remarqué

Code : Tout sélectionner

GUICtrlSetFont([color=#FF0000]controlID[/color], 8, 10, 400, 0, "MS Sans Serif")

[Laddy]

Arf je me suis emmélée les pinceaux entre GuiSetFont, et GuiCtrlSetFont.
D'ailleurs je ne pense pas avoir saisi la différence entre les deux...

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;Opt("GUIOnEventMode", 1)
;GUIRegisterMsg($WM_COMMAND, "DoubleClick")

#Region ### START Koda GUI section ### Form=C:\Program Files\AutoIt3\SciTE\Koda\Forms\GuiChromeProfil.kxf
;GUI PRINCIPAL
Global $InstallDir, $UserName, $DossierSelectionne, $Form2, $VersionIni, $VersionBDR, $NOM_ZIP, $Resultat, $LBN_DBLCLK

Local $color = 0xFFFFFF

Global $ChromeManager = GUICreate("Google Chrome - Choisissez un profil utilisateur", 345, 218, 192, 124)
;;GUICtrlSetFont($ChromeManager,8, 10, 400, 0, "MS Sans Serif")
;GUISetOnEvent($GUI_EVENT_CLOSE, "Sortie")
$backgroundColor = GUISetBkColor($color, $ChromeManager)
Global $ListProfil = GUICtrlCreateList("", 168, 48, 169, 73)
Global $StartChrome = GUICtrlCreateButton("Demarrer Chrome", 144, 168, 97, 33, $WS_GROUP)
GUISetFont(8, 10, 400, 0, "MS Sans Serif")
;;GUICtrlSetFont(-1,8, 10, 400, 0, "MS Sans Serif")
;GUICtrlSetOnEvent($StartChrome, "Start") ; *****
Global $Quit = GUICtrlCreateButton("Quitter", 249, 168, 87, 33, $WS_GROUP)
;GUICtrlSetOnEvent($Quit, "Sortie") ; *****
Global $CreateProfil = GUICtrlCreateButton("Créer un profil", 8, 32, 145, 33, $WS_GROUP)
;GUICtrlSetOnEvent($CreateProfil, "CreateProfil") ; *****
GUISetFont(8, 10, 400, 0, "MS Sans Serif")
;;GUICtrlSetFont($CreateProfil,14, 10, 400, 0, "MS Sans Serif")
Global $Label1 = GUICtrlCreateLabel(" Chrome conserve vos préférences et paramètres dans votre profil", 8, 8, 324, 17)
GUISetFont(8, 10, 400, 0, "MS Sans Serif")
;;GUICtrlSetFont(-1,8, 10, 400, 0, "MS Sans Serif")
Global $Delete = GUICtrlCreateButton("Supprimer un profil", 8, 80, 145, 33, $WS_GROUP)
;GUICtrlSetOnEvent($Delete, "Delete") ; *****
GUISetFont(8, 10, 400, 0, "MS Sans Serif")
;;GUICtrlSetFont(-1,8, 10, 400, 0, "MS Sans Serif")
Global $Backup = GUICtrlCreateButton("Sauvegarder Profil", 8, 128, 147, 33, $WS_GROUP)
GUISetFont(8, 10, 400, 0, "MS Sans Serif")
;GUICtrlSetFont(-1,8, 10, 400, 0, "MS Sans Serif")
;GUICtrlSetOnEvent($Backup, "Backup") ; *****
GUISetState(@SW_SHOW, $ChromeManager)
#EndRegion ### END Koda GUI section ###

Do
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $StartChrome
            ;Start()
        Case $CreateProfil
            ;CreateProfil()
        Case $Delete
            ;Delete()
        Case $Backup
            ;Backup()
        Case $Quit
            Exit
    EndSwitch
Until $Msg = $GUI_EVENT_CLOSE
 

Voici le soucis dans je parle sur ma tv :


ma config tv :





Je pense que c'est à cause du 200% sur la police d'écriture mon but serait de fixer la taille de la gui et de la police d'écriture mais je ne sais pas si c'est possible.
Sur PC normal je n'ai pas ce type de bug.

Edit
mikell > je vais regarder ton script merci

[mikell]

Ben pourquoi ne pas imposer une taille de gui et de boutons à 200% en cas d'affichage à résolution TV ?
Si tu mets la taille de police à 200% pour mieux y voir, réduire ensuite la police serait pas logique ^^

[Laddy]

Me sens un peu stupide mais normalement cette ligne ne fixe pas la taille de la gui ?

Code : Tout sélectionner

Global $ChromeManager = GUICreate("Google Chrome - Choisissez un profil utilisateur", 345, 218, 192, 124)

pour ton idée, je ne vois pas comment faire.

[mikell]

Ben oui la taille de ta gui est fixée au départ
Mais ton problème est de faire rentrer une police de taille 200% dans une gui qui reste à 100%
Donc une solution est que le script au lancement détecte la résolution d'affichage, et si tu es en 1832x1042 alors il te fait une gui de taille 2, sinon il reste en taille 1
Ce genre de code devrait le faire

► Afficher le texte

Code : Tout sélectionner

Global $s
$resH = _GetCurrentDisplaySettings()
If $resH = 1832 Then
    $s = 2
Else
    $s = 1
EndIf
_Gui()

While 1
Sleep(10)
Wend


Func _Gui()
Global $ChromeManager = GUICreate("Google Chrome - Choisissez un profil utilisateur", 345*$s, 218*$s, 192, 124)
Global $ListProfil = GUICtrlCreateList("", 168*$s, 48*$s, 169*$s, 73*$s)
Global $StartChrome = GUICtrlCreateButton("Demarrer Chrome", 144*$s, 168*$s, 97*$s, 33*$s)
Global $Quit = GUICtrlCreateButton("Quitter", 249*$s, 168*$s, 87*$s, 33*$s)
Global $CreateProfil = GUICtrlCreateButton("Créer un profil", 8*$s, 32*$s, 145*$s, 33*$s)
Global $Label1 = GUICtrlCreateLabel(" Chrome conserve vos préférences...", 8*$s, 8*$s, 324*$s, 17*$s)
;Global $Delete = GUICtrlCreateButton("Supprimer un profil", 8, 80, 145, 33)
;Global $Backup = GUICtrlCreateButton("Sauvegarder Profil", 8, 128, 147, 33)
GUISetState()
EndFunc

Func _GetCurrentDisplaySettings()
Dim $Obj_WMIService = ObjGet('winmgmts:\\.\root\cimv2')
    Dim $Col_Items = $Obj_WMIService.ExecQuery('Select * from Win32_VideoController')
    For $Obj_Item In $Col_Items
        $curHR = $Obj_Item.CurrentHorizontalResolution
        $curVR = $Obj_Item.CurrentVerticalResolution
    Next
;msgbox(0,"", $curHR & " x " & $curVR)
Return $curHR
EndFunc
 

[Laddy]

Ok merci je vais tester ton code dès que possible, la tv est occupé lol

[zeshrek]

sinon, il y a la solution de contournement à la police de caractere zoomée à 200%.
Comment ?
En utilisant non pas un texte pour remplir les boutons mais une image. Par exemple celle du snapshot des boutons corrects de la version affichée sur moniteur. Ainsi, ca devient des bitmap, donc insensibilité au parametre de police.
Et pas besoin de détecter la résolution de l'écran, ce qui peut aussi etre la cause de dysfonctionnements. Qui peut dire qu'il n'y a pas un ordi/portable qui ne sera pas dans la même résolution que sa télé ?

[mikell]

Bien pensé les images pour les boutons
Mais ça ne résoud pas le problème de l'affichage dans la Listbox

[zeshrek]

Ah ouais... c'pas faux...
Alors plutot que de se baser sur la résolution de l'écran, il faudrait regarder dans la registry le facteur de multiplication de la police de facon a appliquer son inverse a la taille de la police utilisée dans la GUI.

Donc logiquement il faut lire le contenu de
Clé : HKEY_CURRENT_USER\Control Panel\Desktop
Valeur : LogPixels

Si la valeur existe pas, logiquement c'est qu'on n'a jamais changé ce parametre
Sinon (sous seven) elle contient :
- 96 quand on est a 100% (me demande pas pkoi c'est 96 et pas 100)
- 120 quand on est a 125% (meme remarque que ci dessus)
Pour les autres OS ou pour un autre facteur de zoom, m'est avis qu'il faudra faire des éssais.

Je vois pas mieux.

[Iste]

(me demande pas pkoi c'est 96 et pas 100)

car on parle de police est que par defaut on est a 96 pixels par pouce

[mikell]

Hmm dans ce cas alors utiliser

Code : Tout sélectionner

$objWMIService = ObjGet("winmgmts:\\.\root\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_DisplayConfiguration")
For $objItem In $colItems
      $ppp = $objItem.LogPixels 
Next
Msgbox(0,"","LogPixels : " & $ppp  & " ppp" )

et
$s = 100/$ppp
GUISetFont(Round(8*$s), 10, 400, 0, "MS Sans Serif")

[Laddy]

Bonjour à tous les deux

mikell > j'ai testé ton code sur la détection de la résolution ça fonctionne super bien l'interface apparait normalement maintenant.
J'ai testé sur le pc branché à ma tv, sur mon netbook (tous deux sous win 7) et sur mon pc win xp.

C'est sûr que si je vais sur une autre tv je me retrouverai avec le même soucis mais c'est déjà un pas.

Zeshrek > sur mon netbook LogPixels n'existe pas, je n'ai pas encore regardé sur ma tv je verrai plus tard quand elle sera libre et je testerai le retour du code de mikell

[mikell]

sur mon netbook LogPixels n'existe pas

Etrange...
Comme dit l'ogre la valeur LogPixels peut ne pas exister dans le registre si le paramètre n'a pas été changé, mais en détection WMI en principe on la récupère toujours
Sur une autre tv même avec une résolution différente ce n'est pas réellement un problème de résolution, c'est surtout le fait d'augmenter la taille de la police qui mène à augmenter celle de la gui, et LogPixels permettrait de récupérer ce paramètre d'augmentation de la taille de police donc de déterminer le facteur de taille à utiliser pour la gui
Heu je ne suis pas sûr d'avoir été très clair là

[Laddy]

Bonjour
j'ai pas pu testé le script mikell mais j'ai pu regarder la clé de registre donnée par ZeShrek.

LogPixels donne une valeur : 0x00000C (192)