[R] Intégrer a programme exe dans une Gui resizable .

[pierrotm777]

Bonjour,

je cherche à intégrer le programme 'spotify.exe' http://www.spotify.com/download/Spotify%20Installer.exe dans une fenêtre dans on pourrait modifier la taille, spotify s'ajustant alors aussi.

Je cherche aussi à envoyer des commandes 'send' mais là aussi quelle galère

J'ai trouvé quelque lignes de code que j'ai adapté mais je bloque sur le fait que je voudrais que spotify ne puisse pas
être déplacé, hors-mis lors de l'ajustement de la fenêtre principale.

voici le code:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Constants.au3>

$hGUI2 = GUICreate('SpotifyEmbed', 800, 650, 0, 0, BitOr($GUI_SS_DEFAULT_GUI,$WS_CLIPCHILDREN))

$Test = GUICtrlCreateButton("Si Active",100,550,80,40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$CTRLD = GUICtrlCreateButton("Control D", 380, 550, 80, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$CTRLP = GUICtrlCreateButton("Préférences", 480, 550, 100, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$HELP = GUICtrlCreateButton("Aide", 600, 550, 80, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$Annuler = GUICtrlCreateButton("Quitter", 700, 550, 80, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

If Not ProcessExists("spotify.exe") Then
$pID = Run(@ProgramFilesDir&"\Spotify\spotify.exe")
WinWait("[Class:SpotifyMainWindow]")
EndIf

$hChild = WinGetHandle("Spotify")

_WinAPI_SetParent($hChild, $hGUI2)
_WinAPI_SetWindowLong($hChild, $GWL_STYLE, BitOR($WS_CLIPSIBLINGS, $WS_VISIBLE))
_WinAPI_SetWindowLong($hChild, $GWL_HWNDPARENT, $hGUI2)
WinMove($hChild, "", 0, 0)
GUICtrlSetResizing(-1,$GUI_DOCKALL)
GUiSetState(@SW_SHOW, $hGUI2)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ProcessClose($pID)
            Exit

        Case $Annuler
            ProcessClose($pID)
            Exit

        Case $HELP
            WinActivate("Spotify","")
            Opt("SendKeyDownDelay", 50)
            send("{F1}")

        Case $CTRLP
            WinActivate("Spotify","")
            Opt("SendKeyDownDelay", 50)
            Send("^{p}")

        Case $Test
            If WinActive("Spotify") Then
            MsgBox(0, "", "Window was active")
            Else
            MsgBox(0, "", "Window was not active")
        EndIf


    EndSwitch
WEnd

Nota: le bouton $Test sert à tester si la fenêtre spotify est bien active et l'on constate bien que oui .

Avec le bouton 'Aide', je voudrais envoyer la touche F1.
Avec le bouton 'Préférences', je voudrais envoyer les touches 'contrôle + p'.

Merci de votre aide

[pierrotm777]

Bonjour,

j'ai précisé dans le post #1 mon besoin.

En gros , je pense que je n'active pas la bonne fenêtre.

La 'classname' de spotify = SpotifyMainWindow

La 'caption' de spotify = Spotify

Merci de votre aide.

[SagePourpre]

Tu utilises :

Code : Tout sélectionner

WinActivate("Spotify","")

mais tu as déjà le handle de la fenêtre de spotify
stocké dans $hchild.

En utilisant directement WinActivate($hchild)

que de faire un WinActivate('spotify') imprécis, utilise
$hchild que tu as déjà défini plus tôt

Code : Tout sélectionner

WinActivate($hchild)

devrait fonctionner...

[pierrotm777]

Je suis un petit imbécile !

Merci beaucoup !

Voici le résultat si cela intéresse quelqu'un !

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <Constants.au3>

$hGUI2 = GUICreate('SpotifyEmbed', 800, 650, 0, 0, BitOr($GUI_SS_DEFAULT_GUI,$WS_CLIPCHILDREN))

$MUTE = GUICtrlCreateButton("X",110,550,60,40)
GUICtrlSetFont(-1, 30, 800, 0, "Webdings")

$PREV = GUICtrlCreateButton("3",180,550,60,40)
GUICtrlSetFont(-1, 30, 800, 0, "Webdings")

$PLAYPAUSE = GUICtrlCreateButton(";4",250,550,90,40)
GUICtrlSetFont(-1, 30, 800, 0, "Webdings")

$NEXT = GUICtrlCreateButton("4",350,550,60,40)
GUICtrlSetFont(-1, 30, 800, 0, "Webdings")

$CTRLDOWN = GUICtrlCreateButton("Vol -", 420, 550, 60, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$CTRLUP = GUICtrlCreateButton("Vol +", 490, 550, 60, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$CTRLP = GUICtrlCreateButton("Préf", 560, 550, 60, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$HELP = GUICtrlCreateButton("Aide", 630, 550, 60, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

$Annuler = GUICtrlCreateButton("Quitter", 700, 550, 60, 40)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

If ProcessExists("spotify.exe") Then ProcessClose("spotify.exe")
sleep(1000)
If Not ProcessExists("spotify.exe") Then
$pID = Run(@ProgramFilesDir&"\Spotify\spotify.exe")
WinWait("[Class:SpotifyMainWindow]")
EndIf

$hChild = WinGetHandle("Spotify")

_WinAPI_SetParent($hChild, $hGUI2)
_WinAPI_SetWindowLong($hChild, $GWL_STYLE, BitOR($WS_CLIPSIBLINGS, $WS_VISIBLE))
_WinAPI_SetWindowLong($hChild, $GWL_HWNDPARENT, $hGUI2)
WinMove($hChild, "", 0, 0)
GUICtrlSetResizing(-1,$GUI_DOCKALL)
GUiSetState(@SW_SHOW, $hGUI2)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ProcessClose($pID)
            Exit

        Case $Annuler
            ProcessClose($pID)
            Exit

        Case $HELP
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            send("{F1}")

        Case $CTRLP
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^{p}")

        Case $CTRLUP
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^{UP}")

        Case $CTRLDOWN
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^{DOWN}")

        Case $PREV
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^{LEFT}")

        Case $PLAYPAUSE
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("{SPACE}")

        Case $NEXT
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^{RIGHT}")

        Case $MUTE
            WinActivate($hChild,"")
            Opt("SendKeyDownDelay", 50)
            Send("^+{DOWN}")

    EndSwitch
WEnd