[R] Lire l'état d'un TrayTip

[keltharak]

Bonjour,

Est-il possible de lire l'état d'un TrayTip ? Je veux dire par la, est-on capable de checker le Traytip pour savoir s'il est toujours visible pour l'utilisateur ? (sachant qu'il peut se fermer soit par le Timeout, soit par l'action de l'utilisateur...)

Merci d'avance

[ZDS]

Bonjour,

Ce n'est pas forcément facile de détecter l'état d'un traytip, mais en faisant une petite recherche sur le forum anglophone d'AutoIt, tu tombes sur un exemple de script qui permet de détecter un clic sur un traytip, mais aussi de détecter si le traytip se ferme (user ou timeout). ^^

Je te file le lien au cas où, et le script en spoiler :

► Afficher le texteScript provenant de Rover

http://www.autoitscript.com/forum/topic/97757-solved-detect-click-on-traytip/page__p__703181#entry703181

Code : Tout sélectionner

;Author: rover 07/04/09
;MSDN reference:
;Shell_NotifyIcon Function
;http://msdn.microsoft.com/en-us/library/bb762159(VS.85).aspx
  #include <GUIConstantsEX.au3>
  #include <Constants.au3>
  #include <WindowsConstants.au3>
  #include <WinAPI.au3>
  #include <StaticConstants.au3>
  
  Global Const $NIN_BALLOONTIMEOUT = $WM_USER + 4
  Global Const $NIN_BALLOONUSERCLICK = $WM_USER + 5
;Global Const $GWLP_WNDPROC = -4; for SetWindowLongPtr
  
  Global $wProcNew = 0, $wProcOld = 0, $iMsg, $iError = 0
  
;get handle to AutoIt v3 hidden gui
  Global $hGUI1 = _AutoItWinGetHandle()
;$hGUI1 = WinGetHandle(AutoItWinGetTitle())
  
;will work without GUICreate but global vars must be set in WndProc instead of GUICtrlCreateDummy/GUICtrlSendToDummy
  
;NOTE: _WinAPI_SetWindowLong() in WinAPI.au3 consistently returns 'The specified procedure could not be found' error 127
;error is due to the call being SetWindowLong instead of SetWindowLongW,
;using SetWindowLongW the error message is 'The operation completed successfully.
  
  Global $hGUI2 = GUICreate("Traytip click detect", 260, 150, @DesktopWidth - 400, @DesktopHeight - 300)
  Global $cTooltipClose = GUICtrlCreateDummy()
  Global $cTooltipClick = GUICtrlCreateDummy()
  Global $cLabel1 = GUICtrlCreateLabel("Traytip area clicked", 70, 80, 120, 16, $SS_CENTER)
  Global $cLabel2 = GUICtrlCreateLabel("", 10, 110, 240, 16, $SS_CENTER)
  GUICtrlSetBkColor(-1, 0xFFFFFF)
  Global $cButton = GUICtrlCreateButton("Create Traytip", 70, 30, 120, 25)
  GUISetState()
  
  
;subclass AutoIt v3 gui to get tray icon/traytip notifications
  _SubclassWin($hGUI1, $wProcNew, $wProcOld)
  Global $sLastError = _WinAPI_GetLastErrorMessage()
  ConsoleWrite('- GetLastErrorMessage ' & $sLastError & "- Error: " & _WinAPI_GetLastError() & @CRLF)
  ConsoleWrite('+$wProcOld = ' & $wProcOld & @CRLF)
  GUICtrlSetData($cLabel2, $sLastError)
  
  If StringInStr($sLastError, "Access is denied.") <> 0 Then
      GUICtrlSetBkColor($cLabel2, 0xFF0000)
  EndIf
  
  While 1
      $iMsg = GUIGetMsg()
      Switch $iMsg
          Case $cButton
              TrayTip("Clear", "", 1)
              TrayTip("I'm a title", "I'm the message", 5, 1)
          Case $cTooltipClick
              GUICtrlSetData($cLabel2, "")
              GUICtrlSetColor($cLabel2, 0x0000FF)
              Sleep(100)
              GUICtrlSetData($cLabel2, "Tooltip clicked")
              ConsoleWrite("!NIN_BALLOONUSERCLICK" & @CRLF)
          Case $cTooltipClose
              GUICtrlSetData($cLabel2, "")
              GUICtrlSetColor($cLabel2, 0xFF0000)
              Sleep(100)
              GUICtrlSetData($cLabel2, "Tooltip closed")
              ConsoleWrite("-NIN_BALLOONTIMEOUT" & @CRLF)
          Case $GUI_EVENT_CLOSE
              Exit
      EndSwitch
  WEnd
  
  Func _SubclassWin($hWnd, ByRef $hProcNew, ByRef $hProcOld)
      If $hProcNew <> 0 Or $hProcOld <> 0 Then Return SetError(1, 0, 0)
      $hProcNew = DllCallbackRegister("_AutoItWndProc", "int", "hwnd;uint;wparam;lparam")
      If @error Or $hProcNew = 0 Then Return SetError(2, 0, 0)
      $hProcOld = DllCall("User32.dll", "int", "SetWindowLongW", "hwnd", _
              $hWnd, "int", $GWL_WNDPROC, "ptr", DllCallbackGetPtr($hProcNew))
      If @error Or $hProcOld[0] = 0 Then
          $hProcOld = 0
          Return SetError(3, 0, 0)
      EndIf
      $hProcOld = $hProcOld[0]
      Return SetError(0, 0, 1)
  EndFunc;==>_SubclassWin
  
  Func _RestoreWndProc($hWnd, ByRef $hProcNew, ByRef $hProcOld)
      If $hProcOld <> 0 Then _WinAPI_SetWindowLong($hWnd, $GWL_WNDPROC, $hProcOld)
      If $hProcNew <> 0 Then DllCallbackFree($hProcNew)
      $hProcNew = 0
      $hProcOld = 0
  EndFunc;==>_RestoreWndProc
  
  Func OnAutoItExit()
      _RestoreWndProc($hGUI1, $wProcNew, $wProcOld)
  EndFunc;==>OnAutoItExit
  
  Func _AutoItWndProc($hWnd, $iMsg, $iwParam, $ilParam)
      #forceref $hWnd, $iMsg, $iwParam, $ilParam
      Switch $iMsg
          Case $WM_USER + 1;AutoIt callback message value for tray icon (1025), can be retrieved with ReadProcessMemory and TRAYDATA struct
              Switch $ilParam
                  Case $NIN_BALLOONTIMEOUT; timeout and by tooltip close icon
                      GUICtrlSendToDummy($cTooltipClose)
                  Case $NIN_BALLOONUSERCLICK
                      GUICtrlSendToDummy($cTooltipClick)
              EndSwitch
      EndSwitch
   ; pass the unhandled messages to default WindowProc
      Return _WinAPI_CallWindowProc($wProcOld, $hWnd, $iMsg, $iwParam, $ilParam)
  EndFunc;==>_AutoItWndProc
  
;===============================================================================
;
; Function Name:   _AutoItWinGetHandle
; Description:: Returns the Windowhandle of AutoIT-Window
; Parameter(s): --
; Requirement(s):  --
; Return Value(s): Autoitwindow Handle
; Author(s):       Prog@ndy
;
;===============================================================================
;
  Func _AutoItWinGetHandle()
      Local $oldTitle = AutoItWinGetTitle()
      Local $x = Random(1248578, 1249780)
      AutoItWinSetTitle("qwrzu" & $x)
      Local $x = WinGetHandle("qwrzu" & $x)
      AutoItWinSetTitle($oldTitle)
      Return $x
  EndFunc;==>_AutoItWinGetHandle

Comme on dit chez eux, you're welcome

A bientôt !

PS: Sans certitude, l'UDF très complète "ModernMenu" de Holger permet de le faire assez facilement aussi. Mais tout ça n'est possible que si ton traytip provient de ton script (ou assimilé) il me semble.

[sylvanie]

le soucis avec le traytip, c'est que le winexist,wingethandle,etc ne fonctionne pas.

Je pensais à faire un gros truc bourrin (désolé pour l'expression, mais attendez la suite ...) qui consiste à lancer un winlist() avant et après l'appel au traytip pour faire un diff pour récupérer le handle.

C'est très infâme, et là je constate que le traytip apparaît chez moi systématiquement en deuxième position de l'énumération de winlist (la position 0 étant consacrée à la dimension du tableau)

du coups ce script de fiabilité "nitroglycérine" fonctionne chez moi :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>

opt("WinTitleMatchMode",4)

$array=WinList()
_ArrayDisplay($array)

TrayTip("Test","test_text",10)
$array=WinList()
_ArrayDisplay($array)


While WinExists(HWnd($array[2][1]))
    ConsoleWrite("tray vivant"&@CRLF)
    Sleep(500)
WEnd
 

Si ça le fait chez vous, tant mieux ... mais bon ...

[Tlem]

J'ai trouvé ceci :

► Afficher le texte

Code : Tout sélectionner

TrayTip("I'm a title", "I'm the message", 5, 1)
$hnd = WinGetHandle("[CLASS:tooltips_class32]", "")

Sleep(1000)
If WinExists($hnd) Then ConsoleWrite("Le toolTip avec le handle " & $hnd & " est vivant")

While WinExists($hnd)
    Sleep(500)
WEnd

MsgBox(4096,"", "Le ToolTip vient de se fermer")

mais étonnamment cela ne fonctionne pas !!!
Pourtant tout est bon, le handle et le WinExist, mais dans la boucle, ca ne fonctionne pas ...
Il doit me manquer un petit truc, mais là, je ne vois pas (je suis peut être un peu fatigué !!!).

[sylvanie]

J'avais utilisé ceci au début aussi, mais le handle indiqué (détecté aussi par au3info) n'est pas le vrai.
C'est là que je me suis rabattu sur le diff entre deux winlist(), et donc j'ai contaté que le handle retourné n'était pas celui qui gérait "pour de vrai" le tooltip.
pour faire plus propre que ce que j'ai proposé, il faudrait faire une fonction qui traîte les deux tableaux retournés par les winlist() de la manière suivante :
- On recréé 2 tableaux ne contenant que les handle
- On les trie
-On les parcours et on regarde à indice égale si ça diffère, alors le handle du 2eme tableau est (à 90%+des brouette) le handle cherché

Maintenant pourquoi le 90% ... et bien il se peut qu'entre les deux appels, des fenêtres de la session disparaissent ou se créent, et là pas de chance.

[Tlem]

Rhhooo, ben alors, si AutoIt nous fait des blagues, maintenant ...

[sylvanie]

A défaut de mieux voici ce que je proposais tout à l'heure en théorie :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>

opt("WinTitleMatchMode",4)

$array1=WinList()

TrayTip("Test","test_text",10)
$array2=WinList()


$handle=detect_hnd($array1,$array2)

While WinExists(HWnd($array2[2][1]))
    ConsoleWrite("tray vivant"&@CRLF)
    Sleep(500)
WEnd

Func detect_hnd($t1,$t2)
    Local $ind
    Local $indmin=min($t1[0][0],$t2[0][0])
    If $indmin=$t2[0][0] Then Return detect_hnd($t2,$t1)
    _ArraySort($t1,0,0,0,1)
    _ArraySort($t2,0,0,0,1)
    For $ind=1 To $indmin
        If $t1[$ind][1] <> $t2[$ind][1] Then Return $t2[$ind][1]
    Next
    ;;le handle n'est pas encore trouvé, on retourne alors le prochain elt de t2
    If $t2[0][0] > $indmin Then Return $t2[$indmin+1][1]
    ;;bon la on est dans la panade car on est dans un cas ou les 2 tableaux sont identiques
    Return $t2[$indmin][1]
EndFunc

Func min($a,$b)
    If $a<$b Then Return $a
    Return $b
EndFunc
 

@Tlem : Et bien là je pense que le handle retouné est celui d'une fenêtre englobante, ce qui fausse le résultat ...

[EDIT]
inserrez les lignes suivantes après l'appel à la fonction de tri :
ConsoleWrite($handle&@CRLF)
ConsoleWrite(WinGetHandle("[CLASS:tooltips_class32]", "")&@CRLF)

vous verrez bien que les handles ne sont pas les mêmes

[Tlem]

J'ai trouvé des petites choses intéressantes ici :
- http://www.autoitscript.com/forum/topic ... _p__703181
- http://www.autoitscript.com/forum/topic ... __p__64671

Le dernier code, créé par valik est surprenant, mais il fonctionne parfaitement ...

[sylvanie]

Ah oui, il est nickel

[keltharak]

Merci beaucoup pour vos réponses et vos solutions.

Je suis arrivé exactement au résultat que je recherchais grâce à la 2° solution de Tlem,

► Afficher le texte

Code : Tout sélectionner

Opt("WinTitleMatchMode", 4)

Global Const $GWL_STYLE_ = -16
Global Const $TTS_BALLOON = 0x40

Func _GetWindowLong($hWnd, $index)
    Local $ret = DllCall("user32.dll", "long", "GetWindowLong", "hwnd", $hWnd, "int", $index )
    If @error Then
        SetError(@error)
        Return 0
    EndIf
    Return $ret[0]
EndFunc; _GetWindowLong()

TrayTip(@ScriptName, "Mon message...", 20)

Local $hWnd = 0
Local $a = WinList("classname=tooltips_class32")
For $i = 1 To UBound($a)-1
    Local $style = _GetWindowLong($a[$i][1], $GWL_STYLE_)
    If BitAND($style, $TTS_BALLOON) Then 
        $hWnd = $a[$i][1]
        ExitLoop
    EndIf
Next
If $hWnd <> 0 Then
    While BitAND(WinGetState($hWnd), 2)
        Sleep(200)
    WEnd
Else
    Sleep(20000)
EndIf

Exit

Ca marche impeccable merci encore.

[sylvanie]

L'implémentation de Rover est plus délicate au début à cerner, mais elle est plus adaptée à des situations du type :
- si j'ai un timeout du ballon alors je peux faire X
- Si l'utilisateur ferme avec la croix je peux faire Y
Du coups ça réponds aussi au problème, mais c'est limite "tops riche"

Il faut la garder en mémoire pour le jour où le cas se posera

PS : Il y a un post de ZDS qui c'est perdu dans les réponses ou j'ai révé ?

[keltharak]

Effectivement, ça permet plus de flexibilité.

Pour le post de ZDS, ce matin en lisant vos réponse je n'en avais qu'une...