[..] Création de label automatique

[Xtroyer]

Bonsoir à tous =)

Voilà, j'ai un petit soucis, en effet, pour mon programme permettant de gérer ces comptes d'un jeu quel qu’il soit, l'utilisateur rempli des Edits ensuite enregistrés dans un INI de la manière suivante :

Code : Tout sélectionner

If FileExists(@DocumentsCommonDir & "\Comptes.ini") = 0 Then
    $chiffre = 0
Else
    $chiffre = IniRead(@DocumentsCommonDir & "\Compte.ini", "Nombre de compte", "NoDC", 0)
    $chiffre += 1
EndIf
IniWrite(@DocumentsCommonDir & "\Comptes.ini", "Nombre de compte", "NoDC", $chiffre)
IniWrite(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "NDC" & $chiffre, GUICtrlRead($IP_NDC))
IniWrite(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "MDP" & $chiffre, GUICtrlRead($IP_MDP))
IniWrite(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Serveur" & $chiffre, GUICtrlRead($IP_SER))
IniWrite(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "lvl" & $chiffre, GUICtrlRead($IP_LVL))
EndIf

Ensuite, on les récupère puis on les dispose dans un Group dans une GUI :

Code : Tout sélectionner

If FileExists(@DocumentsCommonDir & "\Comptes.ini") = 0 Then
For $i = 0 To IniRead(@DocumentsCommonDir & "\Comptes.ini", "Nombre de compte", "NoDC", 0) Step 1
If $i = 0 Then
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "NDC" & $i, 0), 16, 104, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "MDP" & $i, 0), 176, 104, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Serveur" & $i, 0), 336, 104, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "lvl" & $i, 0), 432, 104, 4, 4)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
Else
    $pos += 10
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "NDC" & $i, 0), 16, 104 + $pos, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "MDP" & $i, 0), 176, 104 + $pos, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Serveur" & $i, 0), 336, 104 + $pos, 4, 4)
    $Label & $i = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "lvl" & $i, 0), 432, 104 + $pos , 4, 4)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
EndIf
Next
EndIf

Mais manque de pot ça fonctionne pas du tout quant à la création des label x) Une erreur de syntaxe au niveau de la création que je ne sais résoudre

Des idées ?

[jchd]

Utilise un tableau d'identifiants, c'est mille fois plus propre et facile que Assign() (ce que tu voulais faire).

[mikell]

Code : Tout sélectionner

$Label [color=#FF0000]& $i[/color] = GUICtrlCreateLabel()  ;  pas bon
$Label [color=#FF0000][$i][/color] = GUICtrlCreateLabel()   ; ça oui

[Xtroyer]

J'y ai pensé ce matin dans le RER x) je test de suite =)

[mikell]

Il me semble que ça devrait donner quelque chose de ce genre

► Afficher le texte

Code : Tout sélectionner

$ini = @DocumentsCommonDir & "\Comptes.ini"
$nb = IniRead($ini, "Nombre de compte", "NoDC", "0")

Dim $Label[$nb][4]
Dim $identifiants[4] = ["NDC", "MDP", "Serveur", "lvl"]
$left = 16
$pos = 104

For $i = 0 To $nb-1
    For $j = 0 To 3
        $item = IniRead($ini, "Comptes", $identifiants[$j] & $i, "0")
        $Label[$i][$j] = GUICtrlCreateLabel($item, $left, $pos, 4, 4)
        $left += 160
    Next
    $left = 16  
    $pos +=10
Next
 

[Xtroyer]

Euh, vu l'organisation de mon INI je ne pense pas utiliser ce code Mikell

INI :
[Nombre de compte]
NoDC=3
[Comptes]
NDC0=
MDP0=
Serveur0=
lvl0=
Interet0=MOY
NDC1=Essai
MDP1=test
Serveur1=osef
lvl1=60
Interet1=MOY

Code qui ne fonctionne toujours pas :

► Afficher le texte

Code : Tout sélectionner

Case $Button1
            GUISetState(@SW_SHOW, $GUI_AFF)
            $pos = 0
        If FileExists(@DocumentsCommonDir & "\Comptes.ini") = 0 Then
        $nombre = IniRead(@DocumentsCommonDir & "\Comptes.ini", "Nombre de compte", "NoDC", 0)
        Dim $info[$nombre]
        For $i = 0 To $nombre - 1 Step 1
        If $i = 0 Then
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "NDC" & $i, 0), 16, 104)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "MDP" & $i, 0), 176, 104)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Serveur" & $i, 0), 336, 104)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "lvl" & $i, 0), 432, 104)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Interet" & $i, 0), 528, 104)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            GUICtrlCreateGroup("", -99, -99, 1, 1)
        Else
            For $j To 4 step 1
            $pos += 10
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "NDC" & $i, 0), 16, 104 + $pos)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "MDP" & $i, 0), 176, 104 + $pos)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Serveur" & $i, 0), 336, 104 + $pos)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "lvl" & $i, 0), 432, 104 + $pos)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $info[$i] = GUICtrlCreateLabel(IniRead(@DocumentsCommonDir & "\Comptes.ini", "Comptes", "Interet" & $i, 0), 528, 104 + $pos)
            GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            GUICtrlCreateGroup("", -99, -99, 1, 1)
        EndIf
        Next
        EndIf
EndSwitch

Dites moi, comment on sait dans quel GUI va être créer le label ?

[mikell]

Regarde GUISwitch() dans l'aide

[Xtroyer]

Raaa ça ne fonctionne pas ><

[mikell]

Euh, vu l'organisation de mon INI je ne pense pas utiliser ce code Mikell

Tu l'as testé au moins ?

[Xtroyer]

Je viens d'essayer et aucun label n'est visible

[mikell]

Ecoute, tu vas tester le script qui est là-dessous (sans rien y changer) en mettant le ini "Comptes.ini" tel que tu l'as écrit dans le même dossier

► Afficher le texte

Code : Tout sélectionner

GuiCreate("", 800, 300)
GuiSetState()

$ini = @scriptDir & "\Comptes.ini"
$nb = IniRead($ini, "Nombre de compte", "NoDC", "0")

Dim $Label[$nb][5]
Dim $identifiants[5] = ["NDC", "MDP", "Serveur", "lvl", "Interet"]
$left = 16
$pos = 104

GUICtrlCreateGroup("", 5, 90, 750, 100)
For $i = 0 To $nb-1
    For $j = 0 To 4
        $item = IniRead($ini, "Comptes", $identifiants[$j] & $i, "0")
        $Label[$i][$j] = GUICtrlCreateLabel($item, $left, $pos, 60, 20)
        GUICtrlSetBkColor(-1, 0xffffff)
        GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
        $left += 160
    Next
    $left = 16 
    $pos +=30
Next
GUICtrlCreateGroup("", -99, -99, 1, 1)

While GuiGetMsg()<>-3
Sleep(10)
Wend

et tu vas voir que ça marche

[Xtroyer]

Bon en fait c'est réglé, je ne sais pas trop d'où venais le problème mais bon x)

Par contre, j'aimerais savoir comment faire un ascenseur verticale car dès qu'il y a trop de label, cela dépasse de la page et on ne les voit plus, je crois me souvenir qu'il faut utiliser les groupbox mais je ne me rappelle plus de quelle manière

[mikell]

Tu devrais mettre ce sujet en "résolu" et ouvrir un nouveau sujet

[Xtroyer]

Me revoici =)

Voilà, le code fonctionne bien, mais j'aimerais savoir, quelque chose. En effet, lorsqu'on clic sur un bouton, cela crée les label et affiche la GUI, mais dès qu'on clic une deuxième fois, ça les recréer par dessus donnant l'impression qu'il se chevauche et j'aimerai éviter ça.
Je pensais créer la liste directement lors de la création de la GUI, utiliser GuiControlDelete et recréer par dessus mais ça ne semble pas fonctionner

[mikell]

Rhaa la la tu cogites pas assez
Si j'ai bien compris, tu veux afficher tes labels à l'ouverture de la gui, et pouvoir ensuite rajouter une rangée de labels avec un bouton
Utilise les variables qui existent déjà !
Voilà un exemple (à toi de l'adapter) fait pour le ini de ton post précédent, essaye d'appuyer plusieurs fois sur le bouton :

► Afficher le texte

Code : Tout sélectionner

GuiCreate("", 800, 300)
$button = GuiCtrlCreateButton("Update", 50, 30, 70, 30)
GuiSetState()

$ini = @scriptDir & "\Comptes.ini"
$nb = IniRead($ini, "Nombre de compte", "NoDC", "0")

Dim $Label[$nb][5]
Dim $identifiants[5] = ["NDC", "MDP", "Serveur", "lvl", "Interet"]
$left = 16
$pos = 104

$group = GUICtrlCreateGroup("", 5, 90, 750, 105)
For $i = 0 To $nb-1
    For $j = 0 To 4
        $item = IniRead($ini, "Comptes", $identifiants[$j] & $i, "0")
        $Label[$i][$j] = GUICtrlCreateLabel($item, [color=#FF0000]$left[/color], [color=#FF0000]$pos[/color], 60, 20)
        GUICtrlSetBkColor(-1, 0xffffff)
        GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
        $left += 160
    Next
    [color=#FF0000]$left[/color] = 16
    [color=#FF0000]$pos[/color] +=30
Next
GUICtrlCreateGroup("", -99, -99, 1, 1)

While 1
$msg = GuiGetMsg()
If $msg = -3 Then Exit
If $msg = $button Then _Update()
Sleep(10)
Wend

Func _Update()
    Msgbox(0,"", "coordonnées de la prochaine rangée :  " & [color=#FF0000]$left[/color] & " , " & [color=#FF0000]$pos[/color])
    For $i = 0 To 4
        $item = "new " & $nb+1
        GUICtrlCreateLabel($item, [color=#FF0000]$left[/color], [color=#FF0000]$pos[/color], 60, 20)
        GUICtrlSetBkColor(-1, 0xffffff)
        GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
        $left += 160
    Next
    $left = 16
    $pos +=30
    GuiCtrlSetPos($group, 5, 90, 750, [color=#FF0000]$pos[/color]-90)
    $nb += 1
EndFunc
 

Tu remarqueras que la création des labels et leur mise à jour ont quelques points communs... pourquoi ne pas en faire en une fonction ?

► Afficher le texte

Code : Tout sélectionner

GuiCreate("", 800, 300)
$button = GuiCtrlCreateButton("Update", 50, 30, 70, 30)
GuiSetState()

$ini = @scriptDir & "\Comptes.ini"
$nb = IniRead($ini, "Nombre de compte", "NoDC", "0")

Dim $Label[$nb][5]
Dim $identifiants[5] = ["NDC", "MDP", "Serveur", "lvl", "Interet"]
$left = 16
$pos = 104

$group = GUICtrlCreateGroup("", 5, 90)
For $i = 0 To $nb-1
    _CreateLabels($i)
Next

While 1
    $msg = GuiGetMsg()
    If $msg = -3 Then Exit
    If $msg = $button Then _Update()
    Sleep(10)
Wend

;-------------------------------------------------------------

Func _Update()
    _CreateLabels($nb+1)
    $nb += 1
EndFunc

Func _CreateLabels($numerodecompte)
    For $i = 0 To 4
         $item = IniRead($ini, "Comptes", $identifiants[$i] & $numerodecompte, "0")
        GUICtrlCreateLabel($item, $left, $pos, 60, 20)
        GUICtrlSetBkColor(-1, 0xffffff)
        GUICtrlSetFont(-1, 12, 400, 0, "Lucida Calligraphy")
            $left += 160
    Next
    $left = 16
    $pos +=30
    GuiCtrlSetPos($group, 5, 90, 750, $pos-90)
EndFunc