[R] Formatage d'un fichier texte particulier

[pierrotm777]

Bonjour,

Pour une application particulière , Ride Runner , Front End Carpc, j'ai besoin de reformater un fichier
de POI (points d'intéret GPS) , au format Garmin .csv dans le même format .csv ou .txt :
Téléchargeable ici par exemple:
http://www2.alertegps.com/download_basi ... ous_menu=1

On y obtient 4 fichiers:
RF.csv , radars fixe
RFR.csv, radars feu rouge
RM.csv, radars mobile
ZD.csv, zones dangereuses


Exemple du format de ces 4 fichiers (ZD.csv n'ayant pas de vitesse définie ex: @110)
55.50166,-21.30224,"Num 3461@110" (Radar fixe)
55.42566,-21.30207,"Num 3457@110" (Radar feu rouge)
55.30042,-21.23435,"Num 3455@90" (Radar Mobile)
55.30413,-20.96288,"Num 3456" (Zone Danger)

Le format Garmin est le suivant :
Longitude,Latitude,"Numéro_du_POI@vitesse"

Je voudrais obtenir:
Latitude,Longitude,"RADAR_FIXE vitesse"

Ce qui pourrais donner pour les 4 types de fichiers ci-dessus:
soit :

-21.30224,55.50166,"RADAR_FIXE_110"
-21.30207,55.42566,"RADAR_FEU_ROUGE_110"
-21.23435,55.30042,"RADAR_MOBILE_90"
-20.96288,55.30413,"ZONE_DANGER"

Je voudrais pouvoir donc formater ces 4 fichiers en les sélectionnant par un bouton ouvrant une liste (browser),
et au final concaténer en un seul fichier final au même format .csv ou .txt .

Je vous remercie par avance de votre aide

[Tlem]

Pour vous mettre sur la voie, voici ce que vous devez faire :

- Lire le fichier source séquentiellement dans une boucle :

Code : Tout sélectionner

FileOpen...
...
While 1
     ...
     FileReadLine...
     ...
Wend
FileClose

- Traiter chaque ligne lue pour en retirer les informations désirées.
En l'occurrence vous pouvez utiliser la virgule comme séparateur à l'aide de la fonction StringSplit.

- Suite au traitement précédent, vous vous retrouverez avec 3 'blocs' de données :
Bloc 1 = Longitude
Bloc 2 = Latitude
Bloc 3 = "Numéro_du_POI@vitesse"
Vous devez donc faire d'autres traitement pour décomposer le bloc 3.
Là encore, la fonction StringSplit ou encore mieux la fonction StringRegExp vous permettront d'extraire la vitesse.

En ce qui concerne le type de radar, là c'est un tout petit peut plus complexe, mais pas impossible.
Personnellement, j'opterais pour la recherche de chaine complète avec la fonction StringinStr.
Genre : Si la chaine "Radar fixe" existe alors écrit "RADAR_FIXE_" + $Vitesse

Voilà les grandes lignes.
En utilisant l'outil de recherche du forum, vous pourrez trouver de nombreux exemples utilisant les fonctions que j'ai cité.

[pierrotm777]

Merci beaucoup,

Comme toujours vous êtes présent pour aider
les plus déminis ( en neurones comme moi) , et
je vous en remercie .

Je vais tenter de travailler un peu la dessu et vous demanderais peu être à nouveau de l'aide .

Merci de votre réponse .

[Tlem]

Commencez à construire votre script et si vous êtes bloqué, laissez un message pour nous dire quel problème vous rencontrez.

[pierrotm777]

Bon surtout ne riez pas, voici mon œuvre.
Je n'ai que de vague notion de basic .

Je n'arrive pas à ouvrir les 4 fichiers en même temps .

J'ai réussi à ouvrir un fichier et le lire mais je ne passe à la deuxième ligne
qu'en appuyant sur OK .

J'ai réussi aussi à créer un fichier de sortie mais vide .

Je joind se fichier .

Merci par avance

[Tlem]

Le début me parait correct.
Votre problème vient du fait que vous faite d'abord une boucle de lecture puis une autre boucle pour l'écriture.

De plus, dans la première boucle, vous attribuez chaque ligne à la variable $line_in (ça c'est bon) mais par la suite vous re-définissez cette variable par "l'éclatement" de la ligne : "Longitude,Latitude,Numero@Vitesse"
Déjà, ce n'est pas cette phrase qu'il faut spliter, mais la variable $line_in puisqu'elle contient la chaine à traiter.
Ensuite le résultat sera répartit dans cette nouvelle variable $line_in mais avec un petit quelque chose en plus (voir l'aide de cette fonction).

Ensuite, dans cette boucle, à quel moment enregistrez vous le résultat dans le fichier de sortie ???
Hé oui tout le traitement doit ce faire dans la même boucle et non dans deux boucle séparée.

Une autre solution serait de lire l'intégralité du fichier et de le mettre directement sous forme de tableau grâce à la fonction _FileReadToArray.
Une fois le tableau obtenu, il suffit de le lire ligne par ligne (tout ça ce fait en mémoire, donc plus rapide) et de faire une suite de traitements pour obtenir la ligne de résultat.
On re-définit la ligne du tableau avec le résultat obtenu et ainsi de suite.
Une fois tout le tableau modifié, en enregistre le tout avec _FileWriteFromArray (avantage : une seule lecture et une seule écriture sur le disque).

[pierrotm777]

Bon je m'y remet aujourd'hui .

J'en rie d'avance . Allez , le ridicule ne tue pas .

Merci de votre soutient .

A bientôt .

[pierrotm777]

Je pense avoir suivi vos indications .

je pense que l'inversion de mes 3 éléments par ligne (Longitude Latitude Nom@Vitesse)
se situe dans cette commande mais je n'arrive pas à la retranscrire :

$avUser = _FileListToArray($file_in[$2]&","&$file_in[$1]&","&$file_in[$3])

Mont but étant de faire passer la 2eme variable devant la premiere et laisser la troisieme à sa place
pour un traitement suivant .

[Tlem]

Après avoir jeté un oeil sur votre script, je me suis dit qu'il serait bien de vous donner un bon coup de main.

Voici donc ce que ça peut donner :

► Afficher le texteCode

Code : Tout sélectionner

; Ajout des fichiers nécessaires au fonctionnement du script.
#include <File.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#include <Array.au3> ; cette ligne peut être effacée après avoir vu à quoi ressemblait un tableau.

; Déclaration des variables utilisées pour la suite du script.
Dim $aRadars, $Fichier, $Var, $Var2, $Longitude, $Latitude, $Vitesse, $TypeRadar, $Res
Dim $szDrive, $szDir, $szFName, $szExt

_ChoixRadars() ; La fonction attribue automatiquement le nom du fichier et le type de radar.

; On lit le fichier dans un tableau
If Not _FileReadToArray($Fichier, $aRadars) Then ; Si problème à la lecture du fichier
    MsgBox(4096, "Erreur", "Erreur de lecture du fichier ") ; Erreur
    Exit
EndIf

; Décommentez cette ligne pour voir à quoi ressemble le tableau de départ.
;_ArrayDisplay($aRadars, "Tableau des radars")

For $i = 1 To $aRadars[0] ; permet de lire le tableau de l'élément 1 au dernier.
    $Var = StringSplit($aRadars[$i], ",") ; Ceci permet de lire chaque élément du tableau.
    $Longitude = $Var[1] ; On attribue la valeur de la longitude
    $Latitude = $Var[2] ; On attribue la valeur de la latitude
    $Var2 = StringSplit($Var[3], '@"') ; On décompose la chaine restante
    $Vitesse = $Var2[3] ; On récupère la vitesse

    ; Attribution à la cellule du tableau de la chaine mise en forme.
    $aRadars[$i] = $Latitude & ',' & $Longitude & ',"' & $TypeRadar & " " & $Vitesse & '"'
Next

; Décommentez cette ligne pour voir à quoi ressemble le tableau d'arrivée.
;_ArrayDisplay($aRadars, "Tableau des radars")

; Ecriture du fichier de destination :
_ArrayDelete($aRadars, 0) ; On supprime le nombre d'élément du tableau
$Path = _PathSplit($Fichier, $szDrive, $szDir, $szFName, $szExt) ; On décompose chemin, nom de fichier et extention.
$Fichier = $szDrive & $szDir & $szFName & "_New" & $szExt ; on recompose le nom de fichier avec _New en plus du nom.
If Not _FileWriteFromArray($Fichier, $aRadars) Then ; Si problème à l'écriture du fichier
    MsgBox(4096, "Erreur", "Erreur d'écriture du fichier ") ; Erreur
    Exit
EndIf

$Res = MsgBox(36, "", "Voulez-vous traiter un autre fichier ? ")
If $Res = 6 Then
    If @Compiled Then ; Si le fichier est compilé ...
        ShellExecute(@ScriptFullPath) ; alors on le relance puis ...
        Exit ; on quitte celui-ci
    Else
        ShellExecute(@AutoItExe, '"' & @ScriptFullPath & '"') ; Sinon on lance AutoIt.exe avec le script en argument.
    EndIf
EndIf

Func _ChoixRadars()
    ; Cette partie crée la GUI qui sera affichée.
    #Region ### START Koda GUI section ### Form=
    $Form1 = GUICreate("CSV Convert", 310, 250, -1, -1)
    $IDFic = GUICtrlCreateInput("", 16, 40, 250, 21)
    $Choix = GUICtrlCreateButton("...", 270, 40, 20, 20, 0)
    $RF = GUICtrlCreateRadio("Radars Fixes", 24, 80, 113, 17)
    $RM = GUICtrlCreateRadio("Radars Mobiles", 24, 112, 113, 17)
    $RFR = GUICtrlCreateRadio("Radars Feu Rouge", 24, 144, 113, 17)
    $ZD = GUICtrlCreateRadio("Zone Dangereuse", 24, 176, 113, 17)
    $Annuler = GUICtrlCreateButton("Annuler", 144, 216, 75, 25, 0)
    $OK = GUICtrlCreateButton("OK", 224, 216, 75, 25, 0)
    $Label1 = GUICtrlCreateLabel("Choix du fichier csv radars :", 16, 16, 194, 20)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")

    GUICtrlSetState($RF, $GUI_CHECKED) ; Je choisi par défaut 'Radars Fixes" (il en faut bien un premier ...)

    GUISetState(@SW_SHOW) ; Affichage de la GUI
    #EndRegion ### END Koda GUI section ###

    While 1 ; Boucle de message (voir la section création d'une GUI pour comprendre le fonctionnement)
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE, $Annuler ; Si la fenêtre est fermée ou si le bouton annulé est cliqué.
                Exit
            
            Case $Choix ; Si le bouton ... à été cliqué.
                $Fichier = FileOpenDialog("Choisissez le fichier à modifier", @ScriptDir, "Fichier asc (*.csv)", 1)
                If $Fichier <> "" Then GUICtrlSetData($IDFic, $Fichier) ; Si le nom du fichier n'est pas vide,
                                                                        ; on attribue ca valeur au champ de l'input.
            
            Case $OK ; Si le bouton OK à été cliqué.
                $Fichier = GUICtrlRead($IDFic) ; On lit le nom du fichier
                If FileExists($Fichier) Then ; On vérifie que le fichier existe bel et bien.
                    ; Teste chaque radioBox et valide le choix
                    If _IsChecked($RF) Then $TypeRadar = "RADAR_FIXE"
                    If _IsChecked($RM) Then $TypeRadar = "RADAR_MOBILE"
                    If _IsChecked($RFR) Then $TypeRadar = "RADAR_FEU_ROUGE"
                    If _IsChecked($ZD) Then $TypeRadar = "ZONE_DANGEREUSE"
                
                    GUIDelete($Form1) ; Efface la GUI
                    Return ; on sort de la fonction
                EndIf
        EndSwitch
    WEnd
EndFunc   ;==>_ChoixRadars

; Fonction pour tester si une RadioBox est cochée.
Func _IsChecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Certes, c'est un code complet et fonctionnel.
Mais j'ai tellement commenté le script, que j'espère que vous le lirez et comprendrez comment j'y suis arrivé.
Bonne lecture...

Je me permet de supprimer votre script précédent en fichier joint car il n'a plus grand intérêt.

[pierrotm777]

Bonjour avant tout, et surtout merci , c'est exactement ce que je souhaitai .

Je m'étais juste trompé sur le format final et est donc donc modifié la ligne
de recomposition du tableau comme suit :

$aRadars[$i] = $Latitude & ',' & $Longitude & ',,,500,M,"' & $TypeRadar & "_" & $Vitesse & '"'

car le format final est celui la :
LATTITUDE,LONGITUDE,MINHDG,MAXHDG,DIST,UNIT,"SPEEDCAM-TYPE_SPEED"

Si j'osais, je vous demanderais bien un petit ajout de code .

-Serait-il possible d'avoir une option à cocher en plus permettant la concaténation des 4 fichiers ou pas .
-Choix de l'unité entre MI=Miles, FT=Feet, YD=Yards, KM=Kilometers, M=Meters
-Définition des options MINHDG MAXHDG que l'on pourrai saisir dans la fenêtre GUI .

-Serait-il possible de définir un fichier de configuration de cet outil , soit csv2gpsexec.ini , afin
que l'exécutable , csv2gpsexec.exe puisse soit être lancé comme actuellement ,ou dans une ligne de commande
où il viendrait alors lire le nécessaire dans ce fichier ini .

Je vous proposerais bien le contenu du fichier ini suivant:

Code : Tout sélectionner

[csv2gpsexec.ini]
;define if csv2gpsexec run with (true) or without (false) a GUI : default is false
with_gui=false
;you can define all files in entry here
files_in=file_1.csv,file_2.csv,file_3,csv,file_n.csv
;define here the final file name
file_out=speedcam.csv
;define if concatenation is on or off (true or false , default is true)
concatenation=true
;define here the units (MI=Miles, FT=Feet, YD=Yards, KM=Kilometers, M=Meters ; default is M)
units=M
;define here Minimun and Maximum trigger heading (default is nothing)
MINHDG=
MAXHDG=

Dernier détail, ce programme est dédié à une communauté de gens qui s'entre-aident
dont le hobby est le CarPc , je souhaite donc le diffuser gratuitement sur le site
http://www.mp3car.com/vbulletin/softwar ... velopment/ avec votre autorisation
et une indication précisant que cet outil a été fait par vous peu être .


Merci encore par avance

[Tlem]

Le 'petit' ajout de code implique pas mal de travail, et me semble plus complexe à mettre en œuvre que vous ne semblez le croire (je me fait aussi peut être des idées ).

Mais dans l'idée, il serait peut être bien de revoir la GUI pour mettre 4 lignes de sélection de fichiers (1 pour RF, 1 pour RM, 1 pour RFR et 1 pour Zone dangereuse).
Pour la vitesse, ce n'est sans doute que du calcul de base.
Pour le MINHDG et le MAXHDG, je ne vois pas ce que c'est.

En ce qui concerne la diffusion du script/programme, vous pouvez faire comme vous l'entendez (je ne pose pas de copyright sur mes partages du forum ).
Vous pouvez même omettre de citer l'auteur ou le forum, ça ne me posera aucun problèmes.

[pierrotm777]

J'ai essayé de travailler un peu en faisant quelques ajout .
Notamment au niveau du GUI .

MINHDG et MAXHDG sont deux options en degrés qui peuvent prendre la valeur de 0 à 360°, (on peu ne rien u mettre) .

Je cherche un peu mais bon .

[Tlem]

J'aurais plutôt vu quelque chose comme ceci :

► Afficher le texteCode

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("CSV Convert", 568, 353, -1, -1)
$Annuler = GUICtrlCreateButton("Annuler", 392, 296, 75, 25)
$OK = GUICtrlCreateButton("OK", 480, 296, 75, 25)
$Group1 = GUICtrlCreateGroup(" Radars ", 8, 15, 297, 305)
$Fic_RF = GUICtrlCreateInput("", 16, 63, 250, 21)
$Choix_RF = GUICtrlCreateButton("...", 270, 63, 20, 20)
$Lb_RF = GUICtrlCreateLabel("Fichier radars fixes :", 16, 39, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_RM = GUICtrlCreateInput("", 16, 119, 250, 21)
$Choix_RM = GUICtrlCreateButton("...", 270, 119, 20, 20)
$Lb_RM = GUICtrlCreateLabel("Fichier radars mobiles :", 16, 95, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_RFR = GUICtrlCreateInput("", 16, 183, 250, 21)
$Choix_RFR = GUICtrlCreateButton("...", 270, 183, 20, 20)
$Lb_RFR = GUICtrlCreateLabel("Fichier radars feu rouge :", 16, 159, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_ZD = GUICtrlCreateInput("", 16, 247, 250, 21)
$Choix_ZD = GUICtrlCreateButton("...", 270, 247, 20, 20)
$Lb_ZD = GUICtrlCreateLabel("Fichier radars zones dangereuse :", 16, 223, 242, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Ckb_Fusion = GUICtrlCreateCheckbox("Concaténer les fichiers", 16, 287, 185, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup(" Options   ", 312, 15, 241, 169)
$Lb_Minhdg = GUICtrlCreateLabel("MINHDG :", 327, 75, 72, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Lb_Maxhdg = GUICtrlCreateLabel("MAXHDG :", 327, 110, 76, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Lb_Distance = GUICtrlCreateLabel("DISTANCE :", 327, 145, 88, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Inp_Minhdg = GUICtrlCreateInput("", 442, 70, 97, 21)
$Inp_Maxhdg = GUICtrlCreateInput("", 442, 105, 97, 21)
$Inp_Distance = GUICtrlCreateInput("", 442, 140, 97, 21)
$Lb_Unites = GUICtrlCreateLabel("UNITES :", 327, 40, 68, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cb_Unites = GUICtrlCreateCombo("", 442, 35, 97, 25)
GUICtrlSetData(-1, "Miles (MI)|Feet (FT)|Yards (YD)|Kilometers (KM)|Meters (M)", "Kilometers (KM)")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Menu = GUICtrlCreateMenu("?")
$Apropos = GUICtrlCreateMenuItem("A propos", $Menu)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE, $Annuler
Exit

EndSwitch
WEnd

[pierrotm777]

Oui cela a beaucoup de gueule :

Pour le fichier .ini j'ai péparé cela :

Code : Tout sélectionner

If Not FileExists(@ScriptDir & "\csv2gpsexec.ini") Then
   
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "with_gui ", "false or true default=false")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "files_in ", "add files.csv , ex:files1.csv,files2.csv,...filesn.csv")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "file_out ", "file_out name")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "concatenation ", "concatenation all files , false or true default=false")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "units ", "unit (MI,FT,YD,KM,M) default is M")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "minhdg ", "Minimun trigger heading at location in degres(default=nothing)")
    IniWrite("csv2gpsexec.ini", "csv2gpsexec.ini", "maxhdg ", "Minimun trigger heading at location in degres(default=nothing)")
    

EndIf

[pierrotm777]

bon,
J'ai fait les modifications selon vos conseils et j'ai un problem au
niveau du bouton OK
Je pense que pour concaténer il me faudrait ajouter les résultat de chaque fichier séparé de @CRLF .

J'ai bon ou pas du tout ?

[Tlem]

Dans la partie concernant le bouton OK, vous devriez lire chaque input sensé contenir un nom de fichier, contrôler si les fichiers existes.
Si une case est vide ou si un fichier n'existe pas, alors mettre la variable du chemin à vide.

Pour concaténer :
Faites une boucle de traitement sur les 4 fichiers.
Si Vide, ont passe, sinon lit ont les fichiers ligne par ligne ou par un tableau, puis ont fait le traitement.
Ensuite on ajoute le résultat à une variable.

Code : Tout sélectionner

$MaVar = $MaVar & $MaChaineTraitee & @CRLF

Il est vrais que dans l'exemple précédent, j'ai zappé cette partie car je croyais traiter un seul fichier à la fois.
Cette méthode permet de 'créer' le fichier de destination en mémoire.
Pour finir, il ne reste plus qu'à écrire cette chaîne dans le fichier de destination et le tour est joué.

Pour la partie avec le fichier .ini, je vous laisse faire, car en ce qui me concerne, je trouve qu'avec le nombre de choix possible et vu la gestion de fichiers multiples, cela ressemblera plus à une usine à gaz, qu'à un script simple.

PS : Il est inutile de garder l'historique de toutes les versions de votre script.
Editer la première version et à chaque modif indiquez le lien.

[pierrotm777]

Bonjour,

Merci de votre réponse .

Je vais essayer aujourd'hui de tenir compte de vos conseils.

Je viens juste de réaliser que vous êtes aussi de Bordeaux.

Au plaisir

[pierrotm777]

Bonjour,

Je pense avoir un peu travailler sur le sujet .

-J'ai réussi à récupérer tous les input
-Sur la concaténation j'ai bien gardé un test de bouton radio qui conditionne la somme des variables , mais si je choisi cet option ,
le soft ne va pas plus loin .
-Si je ne choisi pas dans le combo l'unité, M n'arrive pas par défaut .
-Seul le dernier fichier est pris compte quelque fichier que je choisisse.
-Dans le "A Propos" Je voudrais que le lien soit cliquable .

Pouvez vous m'aiguiller ?

Merci par avance d'un coup de pouce.

[Tlem]

Je n'ai mis aucun commentaire et je ne l'ai pas testé à fond, mais ceci devrait fonctionner :

► Afficher le texteCode

Code : Tout sélectionner

#include <UpDownConstants.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <File.au3>
#include <IE.au3>


#Region ### START Koda GUI section ###
$Form1_1 = GUICreate("CSV Convert", 568, 353, -1, -1)
$Annuler = GUICtrlCreateButton("Annuler", 392, 296, 75, 25)
$OK = GUICtrlCreateButton("OK", 480, 296, 75, 25)
$Group1 = GUICtrlCreateGroup(" Radars ", 8, 15, 297, 305)
$Fic_RF = GUICtrlCreateInput("", 16, 63, 250, 21)
$Choix_RF = GUICtrlCreateButton("...", 270, 63, 20, 20)
$Lb_RF = GUICtrlCreateLabel("Fichier radars fixes :", 16, 39, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_RM = GUICtrlCreateInput("", 16, 119, 250, 21)
$Choix_RM = GUICtrlCreateButton("...", 270, 119, 20, 20)
$Lb_RM = GUICtrlCreateLabel("Fichier radars mobiles :", 16, 95, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_RFR = GUICtrlCreateInput("", 16, 183, 250, 21)
$Choix_RFR = GUICtrlCreateButton("...", 270, 183, 20, 20)
$Lb_RFR = GUICtrlCreateLabel("Fichier radars feu rouge :", 16, 159, 194, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Fic_ZD = GUICtrlCreateInput("", 16, 247, 250, 21)
$Choix_ZD = GUICtrlCreateButton("...", 270, 247, 20, 20)
$Lb_ZD = GUICtrlCreateLabel("Fichier radars zones dangereuse :", 16, 223, 242, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cb_Fusion = GUICtrlCreateCheckbox("Concaténer les fichiers", 16, 287, 185, 17)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup(" Options   ", 312, 15, 241, 169)
$Lb_Minhdg = GUICtrlCreateLabel("MINHDG :", 327, 75, 72, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Lb_Maxhdg = GUICtrlCreateLabel("MAXHDG :", 327, 110, 76, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Lb_Distance = GUICtrlCreateLabel("DISTANCE :", 327, 145, 88, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Inp_Minhdg = GUICtrlCreateInput("0", 442, 70, 97, 21)
GUICtrlCreateUpdown(-1, $UDS_WRAP)
GUICtrlSetLimit(-1, 360, 0)
$Inp_Maxhdg = GUICtrlCreateInput("0", 442, 105, 97, 21)
GUICtrlCreateUpdown(-1, $UDS_WRAP)
GUICtrlSetLimit(-1, 360, 0)
$Inp_Distance = GUICtrlCreateInput("0", 442, 140, 97, 21)
$Lb_Unites = GUICtrlCreateLabel("UNITES :", 327, 40, 68, 20)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$Cb_Unites = GUICtrlCreateCombo("", 442, 35, 97, 25)
GUICtrlSetData(-1, "Miles|Feet|Yards|Kilometers|Meters", "Kilometers")
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Menu1 = GUICtrlCreateMenu("?")
$MenuAPropos = GUICtrlCreateMenuItem("A propos", $Menu1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $Annuler
            Exit

        Case $Choix_RF
            $aFic_RF = FileOpenDialog("Fichier Radars Fixes", @ScriptDir, "Fichier asc (*.csv)", 1)
            If $aFic_RF <> "" Then GUICtrlSetData($Fic_RF, $aFic_RF)

        Case $Choix_RM
            $aFic_RM = FileOpenDialog("Fichier Radars Mobiles", @ScriptDir, "Fichier asc (*.csv)", 1)
            If $aFic_RM <> "" Then GUICtrlSetData($Fic_RM, $aFic_RM)

        Case $Choix_RFR
            $aFic_RFR = FileOpenDialog("Fichier Radars Feu Rouge", @ScriptDir, "Fichier asc (*.csv)", 1)
            If $aFic_RFR <> "" Then GUICtrlSetData($Fic_RFR, $aFic_RFR)

        Case $Choix_ZD
            $aFic_ZD = FileOpenDialog("Fichier Radars Zones Dangereuses", @ScriptDir, "Fichier asc (*.csv)", 1)
            If $aFic_ZD <> "" Then GUICtrlSetData($Fic_ZD, $aFic_ZD)

        Case $MenuAPropos
            _Apropos()

        Case $OK
            $vFic_RF = GUICtrlRead($Fic_RF)
            $vFic_RM = GUICtrlRead($Fic_RM)
            $vFic_RFR = GUICtrlRead($Fic_RFR)
            $vFic_ZD = GUICtrlRead($Fic_ZD)

            If $vFic_RF & $vFic_RM & $vFic_RFR & $vFic_ZD <> "" Then
                SplashTextOn("", "Conversion en cours ...", 250, 60, -1, -1, 32, "", 12, 800)

                $Distance = GUICtrlRead($Inp_Distance)
                $Maxhdg = GUICtrlRead($Inp_Maxhdg)
                $Minhdg = GUICtrlRead($Inp_Minhdg)

                $Unites = GUICtrlRead($Cb_Unites)
                Select
                    Case $Unites = "Miles"
                        $Unites = "MI"

                    Case $Unites = "Feet"
                        $Unites = "FT"

                    Case $Unites = "Yards"
                        $Unites = "YD"

                    Case $Unites = "Kilometers"
                        $Unites = "KM"

                    Case $Unites = "Meters"
                        $Unites = "M"
                EndSelect

                Dim $aRF, $aRM, $aRFR, $aZD
                _FileReadToArray($vFic_RF, $aRF)
                _FileReadToArray($vFic_RM, $aRM)
                _FileReadToArray($vFic_RFR, $aRFR)
                _FileReadToArray($vFic_ZD, $aZD)

                Dim $sRF, $sRM, $sRFR, $sZD
                If IsArray($aRF) Then
                    $aRF = _DoIt($aRF, "RADAR_FIXE", $Unites, $Maxhdg, $Minhdg, $Distance)
                    $sRF = _ArrayToString($aRF, @CRLF)
                EndIf

                If IsArray($aRM) Then
                    $aRM = _DoIt($aRM, "RADAR_MOBILE", $Unites, $Maxhdg, $Minhdg, $Distance)
                    $sRM = _ArrayToString($aRM, @CRLF)
                EndIf

                If IsArray($aRFR) Then
                    $aRFR = _DoIt($aRFR, "RADAR_FEU_ROUGE", $Unites, $Maxhdg, $Minhdg, $Distance)
                    $sRFR = _ArrayToString($aRFR, @CRLF)
                EndIf

                If IsArray($aZD) Then
                    $aZD = _DoIt($aZD, "ZONE_DANGEREUSE", $Unites, $Maxhdg, $Minhdg, $Distance)
                    $sZD = _ArrayToString($aZD, @CRLF)
                EndIf

                If _IsChecked($Cb_Fusion) Then
                    FileWrite("Radars_Fusion.csv", $sRF & $sRM & $sRFR & $sZD)
                Else
                    If $sRF <> "" Then _SaveNewFile($vFic_RF, $sRF)
                    If $sRM <> "" Then _SaveNewFile($vFic_RM, $sRM)
                    If $sRFR <> "" Then _SaveNewFile($vFic_RFR, $sRFR)
                    If $sZD <> "" Then _SaveNewFile($vFic_ZD, $sZD)
                EndIf

                SplashOff()
                MsgBox(64, "CSV Convert", "Conversion terminée")
            EndIf
    EndSwitch
WEnd

Exit
; #######################################################
; ####################   Fonctions   ####################
; #######################################################
Func _IsChecked($control)
    Return BitAND(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Func _DoIt($aRadars, $TypeRadar, $Unt, $Mxhdg = 0, $Mnhdg = 0, $Dst = 0)
    Local $i, $Var, $Var2, $Longitude, $Latitude, $Vitesse
    For $i = 1 To $aRadars[0]
        $Var = StringSplit($aRadars[$i], ",")
        $Longitude = $Var[1]
        $Latitude = $Var[2]
        $Var2 = StringSplit($Var[3], '@"')
        $Vitesse = $Var2[3]

        $aRadars[$i] = $Latitude & ',' & $Longitude & ',' & $Mxhdg & ',' & $Mnhdg & ',' & _
                $Dst & ',' & $Unt & ',"' & $TypeRadar & "_" & $Vitesse & '"'
    Next

    _ArrayDelete($aRadars, 0) ; On supprime le nombre d'élément du tableau
    Return $aRadars
EndFunc   ;==>_DoIt

Func _SaveNewFile($Fichier, $sRadar)
    Local $szDrive, $szDir, $szFName, $szExt, $Path
    $Path = _PathSplit($Fichier, $szDrive, $szDir, $szFName, $szExt)
    $Fichier = $szDrive & $szDir & $szFName & "_New" & $szExt

    $hFichier = FileOpen($Fichier, 2)
    If $hFichier = -1 Then
        MsgBox(0, "Erreur", "Impossible de traiter le fichier :" & @CRLF & $Fichier)
        Return
    EndIf

    FileWrite($hFichier, $sRadar)
    FileClose($hFichier)
EndFunc   ;==>_SaveNewFile

Func _Apropos()
    $sHTML = 'Ce programme est conçu pour modifier<br>' & _
            'quatre fichiers ascii issus du site <a href=http://www2.alertegps.com/>alertegps.com</a><br><br>' & _
            'Les fichiers au format Garmin sont à télécharger ' & _
            '<a href=http://www2.alertegps.com/download_basic.asp?id_matos=8&menu=1&sous_menu=1>ici</a><br><br>' & _
            'On obtient quatre fichiers :<br>' & _
            'RF.csv , radars fixe<br>' & _
            'RFR.csv, radars feu rouge<br>' & _
            'RM.csv, radars mobile<br>' & _
            'ZD.csv, zones dangereuses<br><br>' & _
            'Exemple du format de ces 4 fichiers (ZD.csv n''ayant pas de vitesse définie ex: @110)<br>' & _
            '55.50166,-21.30224,"Num 3461@110" (Radar fixe)"<br>' & _
            '55.42566,-21.30207,"Num 3457@110" (Radar feu rouge)"<br>' & _
            '55.30042,-21.23435,"Num 3455@90" (Radar Mobile)<br>' & _
            '55.30413,-20.96288,"Num 3456" (Zone Danger)<br><br>' & _
            'Ce format est compatible Garmin, soit :<br>' & _
            'Longitude,Latitude,"Numéro_du_POI@vitesse"<br><br>' & _
            'Nous obtenons en sortie :<br>' & _
            'Latitude,Longitude,MinHdg,MaxHdg,,,Distance,Unités,"RADAR_FIXE vitesse"<br>' & _
            'soit au final :<br>' & _
            '-21.30224,55.50166,,,500,"RADAR_FIXE_110"<br>' & _
            '-21.30207,55.42566,,,500,"RADAR_FEU_ROUGE_110"<br>' & _
            '-21.23435,55.30042,,,500,"RADAR_MOBILE_90"<br>' & _
            '-20.96288,55.30413,,,500,"ZONE_DANGER"'

    _IEErrorHandlerRegister()
    $oIE = _IECreateEmbedded()

    $GuiApropos = GUICreate("À Propos", 640, 550, -1, -1, $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
    $GUIActiveX = GUICtrlCreateObj($oIE, 5, 5, 630, 500)
    $OK2 = GUICtrlCreateButton("OK", 300, 515, 75, 25)

    _IENavigate($oIE, "")
    _IEBodyWriteHTML($oIE, $sHTML)

    GUISetState()

    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE Or $msg = $OK2
                ExitLoop
        EndSelect
    WEnd

    GUIDelete($GuiApropos)
EndFunc   ;==>_Apropos

Je veux bien que le site soit cité dans la liste des crédits.

[pierrotm777]

Bonjour,

Et merci pour votre aide .
C'est exactement ce que je voulais .
Juste une remarque , dans le fichier concaténé , il n'y a pas de retour ligne entre chaque type de radar ce qui donne ceci:

57.6725,-2.00621,,,500,M,"RADAR_FIXE_60"16.15745,-61.58584,,,500,M,"RADAR_MOBILE_110" au lieu de ceci :

57.6725,-2.00621,,,500,M,"RADAR_FIXE_60"
16.15745,-61.58584,,,500,M,"RADAR_MOBILE_110"

J'ai donc modifié la ligne suivante :

Code : Tout sélectionner

FileWrite("Radars_Fusion.csv", $sRF & $sRM & $sRFR & $sZD)

par

Code : Tout sélectionner

FileWrite("Radars_Fusion.csv", $sRF & @CRLF & $sRM & @CRLF & $sRFR & @CRLF & $sZD)

Les lien de A Propos s'ouvrent dans la fenêtre A Propos au lieu du navigateur par défaut IE ou Firefox .

J'avais remarqué que dans le fichier ZD.csv trés peu de ligne avaient une vitesse de définie.
On se retrouvait alors avec des lignes du genre "ZONE_DANGEREUSE_" .

J'ai donc ajouté cette ligne de test dans la boucle ci-dessous :

Code : Tout sélectionner

For $i = 1 To $aRadars[0]
        $Var = StringSplit($aRadars[$i], ",")
        $Longitude = $Var[1]
        $Latitude = $Var[2]
        $Var2 = StringSplit($Var[3], '@"')
        $Vitesse = $Var2[3]
        [color=#FF0000]If $Vitesse = "" Then $Vitesse = 0[/color]
        $aRadars[$i] = $Latitude & ',' & $Longitude & ',' & $Mxhdg & ',' & $Mnhdg & ',' & _
                $Dst & ',' & $Unt & ',"' & $TypeRadar & "_" & $Vitesse & '"'
    Next

Ainsi , "ZONE_DANGEREUSE_" devient "ZONE_DANGEREUSE_0" lorsque aucune vitesse n'est trouvée .

Où puis-je trouver un exemple d'option de langage ? Je pensais par exemple à
la mise en place d'une option venant lire un fichier French.lang ou English.lang afin de rendre ce logiciel multilangue .

Pensez vous que la version finale intéresse ce forum , en ce cas il est à disposition .

Je compte ajoutez mes remerciement dans le à Propos , http://www.autoitscript.fr/forum/ , et votre pseudo , Tlem .

Voila , Je vous remercie encore beaucoup car j'ai beaucoup appris et je compte bien
persévérer avec votre aide .