[R] Problème plusieurs couleurs dans listview

[DDleroutier]

[R] Bonjour,

Je suis un peu novice avec autoit et j'aimerais afficher un résultat dans un Listview,
mais en même temps mettre en évidence certaines "cellules".

Voici le code sur lequel je travaille et qui "marchotte". Cependant quand je sélectionne
une ligne, la fenêtre se rafraichit automatiquement et mes cellules rouges redeviennent
noire. Quand je fais sortir la fenêtre de l'écran et que je la ramène au centre du bureau,
j'ai le même soucis.

Voici le code: si vous avez des idées ou une facon de faire qui fonctionne nettement mieux !?

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GUIConstants.au3>

Global $Form = GUICreate("Form", 1024, 438, 400, 124)
Global $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
Global $ListView = GUICtrlCreateListView("", 16, 8, 950, 417, -1,BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
 _GUICtrlListView_SetExtendedListViewStyle($ListView, $exStyles)

_GUICtrlListView_AddColumn(-1, "Application", 100,0)
_GUICtrlListView_AddColumn(-1, "Nom de fichier", 100,0)
_GUICtrlListView_AddColumn(-1, "Etat", 100,0)
_GUICtrlListView_AddColumn(-1, "Version", 100,0)
_GUICtrlListView_AddColumn(-1, "Date", 100,0)
_GUICtrlListView_AddColumn(-1, "Poids", 100,0)
_GUICtrlListView_AddColumn(-1, "Adresse IP", 100,0)
_GUICtrlListView_AddColumn(-1, "Statut", 100,0)
_GUICtrlListView_AddColumn(-1, "Hostname", 100,0)

GUISetState(@SW_SHOW)

;~ _GUICtrlListView_BeginUpdate($ListView)
Remplir()
;~ _GUICtrlListView_EndUpdate($ListView)

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit


  Case $Form
  Case $ListView
 EndSwitch
WEnd

Func Remplir()
    _GUICtrlListView_AddItem($ListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 2", 1)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 3", 2)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 4", 3)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 5", 4)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 6", 5)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 7", 6)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 8", 7)
    _GUICtrlListView_AddSubItem($ListView, 0, "Row 1: Col 9", 8)

    _GUICtrlListView_AddItem($ListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 3", 2)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 4", 3)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 5", 4)
        GUICtrlSetColor($ListView,0xff0000)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 6", 5)
        GUICtrlSetColor($ListView,0x000000)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 7", 6)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 8", 7)
    _GUICtrlListView_AddSubItem($ListView, 1, "Row 2: Col 9", 8)

    _GUICtrlListView_AddItem($ListView, "Row 3: Col 1", 2)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 2", 1)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 3", 2)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 4", 3)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 5", 4)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 6", 5)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 7", 6)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 8", 7)
    _GUICtrlListView_AddSubItem($ListView, 2, "Row 3: Col 9", 8)
EndFunc
 

[jbnh]

Règles de présentation d'un message svp

http://www.autoitscript.fr/forum/viewforum.php?f=35

[DDleroutier]

[R] re bonjour,

Je cherche , je gratte et je crois avoir trouver une solution à mon problème. J'ai très légèrement
modifier le script pour faire voir les possiblités.

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FontConstants.au3>
#include <WinAPI.au3>

Global $Font1 = _WinAPI_CreateFont(14, 6, 0, 0, $FW_BOLD)
Global $Font2 = _WinAPI_CreateFont(14, 6, 0, 0, $FW_BOLD, True)

$hGUI = GUICreate("Test", 300, 200)

$hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems", 10, 10, 280, 180, $LVS_REPORT, $WS_EX_CLIENTEDGE)

_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
_GUICtrlListView_BeginUpdate($hListView)
For $i = 1 To 10
    _GUICtrlListView_AddItem($hListView, "Item" & $i)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem" & $i, 1)
Next
_GUICtrlListView_EndUpdate($hListView)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_WinAPI_DeleteObject($Font1)
_WinAPI_DeleteObject($Font2)

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)

                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")

                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW

                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")

                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")

                    Local $iColor, $hDC
                     $hDC = DllStructGetData($tCustDraw, "hdc")
                    Switch $iItem
                         Case 2


                            If $iSubItem = 0 Then
                                $iColor = 0xFF4466
;~                                 _WinAPI_SelectObject($hDC, $Font1)
                            Else
                                $iColor = 0x5555DD
;~                                 _WinAPI_SelectObject($hDC, $Font2)
                            EndIf
;~                          MsgBox(48,"",$tCustDraw)
                            DllStructSetData($tCustDraw, "clrTextBk", $iColor)
                            Return $CDRF_NEWFONT
                        Case 5


                            If $iSubItem = 0 Then
                                $iColor = 0xFF4466
                                _WinAPI_SelectObject($hDC, $Font1)
                            Else
                                $iColor = 0x5555DD
                                _WinAPI_SelectObject($hDC, $Font2)
                            EndIf
;~                          MsgBox(48,"",$tCustDraw)
                            DllStructSetData($tCustDraw, "clrText", $iColor)
                            Return $CDRF_NEWFONT
                        Case 8


                            If $iSubItem = 0 Then
                                $iColor = 0xFF4466
                                _WinAPI_SelectObject($hDC, $Font1)
                            Else
                                $iColor = 0x5555DD
                                _WinAPI_SelectObject($hDC, $Font2)
                            EndIf

                            DllStructSetData($tCustDraw, "clrText", $iColor)



                            Return $CDRF_NEWFONT
                    EndSwitch
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY