[R] Problème de checkbox

[Pandora]

Bonjour à tous !

Me revoici avec un nouveau problème, je m'explique :

Je voudrais crée une check box mais la se pose trois problèmes :

- le premier : un rectangle apparait autour de mon texte.
- le deuxième : lorsque la check box dispose d'un arrière plan personnalisé (ici une image en .jpg) il est impossible de cocher les choix possible
-le troisième : la fenêtre est surdimensionnée par rapport au texte.

Si sa peut aider voici le code :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Mon programe", 631, 667, 213, 152)
GUICtrlCreatePic("fond.jpg", 0, 0, 700, 670)

Global $Button1 = GUICtrlCreateButton("Lancer   !", 296, 584, 129, 57, $WS_GROUP)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")


Global $Checkbox1 = GUICtrlCreateCheckbox(" Mozilla firefox", 296, 280, 209, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")


GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd
 

Merci d'avance

[TT22]

Pour la taille, essaye ça :

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Mon programe", 300, 100, 213, 152)
GUICtrlCreatePic("fond.jpg", 0, 0, 700, 670)

Global $Button1 = GUICtrlCreateButton("Lancer   !", 80, 35, 129, 57, $WS_GROUP)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")


Global $Checkbox1 = GUICtrlCreateCheckbox(" Mozilla firefox", 10, 10, 209, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")


GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd

[mikell]

Eh ben tu sais qu'il est pas évident ton problème, malgré son air simple ?
Très intéressante ta question en tout cas, car les solutions habituelles ne marchent pas !
Teste ce script (que tu vas devoir adapter à tes besoins...)

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global Enum _
  $i_Start_Row = -1, _
  $i_hGUI_Row, $i_hPic_Row, $i_hCB_Row, _
  $i_Total_Rows
Global $aTrnsChckBxs_DATA[1][$i_Total_Rows]

$hGUI = GUICreate("Test transparent checkbox replacement", 400, 200)
$nPic = GUICtrlCreatePic(@AutoItExe & "\..\Examples\GUI\msoobe.jpg", 0, 0, 400, 200, 0)

GUICtrlCreateCheckbox("Standard checkbox", 10, 10, 200, 20)
GUICtrlCreateCheckbox("Standard checkbox transparent", 10, 50, 200, 20)
GUICtrlSetBkColor(-1, -2)
GUICtrlCreateCheckbox("Standard checkbox workaround", 10, 90, 13, 13)
GUICtrlCreateLabel("Standard checkbox workaround", 26, 90, 200, 13)
GUICtrlSetBkColor(-1, -2)

$nCB1 = _GUICtrlTransCheckbox_Create($hGUI, $nPic, "TransparentCheckbox 1", 10, 130)
$nCB2 = _GUICtrlTransCheckbox_Create($hGUI, $nPic, "TransparentCheckbox 2", 10, 170)

GUISetState(@SW_SHOW, $hGUI)

While 1
 $nGUIMsg = GUIGetMsg()

 Switch $nGUIMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $nCB1, $nCB2
   ConsoleWrite("CheckBox [" & GUICtrlRead($nGUIMsg, 1) & "] checked = " & (GUICtrlRead($nGUIMsg) = $GUI_CHECKED) & @LF)
 EndSwitch
WEnd

Func _GUICtrlTransCheckbox_Create($hGUI, $nBackPic, $sText, $iLeft, $iAbove, $iWidth = -1, $iHeight = -1, $iStyle = -1, $iExStyle = 0)
 Local $nCB = GUICtrlCreateCheckbox($sText, $iLeft, $iAbove, $iWidth, $iHeight, $iStyle, $iExStyle)
 Local $hCB = GUICtrlGetHandle($nCB)
 Local $hPic = GUICtrlGetHandle($nBackPic)

 If $aTrnsChckBxs_DATA[0][0] = 0 Then
  GUIRegisterMsg($WM_NOTIFY, '_TrnsChckBx_WM_NOTIFY')
 EndIf

 $aTrnsChckBxs_DATA[0][0] += 1
 ReDim $aTrnsChckBxs_DATA[$aTrnsChckBxs_DATA[0][0] + 1][$i_Total_Rows]

 $aTrnsChckBxs_DATA[$aTrnsChckBxs_DATA[0][0]][$i_hGUI_Row] = $hGUI
 $aTrnsChckBxs_DATA[$aTrnsChckBxs_DATA[0][0]][$i_hPic_Row] = $hPic
 $aTrnsChckBxs_DATA[$aTrnsChckBxs_DATA[0][0]][$i_hCB_Row] = $hCB

 Return $nCB
EndFunc   ;==>_GUICtrlTransCheckbox_Create

Func _GUICtrlTransCheckbox_Delete($nChckBx)
 Local $hCB = GUICtrlGetHandle($nChckBx)
 Local $aTmp[$aTrnsChckBxs_DATA[0][0]][$i_Total_Rows]

 GUICtrlDelete($nChckBx)

 For $i = 1 To $aTrnsChckBxs_DATA[0][0]
  If $aTrnsChckBxs_DATA[$i][$i_hCB_Row] <> $hCB Then
   $aTmp[0][0] += 1

   $aTmp[$aTmp[0][0]][$i_hGUI_Row] = $aTrnsChckBxs_DATA[$i][$i_hGUI_Row]
   $aTmp[$aTmp[0][0]][$i_hPic_Row] = $aTrnsChckBxs_DATA[$i][$i_hPic_Row]
   $aTmp[$aTmp[0][0]][$i_hCB_Row] = $aTrnsChckBxs_DATA[$i][$i_hCB_Row]
  EndIf
 Next

 ReDim $aTmp[$aTmp[0][0] + 1][$i_Total_Rows]
 $aTrnsChckBxs_DATA = $aTmp

 Return $aTmp[0][0]
EndFunc   ;==>_GUICtrlTransCheckbox_Delete

Func _TrnsChckBx_WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
 Local $hWndFrom, $iIDFrom, $tNMHDR
 Local Const $tagNMCUSTOMDRAW = 'hwnd hWndFrom;uint_ptr IDFrom;int Code;dword DrawStage;hwnd hDC;' & $tagRECT & ';dword_ptr ItemSpec;uint ItemState;lparam ItemlParam'
 Local Const $STM_GETIMAGE = 0x0173

 Local $tNMCD = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
 Local $hWndFrom = DllStructGetData($tNMCD, 'hWndFrom')
 Local $iCode = DllStructGetData($tNMCD, 'Code')
 Local $DrawStage = DllStructGetData($tNMCD, 'DrawStage')
 Local $ItemSpec = DllStructGetData($tNMCD, 'ItemSpec')
 Local $hDC = DllStructGetData($tNMCD, 'hDC')
 Local $hPic, $aPos, $hMemDC, $hBitmap, $hPrev
 Local $iAbove, $iBeneath, $iBoxSize = 13
 For $i = 1 To $aTrnsChckBxs_DATA[0][0]
  If $hWndFrom = $aTrnsChckBxs_DATA[$i][$i_hCB_Row] Then
   Switch $iCode
    Case $NM_CUSTOMDRAW
     Switch $DrawStage
      Case $CDDS_PREPAINT
       $hPic = $aTrnsChckBxs_DATA[$i][$i_hPic_Row]
       $aPos = ControlGetPos($hWnd, '', $hWndFrom)

       If @error Then
        ExitLoop
       EndIf

       If $aPos[3] < $iBoxSize Then $iBoxSize = $aPos[3]
       $iAbove = Floor(($aPos[3] - $iBoxSize) / 2)
       $iBeneath = $iAbove + $iBoxSize

       $hMemDC = _WinAPI_CreateCompatibleDC($hDC)
       $hBitmap = _SendMessage($hPic, $STM_GETIMAGE, $IMAGE_BITMAP, 0)
       $hPrev = _WinAPI_SelectObject($hMemDC, $hBitmap)
       _WinAPI_BitBlt($hDC, 0, 0, $iBoxSize, $iAbove, $hMemDC, $aPos[0], $aPos[1], $SRCCOPY) ;field above checkbox
       _WinAPI_BitBlt($hDC, 0, $iBeneath, $iBoxSize, $iBeneath - $iAbove, $hMemDC, $aPos[0], $aPos[1] + $iBeneath, $SRCCOPY) ;field beneath checkbox
       _WinAPI_BitBlt($hDC, $iBoxSize, 0, $aPos[2] - $iBoxSize, $aPos[3], $hMemDC, $aPos[0] + $iBoxSize, $aPos[1], $SRCCOPY) ;CheckBox text field
       _WinAPI_SelectObject($hMemDC, $hPrev)
       _WinAPI_DeleteDC($hMemDC)
       Return $CDRF_DODEFAULT
     EndSwitch
   EndSwitch

   ExitLoop
  EndIf
 Next

 Return $GUI_RUNDEFMSG
EndFunc   ;==>_TrnsChckBx_WM_NOTIFY

Pour les détails c'est ici (à lire !) :
http://www.autoitscript.com/forum/topic ... t-checkbox


Edit :
... Maintenant, on peut aussi tricher (c.f.ma signature...)

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $Form1 = GUICreate("Mon programe", 631, 667, 213, 152)
GUICtrlCreatePic("fond.jpg", 0, 0, 700, 670)
[color=#FF0000]GUICtrlSetState(-1, $GUI_DISABLE)[/color]  ; <== pour que la checkbox soit active

Global $Button1 = GUICtrlCreateButton("Lancer   !", 296, 584, 129, 57, $WS_GROUP)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")

Global $Checkbox1 = GUICtrlCreateCheckbox("", 296, 286, [color=#FF0000]13, 13[/color])  ; <== la checkbox seule fait 13x13 px
[color=#FF0000]GUICtrlCreateLabel[/color](" Mozilla firefox", 315, 280, 209, 25)  ; <== triche 
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

GUISetState()

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
 EndSwitch
WEnd

Amuse-toi bien !

[TT22]

Essaye ça :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("", 200, 230, 213, 152)
GUICtrlCreatePic("fond.jpg", 0, 0, 700, 670)
GUICtrlSetState(-1, $GUI_DISABLE)

$Button1 = GUICtrlCreateButton("OK", 40, 150, 129, 57, $WS_GROUP)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")

$Checkbox1 = GUICtrlCreateCheckbox("", 10, 10, 13, 13)
GUICtrlCreateLabel("Checkbox1", 30, 5, 209, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$Checkbox2 = GUICtrlCreateCheckbox("", 10, 60, 13, 13)
GUICtrlCreateLabel("Checkbox2", 30, 55, 209, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$Checkbox3 = GUICtrlCreateCheckbox("", 10, 110, 13, 13)
GUICtrlCreateLabel("Checkbox3", 30, 105, 209, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Comic Sans MS")
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

GUISetState()

While 1
 $Msg = GUIGetMsg()
 Switch $Msg
  Case $GUI_EVENT_CLOSE
   Exit
   Case $Button1
    $msg1  = GUICtrlRead($Checkbox1)
    $msg2  = GUICtrlRead($Checkbox2)
    $msg3  = GUICtrlRead($Checkbox3)
       
       If $msg1 = 1 Then
           MsgBox(0,"","Checkbox1")
       EndIf
       If $msg2 = 1 Then
           MsgBox(0,"","Checkbox2")
       EndIf
       If $msg3 = 1 Then
           MsgBox(0,"","Checkbox3")
       EndIf
       
 EndSwitch
WEnd

[mikell]

Marrant... 2 solutions identiques envoyées à quelques minutes d'intervalle

[TT22]

Ouai

[Pandora]

Merci bien je passe en résolue merci de votre rapidité