[R] Fermeture GUI ne fonctionne pas en cours de programme

[pierrotm777]

Bonjour,
Je me sent un peu idiot sur le coup car comme dirait Tlem, depuis le temps je devrais ne plus avoir ce genre de souci.
Et pourtant, dans le script suivant:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GuiUpdateTest", 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)

$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)

GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)

GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)

$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)

GUICtrlCreateGroup("", -99, -99, 1, 1)

$Button7 = GUICtrlCreateButton("Exit", 500, 272, 100, 33, $WS_GROUP)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button7
            Exit
        Case $Button1
            For $i= 0 to 65535 step Round(65535/20,0)
                GUICtrlSetData($Input7,$i)
                sleep(2000)
            Next
    EndSwitch
    sleep(100)
WEnd

Après appuie sur le bouton "Send Command", je suis obligé d'attendre que la boucle for..next soit finie pour avoir accès à nouveau au bouton exit ou la croix de fermeture de la GUI .

Merci de votre aide par avance !

[PandiPanda]

normal,le for .. next et le sleep() sont bloquant !

changer le sleep(2000) par la fonction ci dessous;

► Afficher le texte

Code : Tout sélectionner

Func _Wait($sleep,$GUI=False,$ms=True)
    Local $Time_Ini=TimerInit()
    If IsInt($sleep) And IsBool($GUI) And IsBool($ms) Then
        Local $nbSec
        If $ms Then
            $nbSec=1
        Else
            $nbSec=1000
        EndIf
        If $GUI Then
            Do
                Local $tmpMsg=GUIGetMsg()
                Sleep(10)
                If TimerDiff($Time_Ini) >= $sleep*$nbSec Then ExitLoop
            Until $tmpMsg=$GUI_EVENT_CLOSE
        Else
            Do
                Sleep(10)
            Until TimerDiff($Time_Ini) >= $sleep*$nbSec
        EndIf
    Else
        SetError(1)
    EndIf
EndFunc

Donc comme ceci;

► Afficher le texte

Code : Tout sélectionner

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button7
            Exit
        Case $Button1
            For $i= 0 to 65535 step Round(65535/20,0)
                GUICtrlSetData($Input7,$i)
                _Wait(2000,True)
            Next
    EndSwitch
    _Wait(100,True)
WEnd

[pierrotm777]

Cela ne fonctionne pas chez moi !

[PandiPanda]

étrange m'enfin le problème réside dans votre sleep(2000) ainsi que votre boucle for... next
ceci ?

► Afficher le texte

Code : Tout sélectionner

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button7
            Exit
        Case $Button1
            Local $sleep
            For $i=0 to 65535 step Round(65535/20,0)
                $sleep=2000 ; le temps du sleep
                Do
                    Sleep(10)
                    $sleep-=10
                    If GUIGetMsg()=$GUI_EVENT_CLOSE Then Exit
                Until $sleep=0
                GUICtrlSetData($Input7,$i)
            Next
    EndSwitch
WEnd

Edit: supprimer les lignes superflue ...

[pierrotm777]

Là, ma boucle ne démarre pas !

[pierrotm777]

Ah, là ça fonctionne !
J'ai du modifier le $sleep = 2000 par $sleep = 1000 car la boucle dépassait les 2 secondes.
Y aurait il une autre solution que ma boucle for..next , car cela me semble très lourd !

[pierrotm777]

Pour le bouton Exit , j'ai tenté d'ajouter:

Code : Tout sélectionner

If GUIGetMsg()=$Button7 Then Exit

mais sans succès !

[ZDS]

Bonjour,

Je confirme, le sleep enm***e le monde. Il bouffe certains événements du GUIGetMsg et en laisse passer d'autres (comme le -8 et -11).

► Afficher le texteScript avec décrochage de boucle For

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GuiUpdateTest", 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)

$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)

GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)

GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)

$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)

GUICtrlCreateGroup("", -99, -99, 1, 1)

$Button7 = GUICtrlCreateButton("Exit", 500, 272, 100, 33, $WS_GROUP)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE, $Button7
        $stop = True
    Case $Button1
        Local $step = Round(65535/20,0)
        For $i= 0 to 65535
            ; Valeur à afficher (""&... pour convertir en chaine, et non en nombre)
            Local $valeur = ""&$i-Mod($i,$step)
            ; Si la valeur a changé, on l'affiche
            If GUICtrlRead($Input7) <> $valeur Then GUICtrlSetData($Input7,$valeur)
            $msg = GUIGetMsg()
            If $msg = $GUI_EVENT_CLOSE Or $msg = $Button7 Then
                $stop = True
                ExitLoop
            EndIf
        Next
    EndSwitch
WEnd

Autre solution en utilisant un timer:

► Afficher le texteScript avec utilisation d'un timer

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GuiUpdateTest", 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)

$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)

GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)

GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)

$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)

GUICtrlCreateGroup("", -99, -99, 1, 1)

$Button7 = GUICtrlCreateButton("Exit", 500, 272, 100, 33, $WS_GROUP)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE, $Button7
        $stop = True
    Case $Button1
        For $i= 0 to 65535 Step Round(65535/20,0)
            GUICtrlSetData($Input7,$i)
            Local $timer = TimerInit()
            Do
                $msg = GUIGetMsg()
                $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
            Until TimerDiff($timer)>2000 Or $stop
            If $stop Then ExitLoop
        Next
    EndSwitch
WEnd

A bientôt!

PS: Panda, ça serait vraiment bien que tu testes ton script avant de le fournir ^^ Ton timer ne sert pas à grand chose dans ta boucle. Et faire des sleep(10) à la chaine consomme plus de temps à se lancer et faire le reste du code qu'à s'exécuter en l'état. 200 sleep(10) ne prennent pas le même temps que sleep(2000).

[PandiPanda]

désoler oubliez de l'enlever ^^
c'etais de mon script écrit avant ... j'enleve desuite.

[pierrotm777]

Merci beaucoup ZDS,
C'est impeccable !

Merci aussi à PandiPanda qui vient de se faire enguirlander par ma faute !!!

[Baku]

Et pourquoi ne pas simplement utiliser GUICtrlSetOnEvent ?

[pierrotm777]

J'avais essayé mais avec le même problème dans mes boucles for..next.

Juste une autre question !
Si je veux avec le même bouton stop le décomptage sans quitter mais GUI, j'ai testé cela:

► Afficher le texte

Code : Tout sélectionner

    Case $Button1
        GUICtrlSetData($Button1,"Stop Command")
        For $i= 0 to 65535 Step Round(65535/20,0)
            GUICtrlSetData($Input7,$i)
            Local $timer = TimerInit()
            Do
                $msg = GUIGetMsg()
                $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
                If $msg = $Button1 Then
                    GUICtrlSetData($Button1,"Send Command")

                EndIf
            Until TimerDiff($timer)>2000 Or $stop
            If $stop Then ExitLoop
        Next

[mikell]

Dans ce cas-là ça serait plutôt comme ça (credits to ZDS )

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GuiUpdateTest", 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)
$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)
GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)
GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)
$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button7 = GUICtrlCreateButton("Stop décompte", 480, 272, 120, 33, $WS_GROUP)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Local $stop = False
Local $decompt = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE
        $stop = True
   Case $Button7
        $decompt = True
    Case $Button1
        For $i= 0 to 65535 Step Round(65535/20,0)
            GUICtrlSetData($Input7,$i)
            Local $timer = TimerInit()
            Do
                $msg = GUIGetMsg()
                $stop = ($msg = $GUI_EVENT_CLOSE) 
                $decompt = ($msg = $Button7)
            Until TimerDiff($timer)>2000 Or $stop Or $decompt
            If $stop Then ExitLoop
            If $decompt Then 
                $i = 65535      ; <= bourrin mais toujours efficace 
                $ridzevaleur = GuiCtrlRead($Input7)
                MsgBox(0,"", " décompte arrêté à " & $ridzevaleur)
                GUICtrlSetData($Input7,"-")
                $decompt = False
               ; etc
           EndIf
        Next
    EndSwitch
WEnd
 

[ZDS]

Bonjour,

La solution de Mikell fonctionne très bien, mais ayant une préférence pour l'évolution la plus simple possible d'un code existant, voici une autre (algorithmiquement, ça change pas grand chose, mais ça fonctionne pareil, ça n'utilise pas de booléen supplémentaire en fait) :

► Afficher le texteScript avec interruption de la boucle

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
Local $TITRE = "GuiUpdateTest"
$Form1 = GUICreate($TITRE, 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)
$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)
GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)
GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)
$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button7 = GUICtrlCreateButton("Close", 480, 272, 120, 33, $WS_GROUP)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE,$Button7
        $stop = True
    Case $Button1
        Local $texte_Button7 = GUICtrlRead($Button7)
        GUICtrlSetData($Button7,"Cancel")
        For $i= 0 to 65535 Step Round(65535/20,0)
            GUICtrlSetData($Input7,$i)
            Local $timer = TimerInit()
            Do
                $msg = GUIGetMsg()
                $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
            Until TimerDiff($timer)>2000 Or $stop
            If $stop Then
                If $msg = $Button7 Then
                    TrayTip($TITRE, "décompte arrêté à " & GuiCtrlRead($Input7),30,2)
                    $stop = False
                EndIf
                ExitLoop
           EndIf
        Next
        GUICtrlSetData($Button7,$texte_Button7)
    EndSwitch
WEnd

A bientôt !

[pierrotm777]

C'est super ZDS,
Mais en fait j'aurais besoin de six fonctions identiques, j'ai donc modifié ton script ainsi mais

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
Local $TITRE = "GuiUpdateTest"
$Form1 = GUICreate($TITRE, 635, 323, 192, 124)
$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
$Input1 = GUICtrlCreateInput("DFXSPEED", 110, 32, 113, 21)
$Input2 = GUICtrlCreateInput("", 110, 64, 113, 21)
$Input3 = GUICtrlCreateInput("", 110, 96, 113, 21)
$Button1 = GUICtrlCreateButton("Send Command", 500, 32, 100, 25, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Send Command", 500, 64, 100, 25, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Send Command", 500, 96, 100, 25, $WS_GROUP)
GUICtrlCreateLabel("Indicator Name :", 24, 32, 82, 17)
GUICtrlCreateLabel("Indicator Name :", 24, 64, 82, 17)
GUICtrlCreateLabel("Indicator Name :", 24, 96, 82, 17)
GUICtrlCreateLabel("Indicator Value :", 232, 32, 82, 17)
GUICtrlCreateLabel("Indicator Value :", 232, 64, 82, 17)
GUICtrlCreateLabel("Indicator Value :", 232, 96, 82, 17)
$Input7 = GUICtrlCreateInput("-", 318, 32, 113, 21)
$Input8 = GUICtrlCreateInput("-", 318, 64, 113, 21)
$Input9 = GUICtrlCreateInput("-", 318, 96, 113, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)

$Group2 = GUICtrlCreateGroup("Sliders Update", 16, 136, 601, 121)
$Input4 = GUICtrlCreateInput("GPXSLIDER1", 110, 160, 113, 21)
$Input5 = GUICtrlCreateInput("", 110, 192, 113, 21)
$Input6 = GUICtrlCreateInput("", 110, 224, 113, 21)
$Button4 = GUICtrlCreateButton("Send Command", 500, 160, 100, 25, $WS_GROUP)
$Button5 = GUICtrlCreateButton("Send Command", 500, 192, 100, 25, $WS_GROUP)
$Button6 = GUICtrlCreateButton("Send Command", 500, 224, 100, 25, $WS_GROUP)
GUICtrlCreateLabel("Slider Name :", 24, 160, 82, 17)
GUICtrlCreateLabel("Slider Name :", 24, 192, 82, 17)
GUICtrlCreateLabel("Slider Name :", 24, 224, 82, 17)
GUICtrlCreateLabel("Slider Value :", 232, 160, 82, 17)
GUICtrlCreateLabel("Slider Value :", 232, 192, 82, 17)
GUICtrlCreateLabel("Slider Value :", 232, 224, 82, 17)
$Input10 = GUICtrlCreateInput("-", 318, 160, 113, 21)
$Input11 = GUICtrlCreateInput("-", 318, 192, 113, 21)
$Input12 = GUICtrlCreateInput("-", 318, 224, 113, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button7 = GUICtrlCreateButton("Exit", 500, 272, 100, 33, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
If GUICtrlRead($Input1) = "" Then GUICtrlSetState($Button1,$GUI_DISABLE)
If GUICtrlRead($Input2) = "" Then GUICtrlSetState($Button2,$GUI_DISABLE)
If GUICtrlRead($Input3) = "" Then GUICtrlSetState($Button3,$GUI_DISABLE)
If GUICtrlRead($Input4) = "" Then GUICtrlSetState($Button4,$GUI_DISABLE)
If GUICtrlRead($Input5) = "" Then GUICtrlSetState($Button5,$GUI_DISABLE)
If GUICtrlRead($Input6) = "" Then GUICtrlSetState($Button6,$GUI_DISABLE)

#cs
Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE,$Button7
        $stop = True
    Case $Button1
        Local $texte_Button7 = GUICtrlRead($Button7)
        GUICtrlSetData($Button7,"Cancel")
        For $i= 0 to 65535 Step Round(65535/20,0)
            GUICtrlSetData($Input7,$i)
            Local $timer = TimerInit()
            Do
                $msg = GUIGetMsg()
                $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
            Until TimerDiff($timer)>2000 Or $stop
            If $stop Then
                If $msg = $Button7 Then
                    TrayTip($TITRE, "décompte arrêté à " & GuiCtrlRead($Input7),30,2)
                    $stop = False
                EndIf
                ExitLoop
           EndIf
        Next
        GUICtrlSetData($Button7,$texte_Button7)
    EndSwitch
WEnd
#ce
;#cs
Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE,$Button7
            $stop = True
        Case $Button1
            Local $texte_Button1 = GUICtrlRead($Button1)
            GUICtrlSetData($Button1,"Stop Command")
            For $i= 0 to 65535 Step Round(65535/20,0)
                GUICtrlSetData($Input7,$i)
                Local $timer = TimerInit()
                Do
                    $msg = GUIGetMsg()
                    $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
                Until TimerDiff($timer)>2000 Or $stop
                If $stop Then
                    If $msg = $Button1 Then
                        TrayTip($TITRE, "décompte arrêté à " & GuiCtrlRead($Input7),30,2)
                        $stop = False
                    EndIf
                    ExitLoop
               EndIf
            Next
            GUICtrlSetData($Button1,$texte_Button1)

        Case $Button2
            Local $texte_Button2 = GUICtrlRead($Button2)
            GUICtrlSetData($Button2,"Stop Command")
            For $i= 0 to 65535 Step Round(65535/20,0)
                GUICtrlSetData($Input8,$i)
                Local $timer = TimerInit()
                Do
                    $msg = GUIGetMsg()
                    $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7)
                Until TimerDiff($timer)>2000 Or $stop
                If $stop Then
                    If $msg = $Button2 Then
                        TrayTip($TITRE, "décompte arrêté à " & GuiCtrlRead($Input8),30,2)
                        $stop = False
                    EndIf
                    ExitLoop
               EndIf
            Next
            GUICtrlSetData($Button2,$texte_Button2)


        Case $Input1
            If GUICtrlRead($Input1) <> "" Then GUICtrlSetState($Button1,$GUI_ENABLE)
        Case $Input2
            If GUICtrlRead($Input2) <> "" Then GUICtrlSetState($Button2,$GUI_ENABLE)
        Case $Input3
            If GUICtrlRead($Input3) <> "" Then GUICtrlSetState($Button3,$GUI_ENABLE)
        Case $Input4
            If GUICtrlRead($Input4) <> "" Then GUICtrlSetState($Button4,$GUI_ENABLE)
        Case $Input5
            If GUICtrlRead($Input5) <> "" Then GUICtrlSetState($Button5,$GUI_ENABLE)
        Case $Input6
            If GUICtrlRead($Input6) <> "" Then GUICtrlSetState($Button6,$GUI_ENABLE)
    EndSwitch

WEnd

[ZDS]

6 fonctions identiques, utilise plutôt un tableau.
Je te prépare ça après bouffer.

Bon appétit !

[pierrotm777]

Bon appétit

[ZDS]

Re,

► Afficher le texteComment ne pas répéter 6 fois les mêmes lignes de code

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Local $TITRE = "GuiUpdateTest"
Local $NOMBRE = 6

Local $Inputs_Name[$NOMBRE] ; Liste des inputs pour les "Indicator Name" et les "Slider Name"
Local $Inputs_Value[$NOMBRE] ; Liste des inputs pour les "Indicator Value" et les "Slider Value"
Local $Buttons[$NOMBRE] ; Liste des boutons "Send Command" pour les "Indicators" et les "Sliders"

$Form1 = GUICreate($TITRE, 635, 323, 192, 124)

$Group1 = GUICtrlCreateGroup("Indicators Update", 16, 8, 601, 121)
For $i = 0 To $NOMBRE/2-1
    GUICtrlCreateLabel("Indicator Name :",       24, 32+32*$i,  82, 17)
    $Inputs_Name[$i] = GUICtrlCreateInput("",   110, 32+32*$i, 113, 21)
    GUICtrlCreateLabel("Indicator Value :",     232, 32+32*$i,  82, 17)
    $Inputs_Value[$i] = GUICtrlCreateInput("-", 318, 32+32*$i, 113, 21)
    $Buttons[$i] = GUICtrlCreateButton("Send Command", 500, 32+32*$i, 100, 25, $WS_GROUP)
Next
GUICtrlSetData($Inputs_Name[0], "DFXSPEED")

$Group2 = GUICtrlCreateGroup("Sliders Update", 16, 136, 601, 121)
For $i = $NOMBRE/2 To $NOMBRE-1
    GUICtrlCreateLabel("Slider Name :",          24, 64+32*$i,  82, 17)
    $Inputs_Name[$i] = GUICtrlCreateInput("",   110, 64+32*$i, 113, 21)
    GUICtrlCreateLabel("Slider Value :",        232, 64+32*$i,  82, 17)
    $Inputs_Value[$i] = GUICtrlCreateInput("-", 318, 64+32*$i, 113, 21)
    $Buttons[$i] = GUICtrlCreateButton("Send Command", 500, 64+32*$i, 100, 25, $WS_GROUP)
Next
GUICtrlSetData($Inputs_Name[3], "GPXSLIDER1")

GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button7 = GUICtrlCreateButton("Exit", 500, 272, 100, 33, $WS_GROUP)

GUISetState(@SW_SHOW)

Local $stop = False
While Not $stop
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Or $msg = $Button7 Then
        $stop = True
    Else
        For $i = 0 To $NOMBRE-1
            GUICtrlSetStateIfNotAlready($Buttons[$i],cond(GUICtrlRead($Inputs_Name[$i])="",$GUI_DISABLE,$GUI_ENABLE))
        Next
        For $i = 0 To $NOMBRE-1
            If $msg = $Buttons[$i] Then
                Local $texte_Button = GUICtrlRead($Buttons[$i])
                GUICtrlSetData($Buttons[$i],"Stop Command")
                For $k = 0 To $NOMBRE-1
                    If ($k<$NOMBRE/2 And $i<$NOMBRE/2) Or ($k>=$NOMBRE/2 And $i>=$NOMBRE/2) Then
                        GUICtrlSetStateIfNotAlready($Buttons[$k],cond($i=$k,$GUI_ENABLE,$GUI_DISABLE))
                    EndIf
                Next
                For $k= 0 to 65535 Step Round(65535/20,0)
                    GUICtrlSetData($Inputs_Value[$i],$k)
                    Local $timer = TimerInit()
                    Do
                        $msg = GUIGetMsg()
                        $stop = ($msg = $GUI_EVENT_CLOSE Or $msg = $Button7 Or $msg = $Buttons[$i])
                    Until TimerDiff($timer)>2000 Or $stop
                    If $stop Then
                        If $msg = $Buttons[$i] Then
                            TrayTip($TITRE, "décompte arrêté à " & GuiCtrlRead($Inputs_Value[$i]),30,2)
                            $stop = False
                        EndIf
                        ExitLoop
                   EndIf
                Next
                GUICtrlSetData($Buttons[$i],$texte_Button)
            EndIf
        Next
    EndIf
WEnd

Func cond($cond, $true, $false)
    If $cond Then Return $true
    Return $false
EndFunc

Func GUICtrlSetStateIfNotAlready($control,$state)
    If BitAND(GUICtrlGetState($control),$state) <> $state Then
        GUICtrlSetState($control, $state)
    EndIf
EndFunc

Par contre, quand tu rentres dans la boucle d'attente quand la value d'un indicator bouge de 0 à 65535, tu ne peux pas cliquer sur les boutons d'un slider, et inversement. Pour faire fonctionner le tout parallèlement, c'est beaucoup plus de code qu'il faudra pondre ^^

A bientôt!

[pierrotm777]

Merci beaucoup ZDS.
Cela me convient tout à fait !

[pierrotm777]

J'ai ajouté la possibilité de choisir entre 3 variations possible (0->65535) ou (65535->0) ou (0->65535 puis 65535-> 0 en boucle).
Les deux premières options fonctionnent, mais pour la troisième j'ai bien la mise en boucle pas pas d'arrêt possible !