[R] Centrer le texte de bouton + tailles bouton variable.

[satanico64]

Bonsoir mssieurs dames,

Suite a une précédente intervention ICI, je suis un train de refaire une barre d'outil a l'aide des commandes _GUICtrlToolbar_Create, _GUICtrlToolbar_AddButton etc...

Déjà un premier étonnement la dessus, je suis très étonne de trouver si peu d'info sur les _GUICtrlToolbar_Create dans les forums, peu utilisé ?
Je précise que je souhaite une barre dont les boutons ne sont pas des images, mais juste du texte.
Et tous les exemples trouvés sur les forums concernent des boutons-images.

Je vous livre l'ebauche pseudo-fonctionnelle, du code:

► Afficher le texte

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiButton.au3>
#include <StaticConstants.au3>
#include <file.au3>
#include <EditConstants.au3>
#Include <GuiEdit.au3>
#Include <Misc.au3>
#include <GuiListView.au3>
#Include <GuiToolBar.au3>
#Include <GuiImageList.au3>

Opt('MustDeclareVars', 0)
Opt("GUIOnEventMode", 1)
Opt("trayicondebug", 1)

Global $principal, $msg, $ajudaitem2, $ajudaitem1, $sairitem, $menu, $ajuda, $iItem,$hzonetexte

Global $astring[4]
Global Enum $job = 500, $edit, $del, $clone

$principal = GUICreate("Jobs", 600, 55, -1, -1,$WS_POPUP , BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
;$principal = GUICreate("Jobs", 600, 40)
$hzonetexte = GUICtrlCreateEdit("plop c'est moi le texte",-1,-1,600,15)
GUICtrlSetFont($hzonetexte, 6, 400, 0, "Courier New")
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
;_GUICtrlToolbar_GetMaxSize
local $iStyle,$iString,$NEW,$NEW2,$NEW3,$sText,$phrases[4], $hToolbar

; creation de la barre
$htoolbar = _GUICtrlToolbar_Create ($principal,$ES_CENTER )
_GUICtrlToolbar_SetStyle($htoolbar,bitor($TBSTYLE_ALTDRAG,$TBSTYLE_TOOLTIPS))
;_GUICtrlToolbar_SetStyle($htoolbar,$TBSTYLE_TOOLTIPS)
_GUICtrlToolbar_SetExtendedStyle($htoolbar,bitor($TBSTYLE_EX_MIXEDBUTTONS,$ES_CENTER) )
; Les phrases de la toolbar
$phrases[0] = _GUICtrlToolbar_AddString($hToolbar, "New")
$phrases[1] = _GUICtrlToolbar_AddString($hToolbar, "&phrase 2")
$phrases[2] = _GUICtrlToolbar_AddString($hToolbar, "&phrase 3 tres longue")
$phrases[3] = _GUICtrlToolbar_AddString($hToolbar,"texte1")

; ajout des boutons
_GUICtrlToolbar_AddButton($htoolbar,$NEW,-2,$phrases[0] )
_GUICtrlToolbar_SetButtonStyle($htoolbar,$NEW,$BTNS_AUTOSIZE)
; _GUICtrlToolbar_SetMaxTextRows($hToolbar, 2)
;_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($htoolbar,$NEW2,-2,$phrases[1] )
_GUICtrlToolbar_SetButtonStyle($htoolbar,$NEW2,$BTNS_SHOWTEXT)
_GUICtrlToolbar_AddButton($htoolbar,$NEW3,-2,$phrases[2] )
_GUICtrlToolbar_AddButtonSep($hToolbar)
;~ $joblist = GUICtrlCreateListView("Name|Time|Repeat|Status", 10, 70, 330, 103, -1, 0x00000025)

;GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

GUISetState()


While 1
Sleep(10)
WEnd

Func quit()
Exit
EndFunc

En gros ce qui est utile commence sous :
; creation de la barre
J'ai laissé des commentaires et ne vous inquietez pas sur tous les includes ils concernent d'autres implémentations

Et maintenant, mes 2 problèmes probablement tout simples:
1 comment center le texte de mes boutons ? (verticalement et horizontalement)
2 Comment avoir des boutons de taille différentes ? $BTNS_AUTOSIZE ne donne rien (je ne dois pas m'en servir correctement).
Ma solution ultime sera peut être de créer des gifs a partir du texte de mes boutons, ceux ci devant être fixe et des toolbars comme ça j'en ai vu quelques une et super bien faites.

En vous remerciant.
Nicolas.

[Tlem]

Votre titre n'est pas conforme.

[TopXm]

Hello

Vu que ce ne sont que des boutons textes dans une toolbar pourquoi tu ne créés pas du coup des boutons directement, plutôt qu'une toolbar où tu vas galérer ?
Bon j'avoue je cherche toujours la facilité

► Afficher le textebuttons

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

GUICreate("Jobs", 600, 82, -1, -1, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))

; Trait de la toolbar
GUICtrlCreateLabel("", 0, 50, 600, 1, $SS_SUNKEN)
GUICtrlCreateLabel("", 0, 51, 600, 1, $SS_WHITEFRAME)
;Boutons 
$hButton1 = GUICtrlCreateButton("New", 1, 52, 50, 30, $BS_MULTILINE)
$hButton2 = GUICtrlCreateButton("&phrase 2", 50, 52, 80, 30, $BS_MULTILINE)
$hButton3 = GUICtrlCreateButton("&phrase 3 tres longue", 129, 52, 120, 30, $BS_MULTILINE)
$hButton4 = GUICtrlCreateButton("texte1", 248, 52, 70, 30, $BS_MULTILINE)

GUISetState()


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

[satanico64]

salut,

en fait ma je crée une toolbar avec x boutons. Mes utilisateurs, pourront les désactiver ou non (par exemple pour des boutons inutiles pour eux).

Donc en gros je cherche à pouvoir redessiner ma barre, une fois un bouton désactivé (ou activé).
Et si je dois préciser les coordonnées x,y du bouton ça va pas le faire.
Surtout pour la taille de mon gui principal

Je sais que c'est faisable avec :

$htoolbar = _GUICtrlToolbar_Create ($principal)
_GUICtrlToolbar_AddButton($hToolbar, $NEW,1)
_GUICtrlToolbar_DeleteButton(...

(mais voit la galère ! je bataille dessus depuis 2 semaines, c'est pas simple pour moi de piger les _wm_notify() ou my_wm_command()

Sinon si vous avez des outils 'natifs' autoit pour créer une barre ou je peux simplement enlever/ajouter des boutons et redessiner mon gui, je prend !

enfin voila quoi !

ps: j'ai en fait un code actuellement en place est basé simplement sur des GUICtrlCreateButton et très fonctionnel, mais bon il est figé sur x boutons qui ne bougent pas. Et je veux pouvoir ajouter/supprimer des boutons. D'ou mes recherches la dessus.

[Alaghir]

De toute façon, si tu veux créer un bouton de manière dynamique, il te faudra préciser ses coordonnées.

Tu peux récupérer les données du dernier bouton existant, et jouer avec en y rajoutant l'espace que tu souhaites.

ça te donne une formule du style :

$x2 = $x1 + $l1 + $esp

avec : $x2 la position x du bouton que tu veux créer, $x1 la position x du dernier bouton de ta barre, $l1 la taille horizontale de ce bouton, et $esp l'espace que tu comptes mettre entre chaque bouton.


Je ne suis pas assez expert sur AutoIt pour te pondre un code de but en blanc, mais je pense qu'avec cette méthode tu devrais pouvoir t'en sortir .

Pour ce qui est de la taille de ta fenêtre c'est un petit peu la même chose :
$fl = $x2 + $l2 + $bord

$fl est la largeur de ta fenêtre, $x2 la position x de ton dernier controle, $l2 la longueur de ton dernier controle, $bord l'espace que tu souhaites mettre entre ton dernier contrôle et le bout horizontal de la barre d'outil.

Voilà pour la méthode je dirai . J'essaierai de voir ce soir si le temps que j'aie me le permet comment procéder en autoit .

[mikell]

Voilà un exemple de pseudo-toolbar construite juste avec des machins compréhensibles
Dans l'array de départ tu ne définis pour chaque bouton que le texte et la fonction à exécuter
La taille du bouton est ajustée automatiquement
Clic droit => tu peux enlever ou remettre les boutons
Ce code est très souple et facilement adaptable

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; #include <Array.au3>
#include <WinAPI.au3>

Dim $boutons[5][7] = [[0, "Exit", "_Exit", 0, 0, 0, 0], [0, "OK", "_OK", 0, 0, 0, 0], _ 
            [0, "Enregistrer", "_Enregistrer", 0, 0, 0, 0], [0, "Tester", "_Tester", 0, 0, 0, 0], _ 
            [0, "Lire le journal du Dimanche", "_Newspapa", 0, 0, 0, 0]]
; 0 id ; 1 texte ; 2 fonction ; 3 left pos ; 4 largeur ; 5 menuitem ajouter ; 6 menuitem enlever 

$gui = GUICreate("my_amazing_toolbar", 0, 40, -1, -1, $WS_POPUP)
For $i = 0 To UBound($boutons) - 1
    $boutons[$i][4] = _GetZeSizeOfZisText($boutons[$i][1])
    If $i = 0 Then
        $boutons[$i][3] = 0
    Else
        $boutons[$i][3] = $boutons[$i - 1][3] + $boutons[$i - 1][4]
    EndIf
    $guipos1 = WinGetPos($gui)
    WinMove($gui, "", $guipos1[0], $guipos1[1], $guipos1[2] + $boutons[$i][4])
    $boutons[$i][0] = GUICtrlCreateButton($boutons[$i][1], $boutons[$i][3], 15, $boutons[$i][4], 25)
    GUICtrlSetBkColor($boutons[$i][0], 0xbadaff)
    GUICtrlSetResizing($boutons[$i][0], 256 + 512 + 2)
    $context = GUICtrlCreateContextMenu($boutons[$i][0])
    $boutons[$i][5] = GUICtrlCreateMenuItem("Ajouter", $context)
    $boutons[$i][6] = GUICtrlCreateMenuItem("Enlever", $context)
Next
$label = GUICtrlCreateLabel(" ici y en avoir du texte", 0, 0, 1000, 15, 0x1200, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, 0xffffff)
GUICtrlSetFont(-1, 8, 400, 0, "Courier New")
GUICtrlSetResizing($label, 1)
GUICtrlSetState($label, $GUI_FOCUS)
GUISetState()

;_ArrayDisplay($boutons)


While 1
$msg = GUIGetMsg()

For $i = 0 To UBound($boutons) - 1
    Switch $msg
        Case $boutons[$i][0]        ; actions
            Call($boutons[$i][2])
            GUICtrlSetState($label, $GUI_FOCUS)

        Case $boutons[$i][6]        ; menu enlever
            If $boutons[$i][1] <> "Exit" Then
                $decal = $boutons[$i][4] ;size
                $guipos = WinGetPos($gui)
                WinMove($gui, "", $guipos[0], $guipos[1], $guipos[2] - $decal)
                For $j = $i + 1 To UBound($boutons) - 1
                    $boutons[$j][3] = $boutons[$j][3] - $decal
                    ControlMove($gui, "", $boutons[$j][0], $boutons[$j][3], 15)
                    GUICtrlSetResizing($boutons[$j][0], 256 + 512 + 2)
                Next
                GUICtrlSetState($boutons[$i][0], $GUI_HIDE)
                ExitLoop
            EndIf

        Case $boutons[$i][5]        ; menu ajouter
            $gui2 = GUICreate("titre", 120, 80, -1, -1, $WS_POPUP)
            GUISetBkColor(0xbadaff)
            $itext = GUICtrlCreateCombo("OK", 10, 10, 100, 18)
            For $i = 2 To UBound($boutons) - 1
                GUICtrlSetData($itext, $boutons[$i][1] & "|")
            Next
            $ibtn = GUICtrlCreateButton("OK", 10, 40, 40, 25)
            $iexit = GUICtrlCreateButton("Annuler", 60, 40, 50, 25)
            GUISetState()
            While 1
            $msg2 = GUIGetMsg()
                Switch $msg2
                    Case $iexit
                        GUIDelete($gui2)
                        ExitLoop
                    Case $ibtn        ; ok
                        $itexte = GUICtrlRead($itext)
                        GUIDelete($gui2)
                        For $i = 0 To UBound($boutons) - 1
                           If $itexte = $boutons[$i][1] Then
                            If BitAND(GUICtrlGetState($boutons[$i][0]), $GUI_SHOW) = $GUI_SHOW Then
                                ExitLoop 2
                            Else
                                GUICtrlSetState($boutons[$i][0], $GUI_SHOW)
                                ExitLoop
                            EndIf
                           EndIf
                        Next
                        $guipos2 = WinGetPos($gui)
                        WinMove($gui, "", $guipos2[0], $guipos2[1], $guipos2[2] + $boutons[$i][4])
                        For $j = $i + 1 To UBound($boutons) - 1
                            $boutons[$j][3] += $boutons[$i][4]
                            ControlMove($gui, "", $boutons[$j][0], $boutons[$j][3], 15)
                            GUICtrlSetResizing($boutons[$j][0], 256 + 512 + 2)
                        Next
                        _WinAPI_RedrawWindow($gui) 
                        ExitLoop
                EndSwitch
            WEnd
            $msg = ""
        EndSwitch
    Next
WEnd


Func _GetZeSizeOfZisText($mytext)
    $hDC = _WinAPI_GetDC($gui)
    $tSize = _WinAPI_GetTextExtentPoint32($hDC, $mytext)
    _WinAPI_ReleaseDC($gui, $hDC)
    Return DllStructGetData($tSize, "X") - StringLen($mytext)*2 + 30
EndFunc   

Func _Exit()
    Exit
EndFunc 

Func _OK()
    MsgBox(0, "", "toi y en a cliqué OK")
EndFunc 

Func _Enregistrer()
    MsgBox(0, "", "toi y en a cliqué Enregistrer")
EndFunc  

Func _Tester()
    MsgBox(0, "", "toi y en a cliqué Tester")
EndFunc 

Func _Newspapa()
    MsgBox(0, "", "toi y en a vouloir lire les nouvelles ?")
EndFunc  
 

[satanico64]

Et beh, c'est très interessant tout ça merci bien !!!

Alors à savoir que j'ai pas chomé non plus de mon coté, j'ai bataillé sur la piste que tu m'avais laissé et je suis arrivé a faire ce que je voulais, juste a base de GUICtrlCreateButton etc, avec ajout/suppression, redessinage de gui etc

L'essentiel marche j'ai juste manqué de temps avec le taf .

Cependant, je te rassure tu n'a pas bossé pour rien !

En effet, je feuillette a peine ton code et j'ai déjà des choses qui m'étonnent:

$hDC = _WinAPI_GetDC($gui) => Bigre ! qu'est ce donc-ce ? Apparemment le DC (donc device context), est une notion autre que le Handle....

$tSize = _WinAPI_GetTextExtentPoint32($hDC, $text) => énorme je connaissait pas.

Bon je vais étudier tout ca !
merci !!

[satanico64]

Tiens j'ai l'impression qu'un message a disparu entre temps...


=> Pour Mikell, ton code correspond juste parfaitement à ce que je cherche !
Je sens que je vais m'amuser !!!

Merci beaucoup !
Nicolas.

[mikell]

ton code correspond juste parfaitement à ce que je cherche !

Alors un petit [R] dans le titre du premier sujet ?

Note : oui j'ai effacé mon 1er message, j'avais fait hier soir une 1ère mouture mais ça correspondait pas au cahier des charges alors => viré
pour la taille des boutons les valeurs sont ajustées en fonction de la police par défaut de mon PC, avec une police différente faudra les adapter ou carrément utiliser la fonction StringSize de Melba23 (forum US)

[satanico64]

Après avoir étudié le code, il est vraiment sympa et bien pensé !

Mettre tout ca dans un tableau c'est vraiment pas mal.

Encore merci.


Problem Solved !