[Ex] Création de script Internet Explorer (IE)

[bloodwolff]

Voici une première version de mon script je le publie maintenant car si il n'y a pas d'intérêt je ne le terminerai pas pour rien
En gros le script sert à créer d'autre script car d'après mes lectures sur le forum automatiser les visites reste assez problématique
En gros vous lancez le script , vous entrez l'url de départ
Vous remplissez les formulaire , naviguer sur le site, coché des case , choisissez des options et quand vous avez terminé vous fermer la fenêtre et la un jolie code autoit apparais et il reproduit les actions que vous venez d'effectuer
En théorie le script gère les liens,les input,les boutons,les checkbox,les select,les zones de textes mais bon aucun site n'est semblable et il se peut qu'il ne fonctionne pas sur tout les sites
Donc j'aimerais connaître les sites où le script buggais pour l'adapter et avoir vos commentaires
Si il y a de l'intérêt je le continue

► Afficher le texteversion 2.0

Code : Tout sélectionner

;==================================================================
;################# Déclaration des Includes #######################
;==================================================================
#include <IE.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>

;==================================================================
;################## Déclaration des Options #######################
;==================================================================
OnAutoItExitRegister("OnExit")
Opt("GUIOnEventMode",1)
_IEErrorHandlerRegister()

$url = InputBox("autoIE", "Quel est l'url?", "", "", 120, 150)

;==================================================================
;################# Déclaration des variables ######################
;==================================================================
Global $ie_get_obj_by_value = False
Global $script = '#include <IE.au3>' & @CRLF & @CRLF
$script &= '$oIE = _IECreate ("' & $url & '")' & @CRLF & @CRLF
Global $oIE = _IECreateEmbedded()

;==================================================================
;#################### Création de la Gui  #########################
;==================================================================
$form = GUICreate("", 400, 200, -1, -1, $WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($form, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 400, 200)
GUICtrlSetResizing($GUIActiveX, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
_IENavigate($oIE, $url)
GUISetState(@SW_SHOW)
GUISetState(@SW_MAXIMIZE)

;==================================================================
;################# Déclaration des Events #######################
;==================================================================

GUISetOnEvent($GUI_EVENT_CLOSE, "Onexit")
Obj_event()

;==================================================================
;######################## Boucle infini ###########################
;==================================================================
While 1
    Sleep(1000)
WEnd

;==================================================================
;########## Fonctions de déclarations d'events ####################
;==================================================================
Func Obj_event()
    ConsoleWrite("a" & @CRLF)
    $oElements = _IETagNameAllGetCollection($oIE)
    For $oElement in $oElements
        $tag = ""
        Switch String($oElement.tagname)
            Case "input"
                Switch String($oElement.type)
                    Case "submit"
                        $tag = "Submit"
                    Case "button"
                        $tag = "Submit"
                    Case "Checkbox"
                        $tag = "Checkbox"
                    case "radio"
                        $tag = "Checkbox"
                    Case "text"
                        $tag = "Text"
                    case "password"
                        $tag = "Text"
                EndSwitch
            Case "textarea"
                $tag = "Text"
            Case "A"
                $tag = "Link"
            Case "Select"
                $tag = "Select"
        EndSwitch
        If $tag <> "" Then ObjEvent($oElement, $tag & "_")
    Next
EndFunc ;Obj_event

;==================================================================
;##################### Fonctions d'events #########################
;==================================================================

Func Select_OnChange()
    $obj = @COM_EventObj
    if String($obj.id) <> "0" and string($obj.id) <> "" Then
        $check_name = string($obj.id)
        $var_name = "Id"
    ElseIf String($obj.name) <> "0" and string($obj.name) <> "" Then
        $check_name = string($obj.name)
        $var_name = "Name"
    Else
        Return
    EndIf
    $script &= '$Select_' & $var_name & ' = _IEGetObjById($oIE, "' & String($obj.id) & '")' & @CRLF
    $script &= '$Select_' & $var_name & '.selectedindex = ' & number($obj.selectedIndex) & @CRLF
EndFunc

Func Link_OnFocus()
    $obj = @COM_EventObj
    $url = String($obj.href)
    $script &= '_IENavigate ($oIE, "' & $url & '")' & @CRLF & @CRLF
    _IENavigate($oIE, $url)
    Obj_event()
EndFunc ;Link_onclick

Func Checkbox_Onclick()
    $obj = @COM_EventObj
    if String($obj.id) <> "0" and string($obj.id) <> "" Then
        $check_name = string($obj.id)
        $var_name = "Id"
    ElseIf String($obj.name) <> "0" and string($obj.name) <> "" Then
        $check_name = string($obj.name)
        $var_name = "Name"
    Else
        Return
    EndIf
    $script &= '$check_' & $var_name & '  = _IEGetObjBy' & $var_name & '($oIE, "' & $check_name & '")' & @CRLF
    If string($obj.type) = "Radio" Then
        $checked = False
    Else
        $checked = $obj.checked
    EndIf
    If $checked Then
        $script &= '$check_' & $var_name & '.checked = True' & @CRLF
    ElseIf Not $checked Then
        $script &= '$check_' & $var_name & '.checked = False' & @CRLF
    EndIf
EndFunc ; checkbox

Func Text_Onblur()
    $obj = @COM_EventObj
    $text = String($obj.value)
    if String($obj.id) <> "0" and string($obj.id) <> "" Then
        $input_name = string($obj.id)
        $var_name = "Id"
    ElseIf String($obj.name) <> "0" and string($obj.name) <> "" Then
        $input_name = string($obj.name)
        $var_name = "Name"
    Else
        Return
    EndIf
    $script &= '$Input_' & $var_name & '  = _IEGetObjBy' & $var_name & '($oIE, "' & $input_name & '")' & @CRLF
    $script &= '_IEFormElementSetValue($Input_' & $var_name & ', "' & $text & '")' & @CRLF
EndFunc ;text_onblur

Func Submit_Onclick()
    $obj = @COM_EventObj
    If String($obj.id) <> "0" and String($obj.id) <> "" Then
        $submit_name = String($obj.id)
        $var_name = "Id"
    ElseIf String($obj.name) <> "0" and String($obj.name) <> "" Then
        $submit_name = String($obj.name)
        $var_name = "Name"
    ElseIf String($obj.value) <> "0" and String($obj.value) <> "" Then
        $submit_name = String($obj.value)
        $var_name = "Value"
        $ie_get_obj_by_value = True
    Else
        Return
    EndIf
    $script &= '$submit_' & $var_name &'  = _IEGetObjBy' & $var_name & '($oIE, "' & $submit_name & '")' & @CRLF
    $script &= '_IEAction($submit_' & $var_name & ', "Click")' & @CRLF & @CRLF
EndFunc ;submit_onclick

;==================================================================
;###################### Fonction de Fin ###########################
;==================================================================
Func OnExit()
    OnAutoItExitUnregister("OnExit")
    GUIDelete()
    Opt("GUIOnEventMode",0)
    If $ie_get_obj_by_value Then
        $script &= 'Func _IeGetObjByValue($oIE, $value)' & @CRLF
        $script &= '    $oElements = _IETagNameGetCollection($oIE, "INPUT")' & @CRLF
        $script &= '    For $oElement in $oElements' & @CRLF
        $script &= '        If string($oElement.value) = $value Then _' & @CRLF
        $script &= '        Return $oElement' & @CRLF
        $script &= '    Next' & @CRLF
        $script &= 'EndFunc ;~ IeGetObjByValue' & @CRLF
    EndIf
    $Form2 = GUICreate("Code", 612, 436)
    $Edit1 = GUICtrlCreateEdit("", 0, 0, 609, 409, BitOR($GUI_SS_DEFAULT_EDIT, $ES_READONLY))
    GUICtrlSetData(-1, $script)
    $Button1 = GUICtrlCreateButton("Copier", 0, 416, 611, 17)
    GUISetState(@SW_SHOW)
    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $Button1
                ClipPut($script)
                Exit
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>OnExit

 

► Afficher le texteversion 1.0

Code : Tout sélectionner

#include <IE.au3>
#Include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>

OnAutoItExitRegister("OnExit")

$ie_get_obj_by_value = False
$url = InputBox("autoIE", "Quel est l'url?","","",120,150)
Global $script = '#include <IE.au3>' & @CRLF & @CRLF
$script &= '$oIE = _IECreate ("' & $url & '")' & @CRLF & @CRLF

$oIE = _IECreateEmbedded ()
#Region ### START Koda GUI section ### Form=
$form = GUICreate("", 400, 200,-1,-1,$WS_OVERLAPPEDWINDOW)
GUICtrlSetResizing($Form, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
$GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 400, 200)
GUICtrlSetResizing($GUIActiveX, $GUI_DOCKAUTO + $GUI_DOCKBOTTOM + $GUI_DOCKTOP)
$MenuItem1 = GUICtrlCreateMenu("Menu")
$MenuItem2 = GUICtrlCreateMenuItem("Aide - F1", $MenuItem1)
$MenuItem3 = GUICtrlCreateMenuItem("Changer de site - F2", $MenuItem1)
$MenuItem4 = GUICtrlCreateMenuItem("Quitter - Esc", $MenuItem1)
GUICtrlSetState($MenuItem1,$GUI_DISABLE)
#EndRegion ### END Koda GUI section ###
_IENavigate($oIE, $url)
GUISetState(@SW_SHOW)
GUISetState(@SW_MAXIMIZE)

_readonly($oIE)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
    If _IsPressed("01") And WinActive($form) Then
    _onclick($oIE)
    EndIf

WEnd


Func _readonly($oIE)
    $inputs = _IETagNameGetCollection($oIE,"Input")
    For $input in $inputs
        If String($input.type) = "text" or "password" or "textarea" Then _
        $input.readonly = True
    Next
    Send("{tab}")
EndFunc ; readonly

Func _onclick($oIE)
    $active = $oIE.document.activeElement
    Switch String($active.tagname)
        Case "select"
            _Select($active)
        Case "a"
            _link($oIE,$active)
        Case "input" and StringInStr($active.outerhtml,"Type=submit")
            _submit($active)
        Case "input" and StringInStr($active.outerhtml,"Type=CheckBox") or StringInStr($active.outerhtml,"Type=Radio")
            _checkbox($active)
        Case "input"
            If StringInStr($active.outerhtml,"Type=Password") Then
                $mdp = "*"
            Else
                $mdp = ""
            EndIf
            If not string($active.value) Then
                $text = string($active.value)
            Else
                $text = ""
            EndIf
            $text = InputBox("AutoIE", "Quel texte voulez-vous mettre?", $text, $mdp, 120,150)
            If not @error Then _text($active,$text)
        Case "textarea"
        If not string($active.value) Then
            $text = string($active.value)
        Else
            $text = ""
        EndIf
        $Form3 = GUICreate("Code", 612, 436)
        $Edit1 = GUICtrlCreateEdit("", 0, 0, 609, 409)
        GUICtrlSetData(-1, $text)
        $Button2 = GUICtrlCreateButton("Confirmer", 0, 416, 611, 17)
        GUISetState(@SW_SHOW)

        While 1
            $nMsg = GUIGetMsg()
            Switch $nMsg
                Case $Button2
                    $text = GUICtrlRead($Edit1)
                    _text($active, $text)
                    GUIDelete()
                    Return
                Case $GUI_EVENT_CLOSE
                    GUIDelete()
                    Return
            EndSwitch
        WEnd
    EndSwitch

    Do
        Sleep(100)
    Until not _IsPressed("01")

EndFunc ; On click

Func _text($active,$text)
    $input_name = string($active.name)
    $script &= '$Input_name  = _IEGetObjByName($oIE, "' & $input_name & '")' & @CRLF
    $script &= '_IEFormElementSetValue($Input_name, "' & $text & '")' & @CRLF
    _IEFormElementSetValue($active, $text)
EndFunc ;text

Func _checkbox($active)
    $check_name = $active.name
    $script &= '$check_name  = _IEGetObjByName($oIE, "' & $check_name & '")' & @CRLF
    if StringInStr($active.outerhtml,"Type=Radio") Then
        $checked = False
    Else
        $checked = $active.checked
    EndIf
    If $checked Then
        $script &= '$check_name.checked = false' & @CRLF
    ElseIf not $checked Then
        $script &= '$check_name.checked = true' & @CRLF
    EndIf
EndFunc ;checkbox

Func _submit($active)
    $ie_get_obj_by_value = True
    $submit_name = string($active.value)
    $script &= '$submit_name  = _IEGetObjByValue($oIE, "' & $submit_name & '")' & @CRLF
    $script &= '_IEAction($submit_name, "Click")' & @CRLF & @CRLF
    $submit_name = $active
    _IEAction($submit_name, "Click")
EndFunc ;submit

Func _link($oIE,$active)
    $url = String($active.href)
    $script &= '_IENavigate ($oIE, "' & $url & '")' & @CRLF & @CRLF
    _IENavigate($oIE, $url)
    _readonly($oIE)
EndFunc ;link

Func _Select($active)

    dim $Combo[1][2] = [[0,""]]
    For $option In $active.options
        $Combo[0][0] += 1
        ReDim $Combo[$Combo[0][0]+1][2]
        $Combo[$Combo[0][0]][0] = String($option.innertext)
        $Combo[$Combo[0][0]][1] = String($option.index)
        $Combo[0][1] &= "|" & String($option.innertext)
    Next

    $Form2 = GUICreate("", 221, 27)
    $Combo1 = GUICtrlCreateCombo("", 0, 2, 145, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
    GUICtrlSetData(-1,$Combo[0][1],$Combo[1][0])
    $Button2 = GUICtrlCreateButton("Confirmer", 144, 0, 75, 25)
    GUISetState(@SW_SHOW)


    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $Button2
                $compare = GUICtrlRead($Combo1)
                For $i=1 to $Combo[0][0]
                    If $compare = $Combo[$i][0] Then
                        $active.selectedIndex = Number($Combo[$i][1])
                        $script &= '$Select_id  = _IEGetObjById($oIE, "' & String($active.id) & '")' & @CRLF
                        $script &= '$Select_id.selectedindex = ' & Number($Combo[$i][1]) & @CRLF
                        GUIDelete()
                        Return
                    EndIf
                Next
            Case $GUI_EVENT_CLOSE
                Exit

        EndSwitch
    WEnd

EndFunc ;select

Func OnExit()
    If $ie_get_obj_by_value Then
        $script &= 'Func _IeGetObjByValue($oIE, $value)' & @CRLF
        $script &= '    $oElements = _IETagNameGetCollection($oIE, "INPUT")' & @CRLF
        $script &= '    For $oElement in $oElements' & @CRLF
        $script &= '        If string($oElement.value) = $value Then _' & @CRLF
        $script &= '        Return $oElement' & @CRLF
        $script &= '    Next' & @CRLF
        $script &= 'EndFunc ;~ IeGetObjByValue' & @CRLF
    EndIf
    GUIDelete()
    $Form2 = GUICreate("Code", 612, 436)
    $Edit1 = GUICtrlCreateEdit("", 0, 0, 609, 409, BitOR($GUI_SS_DEFAULT_EDIT,$ES_READONLY))
    GUICtrlSetData(-1, $script)
    $Button1 = GUICtrlCreateButton("Copier", 0, 416, 611, 17)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $Button1
                ClipPut($script)
                Exit
            Case $GUI_EVENT_CLOSE
                Exit

        EndSwitch
    WEnd
EndFunc ; Onexit

[pop45]

Sa peut aider, mais faut que tu précise que sa ne marche pas avec du flash ^^

[bloodwolff]

Je sais même pas ce qu'est le flash
Je pense que sa sert à faire des animations sur internet

Mais bon comme je l'ai c'est vraiment une première version, et elle peut être utile pour remplir des formulaire
Je posterai un exemple de script créé avec

[bloodwolff]

Voilà le code d'un script qui pourrait écrire ce message sur le forum (en modifiant les id/mot de passe) crée par le script

Édit: Voilà le code ^^
Ps: script totalement inutile mais bon il fonctionne et il m'a pris 20 secondes à faire au lieu de plusieurs minutes normalement

► Afficher le texte

Code : Tout sélectionner

#include <IE.au3>

$oIE = _IECreate ("http://autoit.fr/forum/ucp.php?mode=login")

$Input_name  = _IEGetObjByName($oIE, "username")
_IEFormElementSetValue($Input_name, "*******")
$Input_name  = _IEGetObjByName($oIE, "password")
_IEFormElementSetValue($Input_name, "******")
$check_name  = _IEGetObjByName($oIE, "viewonline")
$check_name.checked = true
$submit_name  = _IEGetObjByValue($oIE, "Connexion")
_IEAction($submit_name, "Click")

_IENavigate ($oIE, "http://autoit.fr/forum/index.php?sid=7351ee9345a6c328618f87f63dab7b6c")

_IENavigate ($oIE, "http://autoit.fr/forum/viewforum.php?f=6&sid=7351ee9345a6c328618f87f63dab7b6c")

_IENavigate ($oIE, "http://autoit.fr/forum/viewtopic.php?f=6&t=6364&sid=7351ee9345a6c328618f87f63dab7b6c")

_IENavigate ($oIE, "http://autoit.fr/forum/posting.php?mode=reply&f=6&t=6364&sid=7351ee9345a6c328618f87f63dab7b6c")

$Input_name  = _IEGetObjByName($oIE, "message")
_IEFormElementSetValue($Input_name, "Voilà le code d'un script qui pourrait écrire ce message sur le forum (en modifiant les id/mot de passe) crée par le script")
$submit_name  = _IEGetObjByValue($oIE, "Envoyer")
_IEAction($submit_name, "Click")

_IENavigate ($oIE, "http://autoit.fr/forum/viewtopic.php?f=6&t=6364&p=39759&sid=7351ee9345a6c328618f87f63dab7b6c#p39759")

Func _IeGetObjByValue($oIE, $value)
    $oElements = _IETagNameGetCollection($oIE, "INPUT")
    For $oElement in $oElements
        If string($oElement.value) = $value Then _
        Return $oElement
    Next
EndFunc ;~ IeGetObjByValue
 

[pop45]

Voila un exemple d'interface flash :http://www.megaupload.com/

[bloodwolff]

Ah oui sa va être plus dur à intégrer
Mais bon déjà si il gère les sites de base sa va faciliter la vie à plusieurs personnes je pense

[timmalos]

Tu peux également t'aider de mon ancien script jamais terminé :

http://autoitscript.fr/forum/viewtopic.php?f=6&t=3632

On a pas utilisé la même méthode, mais c'est à voir ce qui marche le mieux.

[bloodwolff]

Ah je ne l'avais pas vu , j'y jetterai un oeil
ps : Ton script me retourne un script qui me donne un erreur au lancement :s mais j'aime la partie graphique c'est beau Tu les trouve où ces icones ?

[bloodwolff]

Mise à jour majeur qui ne paraîtra pas beaucoup pour les utilisateurs
mais le code à été entièrement refait ,
-un peu plus court
- plus de compatibilité envers les différent site
-code plus propre
-changement complet de la méthode pour prélévé les données
-plus de pop up

Code disponible dans le premier post , j'ai laissé le premier mais j'ai retiré le code couleur

Maintenant je vais pouvoir m'attaquer à d'autre amélioration

[bloodwolff]

Bug constaté lorsque l'on clique sur un lien , je règle cela dès que possible

Édit : Bug réglé de façon temporaire

[Supemm]

Bonjour,

merci d'abord pour votre script.
Pour info le script a un problème sur le site suivant :

http://www.cio.fr
on remplit la zone identifiant (un nombre), puis on remplit la zone mot de passe (un nombre) et ensuite on clique sur OK. Cela permet d'accéder aux comptes bancaires.

Cependant quand on exécute le script, le script clique sur le mauvais bouton OK, il clique sur le bouton OK tout en haut à droite qui correspond à la zone "Rechercher". On ne peut donc pas accéder aux comptes automatiquement.


Cordialement,

Emmanuel

[bloodwolff]

Oui j'avais un peu abandonner le script mais je peux regarder quand j'aurai plus de temps !

[leoclem]

Juste un message pour te remercier, tu as fait du bon boulot !
A part quelques petites modifs à effectuer dans le script résultat pour des cas particuliers, on a le corps du script et ça c'était le plus important pour moi!

Moi qui galérais avec l'UDF IE.au3, j'ai trouvé mon bonheur !

Merci encore !

[sksbir]

hello
Ton script est un "must have" pour celui qui n'a jamais touché à l'UDF d'IE6 ( comme moi ).
J'ai testé ton script pour la connexion automatique à GLPI.

Je veux l'utiliser pour une base locale qui n'est donc pas dispo sur internet.

Par contre, pour te montrer, il existe par chance une base glpi de démonstration ici : http://demo.glpi-project.org

Le code généré par ton script pour l'accès à la base de démo est celui-ci:

Code : Tout sélectionner

#include <IE.au3>
$oIE = _IECreate ("http://demo.glpi-project.org/")
$Input_Id  = _IEGetObjById($oIE, "login_name")
_IEFormElementSetValue($Input_Id, "post-only")
$Input_Id  = _IEGetObjById($oIE, "login_password")
_IEFormElementSetValue($Input_Id, "postonly")
$submit_Name  = _IEGetObjByName($oIE, "submit")
_IEAction($submit_Name, "Click")

Et là, j'ai quelques remarques:
- j'ai fait d'autres actions après ça ( cliquer sur "ticket" par exemple), et ton script ne les a pas prises en compte.
- j'aimerais aussi repartir sur une autre URL après la saisie du login, mais ton script ne permet pas de saisir une autre URL après avoir saisi celle de départ.( Edit : après quelques recherches, il suffirait de rajouter une commande _IENavigate() dans le script généré, donc, je sais pas si c'est la peine d'implémenter ça...)

Mais déjà comme ça, ton script est vraiment très bien. Il m'a bien donné envie de gratter l'UDF de IE de plus près : la 1ere question qui me vient à l'esprit étant celle-ci : on utilise AU3info pour repérer les élements de la fenetre IE ? et sinon, on fait comment ? [edit : là aussi, je pense avoir trouvé : code source de la page web, et utilisation de MODIv2

[bloodwolff]

Oui , c'est un peu complexe à faire et je suis conscient qu'il existe de nombreux bug mais je n'ai pas le temps ces temps-ci pour la programmation. J'espère avoir le temps de l'améliorer bientôt et merci pour tes critiques
Sinon si tu as besoin d'aide rapide tu peux toujours m'envoyer un petit message, je verrai ce que je peux faire.

[zesteph]

Merci pour ce script il va m'être utile