[R] Modifier ToolBar selon Tab sélectionné

[cortexx]

Bonjour,

Aprés pas mal de recherche et de tests, je ne parviens pas à modifier les boutons de ma ToolBar selons la tab sélectionné.
Pour être plus précis, je voudrait faire en sorte que lorsque que clique sur un onglet de ma Tab les boutons de ma ToolBar se mette à jour selons se que j'aurais définie.

Auriez vous en réserve une fonction qui me permette de faire ça ?

J'ai bien essayer avec les GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY") ou GUIRegisterMsg($WM_COMMAND, "WM_COMMAND"), mais sans aucun résultat.

[TommyDDR]

Pourriez vous poster le code source ?
J'ai personnellement eu des problèmes avec les TAB qui ne se rafraichissaient pas / apparaissaient pas après un GUICtrlCreate ou autre action sur les Ctrl.

[cortexx]

Voila un exemple qui colle à se que je fait en se moment, je ne peut pas mettre mon code original ça serait beaucoup trop long
Dans se code il n'y a que la gestion des évènements des boutons, vu que je sais même pas comment faire pour gérer les évènements sur les onglets.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#Include <GuiTab.au3>
#include <TabConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)

Local Enum $IDToolBar_New = 100, $IDToolBar_Properties, $IDToolBar_Delete

Local $Form1 = GUICreate("Form", 450, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowCloseForm")

Local $ToolBar1 = _GUICtrlToolbar_Create($Form1, 0)
_GUICtrlToolbar_AddBitmap($ToolBar1, 1, -1, $IDB_VIEW_SMALL_COLOR)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_New, $STD_FILENEW)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Properties, $STD_PROPERTIES)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Delete, $STD_DELETE)

Local $Tab1 = GUICtrlCreateTab(0, 30, 450, 170)

Local $TabSheet1 = GUICtrlCreateTabItem("Tab 0")
Local $Edit1 = GUICtrlCreateEdit("Edit 1", 10, 60, 430, 130)

Local $TabSheet2 = GUICtrlCreateTabItem("Tab 1")
Local $Edit2 = GUICtrlCreateEdit("Edit 2", 10, 60, 430, 130)

Local $TabSheet3 = GUICtrlCreateTabItem("Tab 2")
Local $Edit3 = GUICtrlCreateEdit("Edit 3", 10, 60, 430, 130)

GUICtrlCreateTabItem("")

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)
While 1
    Sleep(50)
WEnd

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Switch _WinAPI_LoWord($iwParam)
        Case $IDToolBar_New
            Switch _GUICtrlTab_GetCurSel($Tab1)
                Case 0
                    GUICtrlSetData($Edit1, "Bouton : New | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 1
                    GUICtrlSetData($Edit2, "Bouton : New | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 2
                    GUICtrlSetData($Edit3, "Bouton : New | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
            EndSwitch
        Case $IDToolBar_Properties
            Switch _GUICtrlTab_GetCurSel($Tab1)
                Case 0
                    GUICtrlSetData($Edit1, "Bouton : Properties | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 1
                    GUICtrlSetData($Edit2, "Bouton : Properties | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 2
                    GUICtrlSetData($Edit3, "Bouton : Properties | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
            EndSwitch
        Case $IDToolBar_Delete
            Switch _GUICtrlTab_GetCurSel($Tab1)
                Case 0
                    GUICtrlSetData($Edit1, "Bouton : Delete | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 1
                    GUICtrlSetData($Edit2, "Bouton : Delete | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
                Case 2
                    GUICtrlSetData($Edit3, "Bouton : Delete | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func WindowCloseForm()
    Exit
EndFunc

[TommyDDR]

Alors, déjà, quand vous nommez vos variables $xxx1, $xxx2, $xxx3, cela veut dire que vous pouvez (Devez !) utiliser un tableau, sinon votre programme ne sera pas facilement utilisable (exemple : vos switch)

Voila qui devrait vous mettre sur la voie pour vos modifications lors d'un clic sur un onglet :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#Include <GuiTab.au3>
#include <TabConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)

Local Enum $IDToolBar_New = 100, $IDToolBar_Properties, $IDToolBar_Delete
Dim $TabSheet[3]
Dim $Edit[3]
Local $Form1 = GUICreate("Form", 450, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowCloseForm")

Local $ToolBar1 = _GUICtrlToolbar_Create($Form1, 0)
_GUICtrlToolbar_AddBitmap($ToolBar1, 1, -1, $IDB_VIEW_SMALL_COLOR)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_New, $STD_FILENEW)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Properties, $STD_PROPERTIES)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Delete, $STD_DELETE)

Local $Tab1 = GUICtrlCreateTab(0, 30, 450, 170)

$TabSheet[0] = GUICtrlCreateTabItem("Tab 0")
$Edit[0] = GUICtrlCreateEdit("Edit 1", 10, 60, 430, 130)
$TabSheet[1] = GUICtrlCreateTabItem("Tab 1")
$Edit[1] = GUICtrlCreateEdit("Edit 2", 10, 60, 430, 130)
$TabSheet[2] = GUICtrlCreateTabItem("Tab 2")
$Edit[2] = GUICtrlCreateEdit("Edit 3", 10, 60, 430, 130)

GUICtrlCreateTabItem("")

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)
While 1
    Sleep(50)
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    If($iwParam = $Tab1) Then
        ToolTip("Clic sur Tab : " & _GUICtrlTab_GetCurSel($Tab1))
    EndIf
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Switch _WinAPI_LoWord($iwParam)
        Case $IDToolBar_New
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : New | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
        Case $IDToolBar_Properties
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : Properties | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
        Case $IDToolBar_Delete
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : Delete | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func WindowCloseForm()
    Exit
EndFunc

Edit : En me relisant, je trouve que j'ai un air "Je fais la morale" . Que nenni, ce ne sont que des conseils, à prendre comme tel ^^.

[cortexx]

J'ai du sauter une étape dans mon apprentissage pour le coup des variables en tableau

Alors j'ai finaliser le code et grace à toi enfin pu faire se que je voulait merci.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#Include <GuiTab.au3>
#include <TabConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)

Local Enum $IDToolBar_New = 100, $IDToolBar_Properties, $IDToolBar_Delete
Dim $TabSheet[3]
Dim $Edit[3]
Local $Form1 = GUICreate("Form", 450, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "WindowCloseForm")

Local $ToolBar1 = _GUICtrlToolbar_Create($Form1, 0)
_GUICtrlToolbar_AddBitmap($ToolBar1, 1, -1, $IDB_VIEW_SMALL_COLOR)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_New, $STD_FILENEW)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Properties, $STD_PROPERTIES)
_GUICtrlToolbar_AddButtonSep($ToolBar1)
_GUICtrlToolbar_AddButton($ToolBar1, $IDToolBar_Delete, $STD_DELETE)

Local $Tab1 = GUICtrlCreateTab(0, 30, 450, 170)

$TabSheet[0] = GUICtrlCreateTabItem("Tab 0")
$Edit[0] = GUICtrlCreateEdit("Edit 1", 10, 60, 430, 130)
$TabSheet[1] = GUICtrlCreateTabItem("Tab 1")
$Edit[1] = GUICtrlCreateEdit("Edit 2", 10, 60, 430, 130)
$TabSheet[2] = GUICtrlCreateTabItem("Tab 2")
$Edit[2] = GUICtrlCreateEdit("Edit 3", 10, 60, 430, 130)

GUICtrlCreateTabItem("")

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
DisableOrEnableButton()
GUISetState(@SW_SHOW)
While 1
    Sleep(50)
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    If ($iwParam = $Tab1) Then
        DisableOrEnableButton()
    EndIf
EndFunc

Func DisableOrEnableButton()
    Switch _GUICtrlTab_GetCurSel($Tab1)
        Case 0
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_New, True)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Properties, True)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Delete, False)
        Case 1
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_New, False)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Properties, True)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Delete, True)
        Case 2
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_New, True)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Properties, False)
            _GUICtrlToolbar_EnableButton($ToolBar1, $IDToolBar_Delete, True)
    EndSwitch
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Switch _WinAPI_LoWord($iwParam)
        Case $IDToolBar_New
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : New | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
        Case $IDToolBar_Properties
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : Properties | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
        Case $IDToolBar_Delete
            GUICtrlSetData($Edit[_GUICtrlTab_GetCurSel($Tab1)], "Bouton : Delete | Tab ID : " & _GUICtrlTab_GetCurSel($Tab1))
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func WindowCloseForm()
    Exit
EndFunc

Je suis toujours ouvert à toute amélioration