[..] Suite de plusieurs GUI + CheckBox Actif

[locos974]

Bonjour,

Je voudrais faire que au lancement de mon script cela affiche ceci ( que la GUI avec Mot de passe )
Ces bien sûr 2 script séparé que je veux réunir

► Afficher le texte

$pass = "Les"
$input = InputBox("Utilisateurs", "Entrez le mot de passe :")

If ($input <> $pass) Then
MsgBox(0,"Utilisateurs", "Le mot de passe est incorrect !")
Else
MsgBox(0,"Utilisateurs", "Le mot de passe est correct !")
Run("C:\Users\Mathieu\AppData\Local\Google\Chrome\Application\Chrome.exe") ; lance Chrome
WinWaitActive ("Nouvel onglet - Google Chrome") ; Attend l'activation de Chrome
Sleep(150)
Send('facebook.com{enter}') ; Tape Facebook.com entrer
Sleep(500) ; Attend 500Milliseconde
Send('^t') ; Ouvre un nouvel onglet
Send('http://sn137w.snt137.mail.live.com/ {enter}') ; ouvre Hotmail et appuie sur ENTRER
Sleep(500) ; Attend 500Milliseconde
Send('^t') ; Ouvre un nouvel onglet
Send('http://radio.funradio.fr/player.html{enter}')
EndIf

Puis après avoir rentré le mot de passe qui suit de cette GUI
Comment faire que si le checkbox 1 et coché alors quand je fait OK ça lance le checkbox 1 et pas les autre ?

► Afficher le texte

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;===============================


#Region ### START Koda GUI section ### Form=
;============================================================
$Form1 = GUICreate("Utilisateurs Windows", 249, 218, 192, 114)

$Group1 = GUICtrlCreateGroup("Page à ouvrir :", 16, 32, 137, 177)
$Checkbox1 = GUICtrlCreateCheckbox("Facebook", 32, 80, 97, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Hotmail", 32, 104, 97, 17)
$Checkbox3 = GUICtrlCreateCheckbox("Funradio", 32, 128, 97, 17)
$Checkbox4 = GUICtrlCreateCheckbox("Blog Espagnol", 32, 152, 97, 17)
$Checkbox5 = GUICtrlCreateCheckbox("Google", 32, 56, 97, 17)
$Checkbox6 = GUICtrlCreateCheckbox("AutoIt Forum", 32, 176, 97, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Label1 = GUICtrlCreateLabel("Choissisez les pages que vous souhaitez ouvrir.", 16, 8, 228, 17)
$Button1 = GUICtrlCreateButton("Quitter", 176, 152, 57, 49, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Lancer", 176, 48, 57, 49, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Nettoyer", 176, 112, 57, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Checkbox1
Case $Checkbox2
Case $Checkbox3
Case $Checkbox4
Case $Checkbox5
Case $Checkbox6
EndSwitch
WEnd

Merci de vos réponse si cela ne vous aide pas dans les explication demandez moi en plus.
Cordialement Locos.

[locos974]

Up svp ?

[ZDS]

Bonjour,

A toi de voir si ça te convient.

► Afficher le texteFusion des deux codes

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;===============================

Local $adresse[7] = [6]
$adresse[1] = "facebook.com"
$adresse[2] = "http://sn137w.snt137.mail.live.com/"
$adresse[3] = "http://radio.funradio.fr/player.html"
$adresse[4] = ""
$adresse[5] = ""
$adresse[6] = ""

#Region ### START Koda GUI section ### Form=
;============================================================
$Form1 = GUICreate("Utilisateurs Windows", 249, 218, 192, 114)

$Group1 = GUICtrlCreateGroup("Page à ouvrir :", 16, 32, 137, 177)
Local $checkbox[7] = [6]
$Checkbox[1] = GUICtrlCreateCheckbox("Facebook", 32, 80, 97, 17)
$Checkbox[2] = GUICtrlCreateCheckbox("Hotmail", 32, 104, 97, 17)
$Checkbox[3] = GUICtrlCreateCheckbox("Funradio", 32, 128, 97, 17)
$Checkbox[4] = GUICtrlCreateCheckbox("Blog Espagnol", 32, 152, 97, 17)
$Checkbox[5] = GUICtrlCreateCheckbox("Google", 32, 56, 97, 17)
$Checkbox[6] = GUICtrlCreateCheckbox("AutoIt Forum", 32, 176, 97, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Label1 = GUICtrlCreateLabel("Choissisez les pages que vous souhaitez ouvrir.", 16, 8, 228, 17)
$Button1 = GUICtrlCreateButton("Quitter", 176, 152, 57, 49, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Lancer", 176, 48, 57, 49, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Nettoyer", 176, 112, 57, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $Button2
        $pass = "Les"
        $input = InputBox("Utilisateurs", "Entrez le mot de passe :")

        If ($input <> $pass) Then
            MsgBox(0,"Utilisateurs", "Le mot de passe est incorrect !")
        Else
            MsgBox(0,"Utilisateurs", "Le mot de passe est correct !")
            $premiere_page = True ; Je suis à la premiere page à ouvrir
            Run("C:\Users\Mathieu\AppData\Local\Google\Chrome\Application\Chrome.exe") ; lance Chrome
            WinWaitActive ("Nouvel onglet - Google Chrome") ; Attend l'activation de Chrome
            Sleep(150)
            For $i = 1 To $adresse[0]
                If isChecked($Checkbox[$i]) Then
                    If Not $premiere_page Then Send('^t')
                    Send($adresse[$i], 1)
                    Send("{enter}")
                    Sleep(500)
                    $premiere_page = False
                EndIf
            Next
        EndIf
    EndSwitch
WEnd

Func isChecked($checkbox)
    Return BitAND(GUICtrlRead($checkbox),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

A bientôt !

[locos974]

C'est pas totalement ce que je voulait mais franchement cela me plaît déjà bien !
Mon idée en faite, que quand le script ce lance :
- Première GUI = Rentré le mot de Passe
- Si mot de passe correct ouvrir la GUI avec les checkBox
- Si le checkbox 1 et sélection ouvrir page Google.fr par exemple
- Si le code est erroné alors fermez le programme OU si possible il y a 3 essaie e après il ce ferme.

Désolé des fautes d'orthographe.. Merci déjà pour l'avancement !

[PandiPanda]

ceci? ^^
a vous de remplir les "blanc" :p

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $pass="Les",$mdp="",$cptMdp=0,$Form1,$Group1,$Checkbox1,$Checkbox2,$Checkbox3, _
$Checkbox4,$Checkbox5,$Checkbox6,$Label1,$Button1,$Button2,$Button3

_DemandeMdp() ; on demande le mot de passe, possibilite de 3 essai
_GuiMain() ; on affiche la GUI principale si Mdp est bon

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button2
            Select
                Case isChecked($Checkbox1)
                    _runFacebook()
                Case isChecked($Checkbox2)
                    ; a completer
                Case isChecked($Checkbox3)
                    ; a completer
                Case isChecked($Checkbox4)
                    ; a completer
                Case isChecked($Checkbox5)
                    _runGoogle()
                Case isChecked($Checkbox6)
                    ; a completer
            EndSelect
    EndSwitch
WEnd

Func _DemandeMdp()
    $mdp = InputBox("Utilisateurs", "Entrez le mot de passe :"&@CRLF&"Test restant "&3-$cptMdp&"/3","","*")
    If $pass <> $mdp Then
        $cptMdp=$cptMdp+1
        If $cptMdp = 3 Then Exit
        _DemandeMdp()
    Else
        MsgBox(0,"Utilisateurs", "Le mot de passe est correct !")
    EndIf
EndFunc

Func _runGoogle()
    ShellExecute("http://google.be")
EndFunc
Func _runFacebook()
    ShellExecute("http://google.be")
EndFunc

Func _GuiMain()
    $Form1 = GUICreate("Utilisateurs Windows", 249, 218, 192, 114)
    $Group1 = GUICtrlCreateGroup("Page à ouvrir :", 16, 32, 137, 177)
    $Checkbox1 = GUICtrlCreateCheckbox("Facebook", 32, 80, 97, 17)
    $Checkbox2 = GUICtrlCreateCheckbox("Hotmail", 32, 104, 97, 17)
    $Checkbox3 = GUICtrlCreateCheckbox("Funradio", 32, 128, 97, 17)
    $Checkbox4 = GUICtrlCreateCheckbox("Blog Espagnol", 32, 152, 97, 17)
    $Checkbox5 = GUICtrlCreateCheckbox("Google", 32, 56, 97, 17)
    $Checkbox6 = GUICtrlCreateCheckbox("AutoIt Forum", 32, 176, 97, 17)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $Label1 = GUICtrlCreateLabel("Choissisez les pages que vous souhaitez ouvrir.", 16, 8, 228, 17)
    $Button1 = GUICtrlCreateButton("Quitter", 176, 152, 57, 49, $WS_GROUP)
    $Button2 = GUICtrlCreateButton("Lancer", 176, 48, 57, 49, $WS_GROUP)
    $Button3 = GUICtrlCreateButton("Nettoyer", 176, 112, 57, 25, $WS_GROUP)
    GUISetState(@SW_SHOW)
EndFunc

Func isChecked($checkbox)
    Return BitAND(GUICtrlRead($checkbox),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

[ZDS]

Re,

Tu n'as qu'à inverser les deux blocs dans le code, et brancher correctement :

► Afficher le texteDemande de code avant GUI principale

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;===============================

Local $ok = False, $essai = 3, $pass = "Les"
Do
    $essai = $essai - 1
    $input = InputBox("Utilisateurs", "(essais restants : " & $essai & ")" & @CRLF & "Entrez le mot de passe :")
    $ok = ($input = $pass)
Until $essai = 0 Or $ok = True
If $ok = False Then
    MsgBox(0,"Utilisateurs", "3 pass incorrects, sortie !")
    Exit
EndIf

Local $adresse[7] = [6]
$adresse[1] = "facebook.com"
$adresse[2] = "http://sn137w.snt137.mail.live.com/"
$adresse[3] = "http://radio.funradio.fr/player.html"
$adresse[4] = ""
$adresse[5] = ""
$adresse[6] = ""

#Region ### START Koda GUI section ### Form=
;============================================================
$Form1 = GUICreate("Utilisateurs Windows", 249, 218, 192, 114)

$Group1 = GUICtrlCreateGroup("Page à ouvrir :", 16, 32, 137, 177)
Local $checkbox[7] = [6]
$Checkbox[1] = GUICtrlCreateCheckbox("Facebook", 32, 80, 97, 17)
$Checkbox[2] = GUICtrlCreateCheckbox("Hotmail", 32, 104, 97, 17)
$Checkbox[3] = GUICtrlCreateCheckbox("Funradio", 32, 128, 97, 17)
$Checkbox[4] = GUICtrlCreateCheckbox("Blog Espagnol", 32, 152, 97, 17)
$Checkbox[5] = GUICtrlCreateCheckbox("Google", 32, 56, 97, 17)
$Checkbox[6] = GUICtrlCreateCheckbox("AutoIt Forum", 32, 176, 97, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Label1 = GUICtrlCreateLabel("Choissisez les pages que vous souhaitez ouvrir.", 16, 8, 228, 17)
$Button1 = GUICtrlCreateButton("Quitter", 176, 152, 57, 49, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Lancer", 176, 48, 57, 49, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Nettoyer", 176, 112, 57, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $Button2
        $premiere_page = True ; Je suis à la premiere page à ouvrir
        Run("C:\Users\Mathieu\AppData\Local\Google\Chrome\Application\Chrome.exe") ; lance Chrome
        WinWaitActive ("Nouvel onglet - Google Chrome") ; Attend l'activation de Chrome
        Sleep(150)
        For $i = 1 To $adresse[0]
            If isChecked($Checkbox[$i]) Then
                If Not $premiere_page Then Send('^t')
                Send($adresse[$i], 1)
                Send("{enter}")
                Sleep(500)
                $premiere_page = False
            EndIf
        Next
    EndSwitch
WEnd

Func isChecked($checkbox)
    Return BitAND(GUICtrlRead($checkbox),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

A bientôt.

[locos974]

Bravo ! une fois de plus sans aucune aide je n'aurais jamais pu finir mon script..
Merci à vous deux c'est sympas .
Et une dernière question lequel d'entre vous deux est le plus fiable ?
EDIT : Du script bien entendue

[mikell]

Et une dernière question lequel d'entre vous deux est le plus fiable ?

Hum hum
Entre un panda belge et un breton dofussomaniaque le choix est hard




.....

[locos974]

Et pour le bouton "Nettoyer" c'est faisable ou pas ?