[R] Amelioration GUI memo

[silvere]

super merci panda mais il manque un petit truc je n'arrive pas a mettre les image png dans le GUICtrlCreatePic et si je les met en jpeg sa enlevé la transparence alors ...

[mikell]

Ben moi j'aime bien l'idée de fonction custom du Panda...
sauf que le sleep me gêne et qu'il vaut mieux faire ça (avec les mêmes images)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

Global $Form1 = GUICreate("Form1", 150,150, 600, 200)
GUISetBkColor(0xffffff)
Global $Pic1 = GUICtrlCreatePic(@ScriptDir&"\1.jpg", 50, 50, 64, 64)
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_PRIMARYUP, "SpecialEvents")

While 1
Sleep(10)
WEnd

Func SpecialEvents()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
        Exit
    Case @GUI_CtrlId = $GUI_EVENT_PRIMARYDOWN
        $a = GUIGetCursorInfo()
        If $a[4] = $Pic1 Then GUICtrlSetImage($Pic1,@ScriptDir&"\2.jpg")
    Case @GUI_CtrlId =  $GUI_EVENT_PRIMARYUP
        $a = GUIGetCursorInfo()
        If $a[4] = $Pic1 Then 
            GUICtrlSetImage($Pic1,@ScriptDir&"\1.jpg")
            MsgBox(0,"CLICK","CLICK SUR L'IMAGE")
        EndIf
   EndSelect
EndFunc   ;==>SpecialEvents
 

[silvere]

J'ai finalement réfléchit longtemps et j'ai trouver sa :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Misc.au3>

Dim $memo[101]
Dim $heure[101]
Dim $min[101]

Global $nombredememo, $heure, $min, $memo, $memo_fait, $normal = True

$memoactuel = 1
$active = False

$nombredememo = IniRead(@ProgramFilesDir & "\Memo\Info.ini", "Memo", "Nombre de memo", "1")
For $i = 1 To $nombredememo
    $memo[$i] = IniRead(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Memo", "")
    $heure[$i] = IniRead(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Heure", "")
    $min[$i] = IniRead(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Minute", "")
Next

#region ### START Koda GUI section ### Form=C:\Users\Silvere\Desktop\_GuiAnimImage\Memo.kxf
Opt("TrayMenuMode", 1)
Global $Form1 = GUICreate("Form1", 585, 245, 215, 170)
Global $Group1 = GUICtrlCreateGroup("Informations", 160, 32, 265, 145)
Global $Label1 = GUICtrlCreateLabel("Memo :", 176, 88, 48, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
Global $Label2 = GUICtrlCreateLabel("Heure :", 176, 144, 47, 20)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
Global $Input_memo = GUICtrlCreateInput($memo[1], 232, 88, 169, 21)
Global $Input_heure = GUICtrlCreateInput($heure[1], 232, 144, 25, 21)
Global $Input_min = GUICtrlCreateInput($min[1], 280, 144, 25, 21)
Global $Label3 = GUICtrlCreateLabel("h", 264, 144, 13, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Label4 = GUICtrlCreateLabel($memoactuel & "/" & $nombredememo, 536, 208, 26, 24)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
FileInstall(".\gauche.JPG", "gauche.JPG")
FileInstall(".\droite.JPG", "droite.JPG")
FileInstall(".\ajouter.JPG", "ajouter.JPG")
FileInstall(".\valider.JPG", "valider.JPG")
FileInstall(".\supprimer.JPG", "supprimer.JPG")
Global $Pic1 = GUICtrlCreatePic("gauche.JPG", 8, 56, 137, 109)
Global $Pic2 = GUICtrlCreatePic("droite.JPG", 432, 56, 137, 109)
Global $Pic3 = GUICtrlCreatePic("ajouter.JPG", 160, 184, 65, 57)
Global $Pic4 = GUICtrlCreatePic("valider.JPG", 256, 184, 73, 57)
Global $Pic5 = GUICtrlCreatePic("supprimer.JPG", 360, 184, 65, 57)
GUISetState(@SW_SHOW)
TraySetIcon("", -1)
TraySetClick("1")
TrayCreateItem("")
$Trayitem1 = TrayCreateItem("Restorer")
TrayCreateItem("")
$Trayitem2 = TrayCreateItem("Quitter")

#endregion ### END Koda GUI section ###

While 1
    $pos = GUIGetCursorInfo()

    If Not @error Then
        If _IsPressed("01") And $pos[4] = $Pic1 Then
            GUICtrlSetImage($Pic1, ".\gauche hover.JPG")
            $normal = False
        ElseIf _IsPressed("01") And $pos[4] = $Pic2 Then
            GUICtrlSetImage($Pic2, ".\droite hover.JPG")
            $normal = False
        ElseIf _IsPressed("01") And $pos[4] = $Pic3 Then
            GUICtrlSetImage($Pic3, ".\ajouter hover.JPG")
            $normal = False
        ElseIf _IsPressed("01") And $pos[4] = $Pic4 Then
            GUICtrlSetImage($Pic4, ".\valider hover.JPG")
            $normal = False
        ElseIf _IsPressed("01") And $pos[4] = $Pic5 Then
            GUICtrlSetImage($Pic5, ".\supprimer hover.JPG")
            $normal = False

        Else
            If $normal = False Then
                GUICtrlDelete($Pic1)
                Global $Pic1 = GUICtrlCreatePic("gauche.JPG", 8, 56, 137, 109)
                GUICtrlDelete($Pic2)
                Global $Pic2 = GUICtrlCreatePic("droite.JPG", 432, 56, 137, 109)
                GUICtrlDelete($Pic3)
                Global $Pic3 = GUICtrlCreatePic("ajouter.JPG", 160, 184, 65, 57)
                GUICtrlDelete($Pic4)
                Global $Pic4 = GUICtrlCreatePic("valider.JPG", 256, 184, 73, 57)
                GUICtrlDelete($Pic5)
                Global $Pic5 = GUICtrlCreatePic("supprimer.JPG", 360, 184, 65, 57)
                $normal = True
            EndIf
        EndIf
    EndIf


    If $active = True Then
        For $i = 1 To $nombredememo
            $memo_en_cour = $memo[$i] & $heure[$i] & $min[$i]
            If $min[$i] = @MIN And $heure[$i] = @HOUR And $memo_en_cour <> $memo_fait Then
                If $memo[$i] <> "" Then
                    MsgBox(64, "Memo", "Rappel : " & $memo[$i])
                Else
                    MsgBox(64, "Memo", "Rappel : Sans information")
                EndIf

                $memo_fait = $memo[$i] & $heure[$i] & $min[$i]
            EndIf
        Next
    EndIf
    $msg = TrayGetMsg()
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE
            $memo[$memoactuel] = GUICtrlRead($Input_memo)
            $heure[$memoactuel] = GUICtrlRead($Input_heure)
            $min[$memoactuel] = GUICtrlRead($Input_min)
            If Not FileExists(@ProgramFilesDir & "\Memo") Then DirCreate(@ProgramFilesDir & "\Memo")
            If Not FileExists(@ProgramFilesDir & "\Memo\Info.ini") Then _FileCreate(@ProgramFilesDir & "\Memo\Info.ini")
            IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo", "Nombre de memo", $nombredememo)
            For $i = 1 To $nombredememo
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Memo", $memo[$i])
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Heure", $heure[$i])
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Minute", $min[$i])
            Next
            Exit
        Case $nMsg = $Pic1
            If $memoactuel > 1 Then
                $memo[$memoactuel] = GUICtrlRead($Input_memo)
                $heure[$memoactuel] = GUICtrlRead($Input_heure)
                $min[$memoactuel] = GUICtrlRead($Input_min)
                $memoactuel = $memoactuel - 1
                GUICtrlSetData($Input_heure, $heure[$memoactuel])
                GUICtrlSetData($Input_min, $min[$memoactuel])
                GUICtrlSetData($Label4, $memoactuel & "/" & $nombredememo)
                GUICtrlSetData($Input_memo, $memo[$memoactuel])
            EndIf
        Case $nMsg = $Pic2
            If $memoactuel < $nombredememo Then
                $memo[$memoactuel] = GUICtrlRead($Input_memo)
                $heure[$memoactuel] = GUICtrlRead($Input_heure)
                $min[$memoactuel] = GUICtrlRead($Input_min)
                $memoactuel = $memoactuel + 1
                GUICtrlSetData($Input_heure, $heure[$memoactuel])
                GUICtrlSetData($Input_min, $min[$memoactuel])
                GUICtrlSetData($Label4, $memoactuel & "/" & $nombredememo)
                GUICtrlSetData($Input_memo, $memo[$memoactuel])
            EndIf
        Case $nMsg = $Pic3
            If $nombredememo < 100 Then
                $nombredememo = $nombredememo + 1
                GUICtrlSetData($Label4, $memoactuel & "/" & $nombredememo)
            Else
                MsgBox(64, "Information", "Vous oublier beaucoup de chose vous :p")
            EndIf
        Case $nMsg = $Pic4
            $memo[$memoactuel] = GUICtrlRead($Input_memo)
            $heure[$memoactuel] = GUICtrlRead($Input_heure)
            $min[$memoactuel] = GUICtrlRead($Input_min)
            $active = True
            GUISetState(@SW_HIDE, $Form1)
        Case $nMsg = $Pic5
            If $memoactuel = $nombredememo Then
                If $nombredememo > 1 Then
                    $memo[$memoactuel] = ""
                    $heure[$memoactuel] = ""
                    $min[$memoactuel] = ""
                    $memoactuel = $memoactuel - 1
                    $nombredememo = $nombredememo - 1
                    GUICtrlSetData($Input_heure, $heure[$memoactuel])
                    GUICtrlSetData($Input_min, $min[$memoactuel])
                    GUICtrlSetData($Input_memo, $memo[$memoactuel])
                    GUICtrlSetData($Label4, $memoactuel & "/" & $nombredememo)
                EndIf

            Else
                For $i = $memoactuel To $nombredememo
                    $min[$i] = $min[$i + 1]
                    $heure[$i] = $heure[$i + 1]
                    $memo[$i] = $memo[$i + 1]
                Next
                $nombredememo = $nombredememo - 1
                GUICtrlSetData($Input_heure, $heure[$memoactuel])
                GUICtrlSetData($Input_min, $min[$memoactuel])
                GUICtrlSetData($Input_memo, $memo[$memoactuel])
                GUICtrlSetData($Label4, $memoactuel & "/" & $nombredememo)
            EndIf
        Case $msg = $Trayitem1
            GUISetState(@SW_SHOW, $Form1)
        Case $msg = $Trayitem2
            $memo[$memoactuel] = GUICtrlRead($Input_memo)
            $heure[$memoactuel] = GUICtrlRead($Input_heure)
            $min[$memoactuel] = GUICtrlRead($Input_min)
            If Not FileExists(@ProgramFilesDir & "\Memo") Then DirCreate(@ProgramFilesDir & "\Memo")
            If Not FileExists(@ProgramFilesDir & "\Memo\Info.ini") Then _FileCreate(@ProgramFilesDir & "\Memo\Info.ini")
            IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo", "Nombre de memo", $nombredememo)
            For $i = 1 To $nombredememo
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Memo", $memo[$i])
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Heure", $heure[$i])
                IniWrite(@ProgramFilesDir & "\Memo\Info.ini", "Memo" & $i, "Minute", $min[$i])
            Next
            Exit
    EndSelect
WEnd



 

[PandiPanda]

@Mikell
votre script 'bug' lorsque on click (on reste appuyer) et on bouge en dehor de la zone d'image ^^

(faudrai genre vérifié si on est bien dans la zone, ... ou bien si on a relacher le click de souris et qu'on à bien click avant sur l'image)

sinon, oui c'est pas mal du tout :p

[mikell]

Hum hum oups

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

Global $Form1 = GUICreate("Form1", 150,150, 600, 200)
GUISetBkColor(0xffffff)
Global $Pic1 = GUICtrlCreatePic(@ScriptDir&"\1.jpg", 50, 50, 64, 64)
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "SpecialEvents")
GUISetOnEvent($GUI_EVENT_PRIMARYUP, "SpecialEvents")
Global $_pic1 = 0

While 1
Sleep(10)
WEnd

Func SpecialEvents()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
        Exit
    Case @GUI_CtrlId = $GUI_EVENT_PRIMARYDOWN
        $a = GUIGetCursorInfo()
        If $a[4] = $Pic1 Then 
        GUICtrlSetImage($Pic1,@ScriptDir&"\2.jpg")
        $_pic1 = 1
    EndIf
    Case @GUI_CtrlId =  $GUI_EVENT_PRIMARYUP
        If $_pic1 = 1 Then
        GUICtrlSetImage($Pic1,@ScriptDir&"\1.jpg")
        MsgBox(0,"CLICK","CLICK SUR L'IMAGE")
        $_pic1 = 0
        EndIf
   EndSelect
EndFunc   ;==>SpecialEvents