[R] GUICtrlCreateInput et GUICtrlRead

[SteveL]

Bonjour à tous,

je me lance dans un petit projet pour le boulot afin de faciliter des créations de comptes qui sont quelque peu rébarbatives...

J'ai commencé un GUI avec les principaux éléments dont j'ai besoin mais je resté bloqué...

En effet, j'ai créé deux champs afin d'y entrer des informations qui seront ré-affichées dans un troisième champs (Tous des GUICtrlCreateInput). Le but étant le suivant: Lorsque l'on rentre un prénom et un nom dans les deux premiers champs (GUICtrlCreateInput), s'affiche alors dans le troisième champ (GUICtrlCreateInput) la chose suivante: Prénom entier + Première lettre du Nom collée puis @PatatiPatata.fr. Voici un exemple:

Prénom: Steve
Nom: Lolo

Nom de session utilisateur: SteveL@PatatiPatata.fr

Je tiens à préciser que c'est pour des créations de comptes Active Directory.

Je reste bloqué car je n'arrive pas à faire afficher dans le troisième champ la combinaison de prénom et première lettre du nom...

Pouvez vous m'aider ?

Voici le code de ma GUI:

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <adfunctions.au3>
#include <array.au3>

; GUI
GuiCreate("AD InfoInterne", 800, 400)
GUISetIcon("C:\Documents and Settings\SteveL\Bureau\AD\Logos\favicon.ico")
GUISetBkColor(0xFFFFFF)

; PIC
GuiCtrlCreatePic("C:\Documents and Settings\SteveL\Bureau\AD\Logos\Logo_bckgrnd.bmp",0,0,800,117)



Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $tab, $tab0, $Prenominput, $Nominput, $Sessioninput, $resultprenom, $resultnom
    Local $tab1
    Local $tab2, $msg

    GuiCtrlSetColor(-1,0xffffff)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(0, 120, 800, 600)

    ; +++++ ONGLET CREATION +++++
    $tab0 = GUICtrlCreateTabItem("Création")
    GUICtrlSetState(-1, $GUI_SHOW)

    GUICtrlCreateLabel("Prénom", 30, 180, 115, 20)
    $Prenominput = GUICtrlCreateInput("", 90, 178, 120, 20)
    $resultprenom = GUICtrlRead ($Prenominput)

    GUICtrlCreateLabel("Nom", 30, 230, 115, 20)
    $Nominput = GUICtrlCreateInput("", 90, 228, 120, 20)
    $resultnom = GUICtrlRead ($Nominput)

    GUICtrlCreateLabel("Nom d'ouverture de session utilisateur", 30, 278, 300, 20)
    $Sessioninput = GUICtrlCreateInput (GUIctrlread ($resultprenom) & GUIctrlread ($resultnom) & "@PatatiPatata.fr", 270, 276, 300, 20)



    GUISetState()


    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc
 

Ce projet me tiens réellement à cœur mais je ne connais pas encore toutes les subtilités de AutoIT... mais je m'entête !

Merci à vous.

Cordialement

[sylvanie]

Bonjour, voici un petit exemple qui necessite tout de même de recliquer dans un des deux contrôles pour mettre à jour le mail. On peut m'améliorer avec un "adlibenable" charger de gueter les changement de texte toutes les secondes par exple.

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$prenom_entre=""
$nom_entre=""
$mail_suffix="@toto.com"


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 456, 323, 192, 124)
$prenom = GUICtrlCreateInput("", 56, 56, 225, 21)
$nom = GUICtrlCreateInput("", 56, 112, 225, 21)
$mail = GUICtrlCreateInput("", 56, 176, 225, 21,$ES_READONLY)
$Labelnom = GUICtrlCreateLabel("Nom", 56, 88, 26, 17)
$Labelprenom = GUICtrlCreateLabel("prenom", 56, 32, 39, 17)
$labelmail = GUICtrlCreateLabel("mail", 56, 152, 22, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $prenom
            update_mail()
        Case $nom
            update_mail()
    EndSwitch
WEnd


Func update_mail()
    Local $nom_courrant,$prenom_courrant

    $nom_courrant = GUICtrlRead($nom)
    $prenom_courrant = GUICtrlRead($prenom)

    If ( ($nom_courrant <> $nom_entre) Or($prenom_courrant <> $prenom_entre) ) Then
        $prenom_entre = $prenom_courrant
        $nom_entre = $nom_courrant
        If ( ( $nom_entre<>"" ) And ( $prenom_entre<>"" ) ) Then
            GUICtrlSetData($mail,StringLeft($prenom_entre,1)&$nom_entre&$mail_suffix)
        EndIf
    EndIf

EndFunc

 

[EDIT] : tout simplement mettre AdlibEnable("update_mail",500) avant le while ...

[jbnh]

Merci aussi de prendre quelques secondes pour lire les règles de présentation d'un message et d'éditer votre titre.

[SteveL]

Merci beaucoup pour votre aide!

Ca marche, je vais donc continuer mon soft!

J'ai réédité le titre du post. J'espère que cela convient!

Merci!

[SteveL]

J'ai encore un soucis mais cette fois-ci, c'est en voulant mettre des onglets...

Je veux que cela apparaisse dans mon onglet "Création". Il me marque une erreur à propos de la fonction update_mail comme quoi elle n'est pas déclarée mais j'avoue que j'ai beau chercher, je ne vois pas d'où vient le problème...

Pouvez vous m'aider s'il vous plait et me dire d'où vient mon erreur ?

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("AD Manager InfoInterne", 800, 700)

Opt('MustDeclareVars', 1)

general()

Func general()
    Local $onglets, $creation, $prenom_entre, $nom_entre, $mail_suffix, $prenom, $nom, $mail, $Labelnom, $Labelprenom, $labelmail, $msg, $nMsg
    Local $modification
    Local $suppression

    $onglets = GUICtrlCreateTab(10, 10, 800, 700)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;CREATION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$creation = GUICtrlCreateTabItem("Création")
GUICtrlSetState(-1, $GUI_SHOW)

$prenom_entre=""
$nom_entre=""
$mail_suffix="@Groupe-Altitude.fr"

$prenom = GUICtrlCreateInput("", 56, 56, 225, 21)
$nom = GUICtrlCreateInput("", 56, 112, 225, 21)
$mail = GUICtrlCreateInput("", 56, 176, 225, 21)
$Labelnom = GUICtrlCreateLabel("Nom", 56, 88, 26, 17)
$Labelprenom = GUICtrlCreateLabel("Prénom", 56, 32, 39, 17)
$labelmail = GUICtrlCreateLabel("Nom d'ouverture de session utilisateur:", 56, 152, 2150, 17)
GUISetState(@SW_SHOW)

AdlibEnable("update_mail",500)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $prenom
            update_mail()
        Case $nom
            update_mail()
    EndSwitch
WEnd

Func update_mail()
    Local $nom_courrant, $prenom_courrant

    $nom_courrant = GUICtrlRead($nom)
    $prenom_courrant = GUICtrlRead($prenom)

    If ( ($nom_courrant <> $nom_entre) Or($prenom_courrant <> $prenom_entre) ) Then
        $prenom_entre = $prenom_courrant
        $nom_entre = $nom_courrant
        If ( ( $nom_entre<>"" ) And ( $prenom_entre<>"" ) ) Then
        GUICtrlSetData($mail,$prenom_entre&StringLeft($nom_entre,1) &$mail_suffix)
        EndIf
    EndIf
EndFunc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;MODIFICATION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $modification = GUICtrlCreateTabItem("Modification")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;SUPPRESSION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $suppression = GUICtrlCreateTabItem("Suppression")



GUICtrlCreateTabItem("")    ; end tabitem definition

GUISetState()

    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc



 

[sylvanie]

Ou là,
un gros gloubi boulga

1) Func ne peut pas inclure une autre déclaration func dans son corps, ce qui est le cas ici. Chaque fonction doit être déclarée les unes en desous des autres

2) ceci nous amène au pb de portée de variable : En effet des variables de contrôles comme$nom,$mail ... sont partagées par les deux fonctions, et donc si on les déclare locales à l'une, elles sont inconnues pour l'autre. Il y a donc 2 solutions :
a) moins belle mais rapide (ce que j'ai fait), mettre les variables communes à portée globale
b) laisser la déclaration locale à l'une, et les passer par paramètre à la deuxième fonction en réécrivant son prototype, comme par exemple :

Code : Tout sélectionner

Func update_mail($id_nom,$id_prenom)

. Cette méthode est préférable pour du long terme.

3) pareil dans le cas des traitement des messages (edit, tab, etc.), il faut une unique boucle while, sinon on ne s'en sort plus.

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("AD Manager InfoInterne", 800, 700)

Opt('MustDeclareVars', 1)
Dim $prenom="",$nom="",$nom_entre="",$prenom_entre="",$mail="",$mail_suffix="@Groupe-Altitude.fr"

general()

Func update_mail()
    Local $nom_courrant, $prenom_courrant

    $nom_courrant = GUICtrlRead($nom)
    $prenom_courrant = GUICtrlRead($prenom)
    If ( ($nom_courrant <> $nom_entre) Or($prenom_courrant <> $prenom_entre) ) Then
        $prenom_entre = $prenom_courrant
        $nom_entre = $nom_courrant
        If ( ( $nom_entre<>"" ) And ( $prenom_entre<>"" ) ) Then
        GUICtrlSetData($mail,$prenom_entre&StringLeft($nom_entre,1) &$mail_suffix)
        EndIf
    EndIf
EndFunc


Func general()
    Local $onglets, $creation, $prenom_entre, $nom_entre, $mail_suffix, $Labelnom, $Labelprenom, $labelmail, $msg, $nMsg
    Local $modification
    Local $suppression

    $onglets = GUICtrlCreateTab(10, 10, 800, 700)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;CREATION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$creation = GUICtrlCreateTabItem("Création")
GUICtrlSetState(-1, $GUI_SHOW)
#cs
$prenom_entre=""
$nom_entre=""
$mail_suffix="@Groupe-Altitude.fr"
#ce

$prenom = GUICtrlCreateInput("", 56, 56, 225, 21)
$nom = GUICtrlCreateInput("", 56, 112, 225, 21)
$mail = GUICtrlCreateInput("", 56, 176, 225, 21)
$Labelnom = GUICtrlCreateLabel("Nom", 56, 88, 26, 17)
$Labelprenom = GUICtrlCreateLabel("Prénom", 56, 32, 39, 17)
$labelmail = GUICtrlCreateLabel("Nom d'ouverture de session utilisateur:", 56, 152, 2150, 17)


AdlibEnable("update_mail",500)



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;MODIFICATION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $modification = GUICtrlCreateTabItem("Modification")

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;SUPPRESSION;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    $suppression = GUICtrlCreateTabItem("Suppression")



GUICtrlCreateTabItem("")    ; end tabitem definition

GUISetState()

    While 1
        $msg = GUIGetMsg()

        Switch $msg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $prenom
                update_mail()
            Case $nom
                update_mail()
        EndSwitch
    WEnd
EndFunc
 

[SteveL]

Bonjour !

Merci beaucoup de m'expliquer toutes ces raisons pour les Func etc. C'est vraiment comme ça que j'arrive à comprendre.

C'est vrai que cela fait moins "gloubi boulga"

Je vais continuer de bosser sur mon projet, mais je vais clôturer le post pendant ce temps là.

Merci beaucoup pour ton intervention cela m'aide vraiment pour la logique de AutoIT.

Bonne journée à vous tous et merci pour votre soutien

SteveL