[R] GUICtrlCreatePic + création d'un point en mouvement

[cortexx]

Bonjour,

Après de multiple recherche et de test, je ne parviens pas à résoudre un problème et j'en appel à votre aide.
Je cherche à créer un point qui se déplace sur une image (pour sa pas de problème), le soucis c'est quand le point se déplace il reste des résidus de sont passage.
J'avais résolu en partie le problème en actualisant l'image avec le point se déplacent. Mais le problème c'est que j'ai d'autres points (cela fixe) qui disparaisse et sa me dérange de les redessiner à chaque fois (vu le nombre sa prend beaucoup trop de ressource et sa deviens très lent).

Je pense que le mieux serait d'avoir l'image en arrière plan (background) et de désiner le ou les point sur une espèce de calque.
Voici un bout de code amènagé pour visualisé mon problème, il vous faut juste ajouter une image de 1024 x 768 (nommé : Plan.jpg) dans le même dossier que le fichier Au3.

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)

Global $GUI, $Count = 0, $background

$GUI = GUICreate("Plan", 1024, 768)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowClose")

$background = GUICtrlCreatePic("Plan.jpg", 0, 0, 1024, 768)

GUISetState()

AdlibRegister('_RefreshDot', 500)

While 1
    Sleep(100)
WEnd

Func _RefreshDot()
    _GDIPlus_Startup()
    Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($GUI)
    Local $Brush = _GDIPlus_BrushCreateSolid(0xFFFF0000)
    Local $Pen = _GDIPlus_PenCreate(0xFFFFFFFF)
    Local $X = 100 + $Count
    Local $Y = 100 + $Count
    _GDIPlus_GraphicsFillEllipse($hGraphic, $X, $Y, 6, 6, $Brush)
    _GDIPlus_GraphicsDrawEllipse($hGraphic, $X, $Y, 6, 6, $Pen)
    _GDIPlus_Shutdown()
    $Count += 1
EndFunc

Func WindowClose()
    Exit
EndFunc

[Iste]

Vous n'avez effectivement pas le choix de tout repeindre. (voir tout les tutos du site du zéro sur tout ce qui touche aux sujet)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)

Global $GUI, $Count = 0, $background

$GUI = GUICreate("Plan", 1024, 768)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowClose")

$background = GUICtrlCreatePic("Plan.jpg", 0, 0, 1024, 768)

GUISetState()

AdlibRegister('_RefreshDot', 50)

While 1
    Sleep(100)
WEnd

Func _RefreshDot()
    _GDIPlus_Startup()
    Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($GUI)
    Local $Brush = _GDIPlus_BrushCreateSolid(0xFFFF0000)
    Local $bgBrush = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
    Local $Pen = _GDIPlus_PenCreate(0xFFFFFFFF)
    Local $X = 100 + $Count
    Local $Y = 100 + $Count

    _GDIPlus_GraphicsFillRect($hGraphic, 0, 0, 1024, 768, $bgBrush)

    _GDIPlus_GraphicsFillEllipse($hGraphic, $X, $Y, 6, 6, $Brush)
    _GDIPlus_GraphicsDrawEllipse($hGraphic, $X, $Y, 6, 6, $Pen)
    _GDIPlus_Shutdown()
    $Count += 1
EndFunc

Func WindowClose()
    Exit
EndFunc

il serait également de bon gout d'appeler les fonctions xxxDispose sur vos objets.

Pour le scintillement, voir du coté du double buffering. Comme c'est un sujet tres lourdement abordé sur la toile et que AutoIt n'est pas orienté pour ce genre de code, je vous laisse vous informer sur google pour plus d'info.

[cortexx]

Merci pour c'est précision, je vais faire mes recherches dans la direction que tu ma proposé.

Par contre tu a mise à jour le mon code et je l'ai testé, mais l'image de fond n'apparait pas .... normal ?

[Iste]

Oui c'est normal, ayant testé cela vite fait au boulot je n'ai meme pas remarqué l'image ^^' (qui ne s'affiche pas n'étant pas présente sur mon pc)

Pour cela, il vous faudra redessiner votre image, soit en updatant l'objet créé par GUICtrlCreatePic (a tester) soit en dessinant directement l'image grace a gdi+

[mikell]

C'est un poil hors-sujet concernant le script posté, mais en plein dedans pour le titre du sujet

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GDIPlus.au3>     
#include <Memory.au3>   

Opt("GUIOnEventMode", 1)

Global $GUI, $background, $X = 100, $Y = 100

$GUI = GUICreate("Plan", 1024, 768)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowClose")
$background = GUICtrlCreatePic("Plan.jpg", 0, 0, 1024, 768)
GUICtrlSetState(-1, $GUI_DISABLE)

$hHBITMAP = Load_BMP_From_Mem(point_gif(), True)  
$point = GUICtrlCreatePic("", 100, 100, 10, 10)
_WinAPI_DeleteObject(GUICtrlSendMsg($point, 0x0172, 0, $hHBITMAP)) 
_WinAPI_DeleteObject($hHBITMAP) 

GUISetState()

AdlibRegister('_RefreshDot', 50)

While 1
    Sleep(100)
WEnd

Func _RefreshDot()
    $X += 1
    $Y += 1
    GUICtrlSetPos($point, $X, $Y) 
EndFunc

Func WindowClose()
    Exit
EndFunc


Func Load_BMP_From_Mem($bImage, $hHBITMAP = False)
    If Not IsBinary($bImage) Then Return SetError(1, 0, 0)
    Local $declared = True
    If Not $ghGDIPDll Then
        _GDIPlus_Startup()
        $declared = False
    EndIf
    Local Const $memBitmap = Binary($bImage) ;load image  saved in variable (memory) and convert it to binary
    Local Const $len = BinaryLen($memBitmap) ;get length of image
    Local Const $hData = _MemGlobalAlloc($len, $GMEM_MOVEABLE) ;allocates movable memory  ($GMEM_MOVEABLE = 0x0002)
    Local Const $pData = _MemGlobalLock($hData) ;translate the handle into a pointer
    Local $tMem = DllStructCreate("byte[" & $len & "]", $pData) ;create struct
    DllStructSetData($tMem, 1, $memBitmap) ;fill struct with image data
    _MemGlobalUnlock($hData) ;decrements the lock count  associated with a memory object that was allocated with GMEM_MOVEABLE
    Local $hStream = DllCall("ole32.dll", "int", "CreateStreamOnHGlobal", "handle", $pData, "int", True, "ptr*", 0)
    $hStream = $hStream[3]
    Local $hBitmap = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromStream", "ptr", $hStream, "int*", 0) ;Creates a Bitmap object based on an IStream COM interface
    $hBitmap = $hBitmap[2]
    Local Const $tVARIANT = DllStructCreate("word vt;word r1;word r2;word r3;ptr data; ptr")
    DllCall("oleaut32.dll", "long", "DispCallFunc", "ptr", $hStream, "dword", 8 + 8 * @AutoItX64, _
            "dword", 4, "dword", 23, "dword", 0, "ptr", 0, "ptr", 0, "ptr", DllStructGetPtr($tVARIANT)) ;release memory from $hStream to avoid memory leak
    $tMem = 0
    If $hHBITMAP Then
        Local Const $hHBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
        _GDIPlus_BitmapDispose($hBitmap)
        If Not $declared Then _GDIPlus_Shutdown()
        Return $hHBmp
    EndIf
    If Not $declared Then _GDIPlus_Shutdown()
    Return $hBitmap
EndFunc   ;==>Load_BMP_From_Mem


Func point_gif()
   Local _
   $FileBin = "0x4749463839610A000A00F70000EF0800FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF"
   $FileBin &= "FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF"
   $FileBin &= "FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF"
   $FileBin &= "FFFFFFFFFFFFFFFFFFFFFFFFFFFF21F90401000001002C000000000A000A0000082000030804401080C0810513224C483000C38710234A64E810E2428A07150A0C08003B"
   Return Binary($FileBin)
EndFunc

[cortexx]

Merci à vous deux, vous m'avez donné deux pistes qui sont prometeuses.
Je vais faire des recherches plus avancé dans le GDI+ et j'ai testé ton code mikell sa fonctionne bien (mis à part un léger cintillement du point .. pas grave), je vais aussi m'en inpiré pour finir mon code.

PS : je vois que je peux compter sur la communauté AutoIT Fr pour trouver de bonne idée