[R] Blocage Case

ThESeRvEuR · #1

Bonjour à tous,

Voilà, je rencontre un petit problème.
J'ai développé une GUI avec différents onglets, des groupes, des boutons, .... qui regroupe tous les outils, logiciels dont j'ai besoin au quotidien.

Par contre, mon problème concerne juste une partie du code :

Code : Tout sélectionner

Case $Button_MSRA
        If Ping (GUICtrlRead($Combo_Liste)) Then
            If _RunDos ("msra.exe /offerRA " & GUICtrlRead($Combo_Liste)) Then ExitLoop
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le PMF " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

Lorsque je lance ce bouton, MSRA se lance correctement sur le PC que j'ai sélectionné dans ma combo list, par contre, pour pouvoir cliquer sur un autre bouton, je dois obligatoirement ferme MSRA. Je ne comprends pas trop pourquoi, étant donné que c'est le seul bouton qui me pose problème.

J'ai bien essayé d'intégrer ContinueCase ou Exitloop, mais rien n'y fait....

Avez-vous une idée ? (Je suis certain qui oui)

Merci d'avance,

#2

Bonjour,
Pouvez-vous fournir le code complet pour reproduction ?

Merci.

ThESeRvEuR · #3

Ci-joint le code complet, c'est en cours, donc tout n'est pas encore clean et je suis certain qu'il peut y avoir des simplifications à faire (si quelqu'un veut participer) :

► Afficher le texte

Code : Tout sélectionner

#include <File.au3>
#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <Process.au3>

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=\Form1.kxf
Global $Form1 = GUICreate("Version 1", 1186, 660, 266, 0)
GUISetFont(10, 400, 0, "Calibri")
GUISetBkColor(0xFFFFFF)
Global $Onglets = GUICtrlCreateTab(8, 200, 1169, 450)
GUICtrlSetFont($Onglets, 10, 400, 0, "Calibri")

Global $Serveurs = GUICtrlCreateTabItem("Gestion Des Serveurs")
Global $Habilitations         = GUICtrlCreateButton("Fichier de suivi des habilitations", 147, 336, 200, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlSetState($Serveurs,$GUI_SHOW)

Global $Group_ADN             = GUICtrlCreateGroup("Active Directory", 405, 241, 370, 125)
Global $ADN                   = GUICtrlCreateButton("Connexion à l'AD", 547, 300, 170, 17)
Global $Pic_ADN               = GUICtrlCreatePic(@ScriptDir & "\Images\ADN.jpg", 442, 281, 60, 60)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_X   = GUICtrlCreateGroup(" ", 788, 241, 370, 125)
Global $X         = GUICtrlCreateButton(" ", 886, 300, 200, 17)
Global $X         = GUICtrlCreatePic(@ScriptDir & "\Images\Excel.jpg", 803, 281, 60, 60)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Somme = GUICtrlCreateGroup("Somme", 22, 371, 370, 125)
GUICtrlSetFont($Somme, 10, 400, 0, "Calibri")
Global $Connexion_80 = GUICtrlCreateButton("Connexion au serveur 55.12.13.16", 120, 391, 250, 17)
Global $TELEDIFF_80 = GUICtrlCreateButton("Modifier le fichier Diffusion.ini", 120, 416, 250, 17)
Global $Informatique_80 = GUICtrlCreateButton("Accès au répertoire Informatique", 120, 441, 250, 17)
Global $Serveur1 = GUICtrlCreatePic(@ScriptDir & "\Images\Serveur.jpg", 37, 400, 70, 70)
Global $Imprimantes_80 = GUICtrlCreateButton("Gèrer les imprimantes par PC", 120, 466, 250, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Laon = GUICtrlCreateGroup("Laon", 405, 371, 370, 125)
GUICtrlSetFont($Laon, 10, 400, 0, "Calibri")
Global $Connexion_021 = GUICtrlCreateButton("Connexion au serveur de 55.12.13.17", 503, 391, 250, 17)
Global $TELEDIFF_021 = GUICtrlCreateButton("Modifier le fichier Diffusion.ini", 503, 416, 250, 17)
Global $Informatique_021 = GUICtrlCreateButton("Accès au répertoire Informatique", 503, 441, 250, 17)
Global $Serveur2 = GUICtrlCreatePic(@ScriptDir & "\Images\Serveur.jpg", 420, 400, 70, 70)
Global $Imprimantes_021 = GUICtrlCreateButton("Gèrer les imprimantes par PC", 503, 466, 250, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $St_Quentin = GUICtrlCreateGroup("St-Quentin", 788, 371, 370, 125)
GUICtrlSetFont($St_Quentin, 10, 400, 0, "Calibri")
Global $Connexion_022 = GUICtrlCreateButton("Connexion au serveur 55.12.13.18", 886, 391, 250, 17)
Global $TELEDIFF_022 = GUICtrlCreateButton("Modifier le fichier Diffusion.ini", 886, 416, 260, 17)
Global $Informatique_022 = GUICtrlCreateButton("Accès au répertoire Informatique", 886, 441, 250, 17)
Global $Serveur3 = GUICtrlCreatePic(@ScriptDir & "\Images\Serveur.jpg", 803, 400, 70, 70)
Global $Imprimantes_022 = GUICtrlCreateButton("Gèrer les imprimantes par PC", 886, 466, 250, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)


Global $Utilisateurs    = GUICtrlCreateTabItem("Utilisateurs")

Global $Group_Liste     = GUICtrlCreateGroup("Liste des PC (la saisie manuelle reste possible)", 25, 240, 1120, 70)
Global $Combo_Liste     = GUICtrlCreateCombo("Sélectionnez le site sur lequel vous souhaitez intervenir ...", 45, 268, 1068, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL,$WS_VSCROLL))
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_MSRA      = GUICtrlCreateGroup("Assistance à distance via MSRA.exe", 25, 320, 260, 70)
Global $MSRA            = GUICtrlCreatePic(@ScriptDir & "\Images\MSRA.jpg", 45, 335, 50, 50)
Global $Button_MSRA     = GUICtrlCreateButton("Démarrer l'assistance", 125, 350, 135, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_MSTSC     = GUICtrlCreateGroup("Connexion Bureau à distance via MSTSC.exe", 25, 400, 260, 70)
Global $MSTSC           = GUICtrlCreatePic(@ScriptDir & "\Images\MSTSC.jpg", 45, 415, 50, 50)
Global $Button_MSTSC    = GUICtrlCreateButton("Valider la connexion", 125, 430, 135, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_Explorer_C    = GUICtrlCreateGroup("Connexion au Lecteur C:\ d'un PC", 25, 480, 260, 70)
Global $Pic_Explorer_C      = GUICtrlCreatePic(@ScriptDir & "\Images\EXPLORATEUR.jpg", 45, 495, 50, 50)
Global $Button_Explorer_C   = GUICtrlCreateButton("Explorateur du C:", 125, 510, 135, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_Explorer_D    = GUICtrlCreateGroup("Connexion au Lecteur D:\ d'un PC", 25, 560, 260, 70)
Global $Pic_Explorer_D      = GUICtrlCreatePic(@ScriptDir & "\Images\EXPLORATEUR.jpg", 45, 575, 50, 50)
Global $Button_Explorer_D   = GUICtrlCreateButton("Explorateur du D:", 125, 590, 135, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Group_GESTION   = GUICtrlCreateGroup("Gestion de l'Ordinateur à distance", 300, 320, 280, 70)
Global $Pic_GESTION     = GUICtrlCreatePic(@ScriptDir & "\Images\GESTION.jpg", 325, 335, 50, 50)
Global $Button_GESTION  = GUICtrlCreateButton("Connexion à l'ordinateur", 400, 350, 160, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)

Global $Logiciels       = GUICtrlCreateTabItem("Logiciels")

Global $Group_Logiciels = GUICtrlCreateGroup("Lanceur de Logiciels de gestion", 25, 240, 1130, 395)
Global $PIC_TOTAL       = GUICtrlCreatePic(@ScriptDir & "\Images\TNM.jpg", 45, 265, 25, 25)
Global $Button_TOTAL    = GUICtrlCreateButton("Total Network Monitor", 80, 270, 135, 17)
Global $PIC_WOL         = GUICtrlCreatePic(@ScriptDir & "\Images\WOL.jpg", 45, 295, 25, 25)
Global $Button_WOL      = GUICtrlCreateButton("Wake On Lan", 80, 300, 135, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateTabItem("")

Global $Mario = GUICtrlCreatePic(@ScriptDir & "\Images\mario-builder.jpg", 0, 0, 260, 196)
Global $Titre = GUICtrlCreateLabel("La boîte à Outils", 500, 72, 907, 37)
    GUICtrlSetFont($Titre, 20, 800, 0, "Calibri")
    GUICtrlSetColor($Titre, 0x800000)
    GUICtrlSetResizing($Titre, $GUI_DOCKHCENTER)
    GUISetState(@SW_SHOW)

#EndRegion ### END Koda GUI section ###

Global $DbName = "Db_PC.txt"

Dim $FileRead, $Data
Global $Form1, $Combo_Liste

_FileReadToArray($DbName, $FileRead)
$Data = _ArrayToString($FileRead, "|", 1)

GUICtrlSetData($Combo_Liste,$Data)
GUISetState(@SW_SHOW)

$SERVEUR_DWF = "55.12.13.16"
$SERVEUR_DGF = "55.12.13.17"
$SERVEUR_DFF = "55.12.13.18"
$FILE_TELEDIFF = "\Informatique\TELEDIFF\Diffusion.ini"

$CONNEXION_DIST = "C:\Windows\System32\mstsc.exe"
$CONNEXION_MSRA = "C:\Windows\System32\msra.exe /offerRA"
$EXCEL          = "C:\Program Files\Microsoft Office\Office14\EXCEL.exe"
$NOTEPAD        = "C:\Program Files\Notepad++\notepad++.exe"
$EXPLORER       = "C:\Windows\explorer.exe"
$TNM            = "C:\Program Files\Total Network Monitor\tnm.exe"
$WOL            = "C:\Program Files\Dipisoft\WakeOnLan\WakeOnLan.exe"

Global $Titre = GUICtrlCreateLabel("Gestion des serveurs : " & $SERVEUR_DFF & "/" & $SERVEUR_DGF & "/" & $SERVEUR_DWF, 500, 100, 907, 37)

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
;~ **************************************************************************************
;~ **************************************************************************************
     Case $Serveurs
;~ **************************************************************************************
;~ **************************************************************************************

     Case $ADN
        If FileExists ("C:\Windows\system32\dsa.msc") Then
            RunAs (InputBox ("Attention","Saississez votre Identifiant Administrateur", "", ""), "CNAMTS", InputBox ("Attention","Saisissez votre mot de passe Administrateur", "", "*"), 0, @ComSpec & ' /c "mmc %windir%\system32\dsa.msc"', "", @SW_HIDE)
     Else
            MsgBox(16, "Erreur", "Les Outils d’administration de serveur distant pour Windows 7 ne sont pas installés." & @CRLF & "Merci de les télécharger, de les installer et de réessayer.")
        EndIf

     Case $Habilitations
         If FileExists ($EXCEL) Then
             Run ($EXCEL & ' "\\' & $SERVEUR_DWF & '\Gestion Personnels + Habilitations + Locaux\Gestion des Agents-Praticiens-PC V2.0.xlsm"')
         Else
            MsgBox(16, "Erreur", "Microsoft Office 2010 n'est pas installé sur ce PC." & @CRLF & "Veuillez contacter votre support pour obtenir le fichier d'installation.")
         EndIf



     Case $Connexion_80
        If Ping ($SERVEUR_DWF) Then
            Run ($CONNEXION_DIST & " /v:" & $SERVEUR_DWF & " /f")
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le serveur " & $SERVEUR_DWF & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $TELEDIFF_80
        If FileExists ($NOTEPAD) Then
            If FileExists ("\\" & $SERVEUR_DWF & $FILE_TELEDIFF) Then
                Run ($NOTEPAD & " \\" & $SERVEUR_DWF & $FILE_TELEDIFF)
            Else
                MsgBox(16, "Erreur", "Le fichier Diffusion.ini n'a pas été trouvé." & @CRLF & "Contactez le support.")
            EndIf
        Else
            MsgBox(16, "Erreur", "Notepad++ n'est pas installé sur ce PC")
        EndIf

     Case $Informatique_80
        If FileExists ("\\" & $SERVEUR_DWF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DWF & "\Informatique\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

     Case $Imprimantes_80
        If FileExists ("\\" & $SERVEUR_DWF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DWF & "\Informatique\Telediff\IMPRIMANTES\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

     Case $Connexion_021
        If Ping ($SERVEUR_DGF) Then
            Run ($CONNEXION_DIST & " /v:" & $SERVEUR_DGF & " /f")
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le serveur " & $SERVEUR_DGF & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $TELEDIFF_021
        If FileExists ($NOTEPAD) Then
            If FileExists ("\\" & $SERVEUR_DGF & $FILE_TELEDIFF) Then
                Run ($NOTEPAD & " \\" & $SERVEUR_DGF & $FILE_TELEDIFF)
            Else
                MsgBox(16, "Erreur", "Le fichier Diffusion.ini n'a pas été trouvé." & @CRLF & "Contactez le support.")
            EndIf
        Else
            MsgBox(16, "Erreur", "Notepad++ n'est pas installé sur ce PC")
        EndIf

     Case $Informatique_021
        If FileExists ("\\" & $SERVEUR_DGF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DGF & "\Informatique\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

     Case $Imprimantes_021
        If FileExists ("\\" & $SERVEUR_DGF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DGF & "\Informatique\Telediff\IMPRIMANTES\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

     Case $Connexion_022
        If Ping ($SERVEUR_DFF) Then
            Run ($CONNEXION_DIST & " /v:" & $SERVEUR_DFF & " /f")
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le serveur " & $SERVEUR_DFF & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $TELEDIFF_022
        If FileExists ($NOTEPAD) Then
            If FileExists ("\\" & $SERVEUR_DFF & $FILE_TELEDIFF) Then
                Run ($NOTEPAD & " \\" & $SERVEUR_DFF & $FILE_TELEDIFF)
            Else
                MsgBox(16, "Erreur", "Le fichier Diffusion.ini n'a pas été trouvé." & @CRLF & "Contactez le support.")
            EndIf
        Else
            MsgBox(16, "Erreur", "Notepad++ n'est pas installé sur ce PC")
        EndIf

     Case $Informatique_022
        If FileExists ("\\" & $SERVEUR_DFF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DFF & "\Informatique\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

     Case $Imprimantes_022
        If FileExists ("\\" & $SERVEUR_DFF & $FILE_TELEDIFF) Then
            Run ($EXPLORER & " \\" & $SERVEUR_DFF & "\Informatique\Telediff\IMPRIMANTES\")
        Else
            MsgBox(16, "Erreur", "Le répertoire 'Informatique' n'a pas été trouvé." & @CRLF & "Contactez le support.")
        EndIf

;~ **************************************************************************************
;~ **************************************************************************************
     Case $Utilisateurs
;~ **************************************************************************************
;~ **************************************************************************************

     Case $Button_MSRA
        If Ping (GUICtrlRead($Combo_Liste)) Then
            If _RunDos ("msra.exe /offerRA " & GUICtrlRead($Combo_Liste)) Then ExitLoop
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le PC " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $Button_MSTSC
        If Ping (GUICtrlRead($Combo_Liste)) Then
            Run ($CONNEXION_DIST & " /v:" & GUICtrlRead($Combo_Liste))
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le PC " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $Button_Explorer_C
        If Ping (GUICtrlRead($Combo_Liste)) Then
            Run ($EXPLORER & " \\" & GUICtrlRead($Combo_Liste) & "\C$")
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le PC " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf
     Case $Button_Explorer_D
        If Ping (GUICtrlRead($Combo_Liste)) Then
            Run ($EXPLORER & " \\" & GUICtrlRead($Combo_Liste) & "\D$")
        Else
            MsgBox(16, "Erreur", "Impossible de joindre le PC " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

     Case $Button_GESTION
        If Ping (GUICtrlRead($Combo_Liste)) Then
            _RunDos ("mmc compmgmt.msc /computer:\\" & GUICtrlRead($Combo_Liste))
     Else
            MsgBox(16, "Erreur", "Impossible de joindre le PC " & GUICtrlRead($Combo_Liste) & @CRLF & "Vérifiez votre connexion réseau ou contactez le support.")
        EndIf

;~ **************************************************************************************
;~ **************************************************************************************
     Case $Logiciels
;~ **************************************************************************************
;~ **************************************************************************************

     Case $Button_TOTAL
        If FileExists ($TNM) Then
            Run ($TNM)
        Else
            MsgBox(16, "Erreur", "Total Network Monitor n'est pas installé sur ce PC")
        EndIf

     Case $Button_WOL
        If FileExists ($WOL) Then
            Run ($WOL)
        Else
            MsgBox(16, "Erreur", "Wake On Lan n'est pas installé sur ce PC")
        EndIf

 EndSwitch
WEnd

#4

_RunDos est "bloquant", il faudra utiliser Run plutôt.

_RunDos a écrit :Remarks
The script waits until the command has been executed.

Le ExitLoop ajouté ne sert à rien.

ThESeRvEuR · #5

Oui j'ai vu, j'ai déjà supprimé le exitloop ...
J'ai bien essayé de passer par Run avec le code suivant, mais cela ne fonctionne pas, MSRA ne se lance pas ....

Code : Tout sélectionner

Run ("C:\Windows\System32\msra.exe /offerRA " & GUICtrlRead($Combo_Liste))

La seule fonction que j'ai trouvé pour est _RunDos ...

#6

Bonjour,
Et comme cela ?

Code : Tout sélectionner

ShellExecute("msra.exe", "/offerRA " & GUICtrlRead($Combo_Liste))

#7

Avec ShellExecute c'est bon pour moi mais pourquoi ça ne fonctionne pas avec Run par contre ?
Visiblement si le script s'exécute en 64 bits, Run() n'arrive pas à exécuter la version 64 bits de MSRA. C'est normal ça ??!

Ces histoires de bits ça m'a toujours perturbé.

Code : Tout sélectionner

#AutoIt3Wrapper_UseX64=y
#include <WinAPI.au3>
Run(@WindowsDir & "\System32\msra.exe")
ConsoleWrite(_WinAPI_GetLastErrorMessage() & @CRLF) ; retourne "L’opération demandée nécessite une élévation."

ThESeRvEuR · #8

Re,

Je testerais ça au boulot demain, mais il me semble que j'avais testé ShellExecute .... Mais parfois ma mémoire flanche

Pour l'histoire du 64 bits, mon script tourne des systèmes 32 bits ....

ThESeRvEuR · #9

De retour ce matin, le ShellExecute fonctionne très bien, j'étais pourtant persuadé l'avoir testé, désolé d'avoir pris votre temps pour si peu.... et merci à vous !

Si vous avez des idées de simplification du script, je suis preneur par contre

AutoIt Français

[R] Blocage Case

[R] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case

Re: [..] Blocage Case