[..] Lister les labels des supports amovibles

[corrs78]

Je souhaite lister les labels des clés ou disques amovibles connectés, exemple:
LEXAR128, AMOVIBLE200, DISQUE_EXT...
Le but est de pouvoir lancer un programme sur un chemin(lettre de lecteur) variable.
Seule problème je n'arrive pas à lister les labels.

Code : Tout sélectionner

#include <GUIConstants.au3>

;$variable
Global $lecteur
Global $label


list_lecteur()
ConsoleWrite("var=" & $lecteur & @CRLF)
ConsoleWrite("var=" & $label & @CRLF)


; - - - - - - - - - - Liste des lecteurs
Func list_lecteur()
$var = DriveGetDrive( "REMOVABLE" );"ALL", "CDROM", "REMOVABLE", "FIXED", "NETWORK", "RAMDISK", or "UNKNOWN"
    If NOT @error Then
        For $i = 1 to $var[0]
            $lecteur = $var[$i] &"\" &$lecteur

        Next
    Else
        $label_cle = GUICtrlCreateLabel("PAS DE CLE USB DETECTEE",130,145)
    EndIf
    
    $variable = DriveGetLabel( $lecteur )
    
     For $i = 1 to $variable[0]
            $label = $variable[$i] &"\" &$label

        Next
EndFunc


exit

Merci de votre aide.

[Yogui]

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <ProgressConstants.au3>
#include <GUIConstants.au3>

$var = DriveGetDrive( "all" )



If NOT @error Then

    For $i = 1 to $var[0]
                        $label = DriveGetLabel( $var[$i] )
                        $type = DriveGetType( $var[$i] )
                        $taille = DriveSpaceTotal( $var[$i] )
                        $stat = DriveStatus( $var[$i] )
                        $sys = DriveGetFileSystem( $var[$i] )
                        

                        if $type = "Removable" Then
                                   if $stat = "READY" Then

MsgBox(4096,"Drive " & $i,$var[$i] &" est un "& $type &"  son nom est "& $label &" sa taille est de "& $taille& " son statut est : "&$stat &" le systeme de fichier est : "& $sys)
                                               $stockage = $var[$i]
                                               $nom = $label
                                               $sortie = "1"

                                   EndIf
                               EndIf
                           Next
                           EndIf

a tester avec une clefs usb

[Tlem]

http://www.autoitscript.fr/forum/viewto ... ?f=3&t=595
merci

En gardant le mode Fonction, voici un code un peut plus complet :

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <array.au3>

$List = list_lecteur()
If Not @error Then
    MsgBox(64,"Info", "Il y a " & $List[0] & " lecteur(s) amovible(s)")
    _ArrayDisplay($List, "Label lecteur(s)")
Else
    MsgBox(16,"Erreur", "Pas de lecteur(s) amovible(s) présent(s).")
EndIf

; - - - - - - - - - - Liste des lecteurs
Func list_lecteur()
    Local $lecteur
    $var = DriveGetDrive("REMOVABLE") ;"ALL"
    If NOT @error Then
        For $i = 1 to $var[0]
            If DriveStatus ($var[$i] & "\") = "READY" Then
            $lecteur &= DriveGetLabel($var[$i] & "\") & "|"
            EndIf
        Next
    Else
        $lecteur = ""
    EndIf
    
    If Not $lecteur = "" Then
        $aLecteur = StringSplit(StringTrimRight($lecteur, 1), "|")
        Return SetError(0, 0, $alecteur)
    Else
        Return SetError(1, 0, $lecteur)
    EndIf
EndFunc


exit

[Jerem21]

Bonjour a tous

Dans le dernier script, je ne vois pas bien a quoi sert cette partie de script :

Code : Tout sélectionner

    If Not $lecteur = "" Then
        $aLecteur = StringSplit(StringTrimRight($lecteur, 1), "|")
        Return SetError(0, 0, $alecteur)
    Else
        Return SetError(1, 0, $lecteur)
    EndIf

Merci

[Tlem]

Et bien tout simplement, si les lecteurs n'ont pas de label, alors il n'y à rien à traiter avec StringSplit et donc on renvoi une erreur.