[R] ListView, désactiver le Drag and Drop

[Strofe]

Bonjour

Après pas mal de recherche, je me permets de solliciter votre aide.

Je veux supprimer l'effet Drag and Drop d'un ListView.

Si je clique sur une ligne et que je déplace la souris, le mode drag and drop est présent.

► Afficher le texte

Code : Tout sélectionner

#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include 'LV_Format_include.au3'

Local $col = ''
For $i = 1 To 6
    $col &= $i & '|'
Next

$GUI = GUICreate('')
$lv = GUICtrlCreateListView(StringTrimRight($col,1), 10, 10, 300, 150,BitOR($LVS_REPORT,$LVS_SHOWSELALWAYS), BitOR($WS_EX_CLIENTEDGE,$LVS_EX_FULLROWSELECT))
$hLV = GUICtrlGetHandle($lv)
For $i = 0 To 5
    _GUICtrlListView_SetColumnWidth($hLV, $i, 49)
Next
_GUICtrlListView_Formatting_Startup($GUI, $hLV)

; add new Items
_GUICtrlListView_AddOrIns_Item($hLV, 'Test0|Test1|Test2|Test3|Test4|Test5')
_GUICtrlListView_AddOrIns_Item($hLV, 'Blub0|Blub1|Blub2|Blub3|Blub4|Blub5')
_GUICtrlListView_AddOrIns_Item($hLV, 'Club0|Club1|Club2|Club3|Club4|Club5')
_GUICtrlListView_AddOrIns_Item($hLV, 'Blab0|Blab1|Blab2|Blab3|Blab4|Blab5')
_GUICtrlListView_AddOrIns_Item($hLV, 'Bumm0|Bumm1|Bumm2|Bumm3|Bumm4|Bumm5')

GUISetState(@SW_SHOW, $GUI)

_GUICtrlListView_DefaultsSet() ; change default settings to standard

WinSetTitle($GUI, '', 'Now click column header to sort')

Do
Until GUIGetMsg() = -3
; clear ressources
_GUICtrlListView_Formatting_Shutdown()

Par avance merci

Christophe

[Tlem]

Voici un exemple plus complet que le simple traitement du Drag&Drop (au cas ou ...) :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#Include <GuiListView.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 217, 200, 192, 124)
$ListView1 = GUICtrlCreateListView("Colonne 1|Colonne 2", 8, 8, 186, 134)

GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 100)
$ListView1_0 = GUICtrlCreateListViewItem("Elément 1", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("Elément 2", $ListView1)
$ListView1_2 = GUICtrlCreateListViewItem("Elément 3", $ListView1)
$ListView1_3 = GUICtrlCreateListViewItem("Elément 4", $ListView1)
GUISetState(@SW_SHOW)

; Register WM_NOTIFY  events
GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

; WM_NOTIFY event handler
Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam)
    #forceref $hWndGUI, $MsgID, $wParam
    Local $tagNMHDR, $event, $hwndFrom, $code, $tagNMLISTVIEW
    $tagNMHDR = DllStructCreate("int;int;int", $lParam);NMHDR (hwndFrom, idFrom, code)
    If @error Then Return
    $event = DllStructGetData($tagNMHDR, 3)
    Select
    Case $wParam = $ListView1
        Select
            Case $event = $NM_CLICK
                ListView_Click()
            Case $event = $NM_DBLCLK
                ListView_DoubleClick()
            Case Else
                $tagNMLISTVIEW = DllStructCreate("int;int;int;int;int;uint;uint;uint;int;int;int", $lParam)
                Select
                    Case $event = $LVN_BEGINDRAG
                        Return 1 ; Disable Drag action
                EndSelect
        EndSelect
    EndSelect
    $tagNMHDR = 0
    $event = 0
    $lParam = 0
EndFunc ;==>WM_Notify_Events

; Function ListView_Click
Func ListView_Click()
    ConsoleWrite("$NM_CLICK" & @CRLF)
EndFunc ;==>ListView_Click

; Function ListView_DoubleClick
Func ListView_DoubleClick()
    ConsoleWrite("$NM_DBLCLK" & @CRLF)
    Local $SelectedItemText = _GUICtrlListView_GetItemText ($ListView1, Number(_GUICtrlListView_GetSelectedIndices($ListView1)))

    MsgBox(0,"Double Click sur ", $SelectedItemText)
EndFunc ;==>ListView_DoubleClick

[Strofe]

Bonsoir

Encore mieux que sur le plan.

Merci le prototype est opérationnel.

Je fais un test à l'échelle 1 dès demain matin.

Encore merci

Christohpe

[Strofe]

Bonjour

Impeccable

Pour info voici le code complet. (sans les paramètres pour la base de données SQL)

► Afficher le texte

Code : Tout sélectionner

#cs
    V02.00 - 27/03/2011 - Simplification du code pour supprimer le Drag and Drop et suppimer la bibliothèque LV_Format_include.au3 & Ajout du Ctrl+C ;
    V01.02 - 25/03/2011 - Ctrl+A ;
    V01.01 - 25/03/2011 - Intégration de la sélection et de la copie dans le presse papier - Séparateur ;
    V01.00 - 23/03/2011 - Création initiale
#ce

#include <Array.au3>
#include <GuiListView.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

;~ Bibliothèques personnelles
#include '_My_ADODB_Constants.au3'

;  ^ Ctrl, + Shift, ! Alt
HotKeySet("^a", "SelectAll" )       ; Ctrl + a
HotKeySet("^c", "CopySelected" )    ; Ctrl + c

Local $haut = 600
Local $pas = 20
Local $col = ''
$col &= 'Article'  & '|'
$col &= 'Famille'  & '|'
$col &= 'Mot Directeur'  & '|'
$col &= 'Désignation'  & '|'
$col &= 'Localisation'  & '|'

$GUI = GUICreate('RJ - Consultation SILOG - V02.00',950,740)

$lv = GUICtrlCreateListView(StringTrimRight($col,1), 10, 10, 930, $haut - 15, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES))
_GUICtrlListView_SetExtendedListViewStyle($lv, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT,$LVS_EX_HEADERDRAGDROP  ))
GUICtrlSendMsg($lv, $LVM_SETCOLUMNWIDTH, 0, 89)
GUICtrlSendMsg($lv, $LVM_SETCOLUMNWIDTH, 1, 69)
GUICtrlSendMsg($lv, $LVM_SETCOLUMNWIDTH, 2, 150)
GUICtrlSendMsg($lv, $LVM_SETCOLUMNWIDTH, 3, 500)
GUICtrlSendMsg($lv, $LVM_SETCOLUMNWIDTH, 4, 100)

$CodeArticle = GUICtrlCreateLabel("Code Article", 40, $haut, 93, 17)
$CdeArt = GUICtrlCreateInput("", 136,$haut, 190, 17)
$CodeFamille = GUICtrlCreateLabel("Code Famille", 40, $haut+$pas, 93, 17)
$CdeFam = GUICtrlCreateInput("", 136,$haut+$pas, 190, 17)
$MotDirecteur = GUICtrlCreateLabel("Mot directeur", 40, $haut+2*$pas, 93, 17)
$MotDir = GUICtrlCreateInput("", 136,$haut+2*$pas, 190, 17)
$Designation = GUICtrlCreateLabel("Désignation", 40, $haut+3*$pas, 93, 17)
$Des = GUICtrlCreateInput("", 136,$haut+3*$pas, 290, 17)
$Designation1 = GUICtrlCreateLabel("et", 439, $haut+3*$pas, 20, 17)
$Des1 = GUICtrlCreateInput("", 460,$haut+3*$pas, 290, 17)
$Localisation = GUICtrlCreateLabel("Localisation", 40, $haut+4*$pas, 93, 17)
$Loc = GUICtrlCreateInput("", 136,$haut+4*$pas, 190, 17)
$Filtre = GUICtrlCreateButton("Filtre", 500, $haut, 95, 22)
$copy = GUICtrlCreateButton("Copier", 600, $haut, 95, 22)
$Raz = GUICtrlCreateButton("RàZ", 700, $haut, 95, 22)
$Quit = GUICtrlCreateButton("Quitter", 800, $haut, 95, 22)

;$ListView1_0 = GUICtrlCreateListViewItem("1|2|3|4|5", $lv)
;$ListView1_0 = GUICtrlCreateListViewItem("6|7|8|9|0", $lv)

GUISetState(@SW_SHOW, $GUI)

; Register WM_NOTIFY  events
GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events")
_GUICtrlListView_RegisterSortCallBack($lv)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $copy
            CopySelected()      
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Quit
            Exit
        Case $Filtre
            FaitFiltre(GUICtrlRead($CdeArt), GUICtrlRead($CdeFam), GUICtrlRead($MotDir), GUICtrlRead($Des), GUICtrlRead($Des1), GUICtrlRead($Loc))
        Case $Raz
            GUICtrlSetData ($CdeArt, "")
            GUICtrlSetData ($CdeFam, "")
            GUICtrlSetData ($MotDir, "")
            GUICtrlSetData ($Des, "")
            GUICtrlSetData ($Des1, "")
            GUICtrlSetData ($Loc, "")
            _GUICtrlListView_DeleteAllItems($lv)


    EndSwitch
WEnd


Exit

;~ -----------------------------------------------
;~ -----------------------------------------------
;~ Fonctions
;~  
Func FaitFiltre($CdeArt, $CdeFam, $MotDir, $Des, $Des1, $Loc)
    
    ;Ouverture de la connection
    $DSN = "DRIVER={SQL Server};SERVER=Nom_du_serveur;DATABASE=Nom_de_la_base;UID=nom_login;PWD=nmot_de_passe;"  
    
    Local $conn = ObjCreate("ADODB.Connection")
    If $conn=0 Then
        MsgBox(0,"RJ - Silog","Connexion impossible")
        Exit
    EndIf
    $conn.ConnectionString = $DSN 
    $conn.CursorLocation = $adUseClient
    $conn.Open()

    $rs = ObjCreate( "ADODB.RecordSet" )   
    Local $sql = ''
    $sql &= "SELECT CodeArticle, CodeFamille, MotDirecteur, Designation1, Localisation FROM ARTICLE WHERE "
    $sql &= "CodeArticle Like '%" & $CdeArt & "%' AND "
    $sql &= "CodeFamille Like '%" & $CdeFam & "%' AND "
    $sql &= "MotDirecteur Like '%" & $MotDir & "%' AND "
    $sql &= "Designation1 Like '%" & $Des & "%' AND "
    $sql &= "Designation1 Like '%" & $Des1 & "%' AND "
    $sql &= "Localisation Like '%" & $Loc & "%' "
    
    $rs.Open( $sql, $conn )
    _GUICtrlListView_DeleteAllItems($lv)
    If $rs.eof Then
            msgbox(0,"RJ SILOG","Rien de correspond à votre demande")
        Else
            If $rs.recordcount>150 then 
                    msgbox(0,"RJ SILOG","Trop de lignes, merci d'affiner votre demande")
                else
                _GUICtrlListView_DeleteAllItems($lv)
                Local $ligne = ''
                Do
                    $ligne &= $rs.Fields("CodeArticle").value & '|'
                    $ligne &= $rs.Fields("CodeFamille").value & '|'
                    $ligne &= $rs.Fields("MotDirecteur").value & '|'
                    $ligne &= $rs.Fields("Designation1").value & '|'
                    $ligne &= $rs.Fields("Localisation").value & '|'
                    GUICtrlCreateListViewItem($ligne, $lv)
                    $ligne = ''
                    $rs.movenext
                until $rs.eof
            EndIf
    EndIf
    $conn.Close  
EndFunc


Func SelectAll()
    _GUICtrlListView_SetItemSelected ($lv,-1)
EndFunc

Func CopyCodeArt()
    ClipPut(_GUICtrlListView_GetItemText ($lv, Number(_GUICtrlListView_GetSelectedIndices($lv))))
    
EndFunc

Func CopySelected()
    If  _GUICtrlListView_GetSelectedCount($lv) >0 Then
        $id = StringSplit(_GUICtrlListView_GetSelectedIndices($lv),"|")
        Local $table = ''
        For $t = 1 to UBound($id) - 1
            $table &= _GUICtrlListView_GetItemTextString($lv,int($id[$t])) & @CRLF
        Next
        $table = StringReplace($table,"|",@tab)
        ClipPut($table) 
    EndIf
EndFunc

; WM_NOTIFY event handler
Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam)
    #forceref $hWndGUI, $MsgID, $wParam
    Local $hWndFrom, $iCode, $tNMHDR, $hWndListView
    
    If Not IsHWnd($lv) Then $hWndListView = GUICtrlGetHandle($lv)
    
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Select
    Case $wParam = $lv
        Select
            Case $iCode = $LVN_COLUMNCLICK 
                Local $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                ; Kick off the sort callback
                _GUICtrlListView_SortItems($hWndFrom, DllStructGetData($tInfo, "SubItem"))
                ; No return
                
            Case $iCode = $NM_DBLCLK
                CopyCodeArt()
            Case Else
                $tagNMLISTVIEW1 = DllStructCreate("int;int;int;int;int;uint;uint;uint;int;int;int", $lParam)
                Select
                    Case $iCode = $LVN_BEGINDRAG
                        Return 1 ; Disable Drag action
                EndSelect
        EndSelect
    EndSelect
    $tagNMHDR1 = 0
    $iCode = 0
    $lParam = 0
EndFunc ;==>WM_Notify_Events
 

Encore merci

Christophe

[jchd]

En AutoIt avec une GUI standard, les ListViewItems ne sont pas "dropables" sauf code additionnel spécifique (avec WM_NOTIFY et $LVN_BEGINDRAG). Le curseur souris peut faire croire que le drag and drop est utilisable, mais ce n'est qu'un effet visuel.

Par contre, il y a deux choses qui me chiffoneraient assez dans la partie SQL. La première est que les littéraux ne sont pas correctement quotés :

Code : Tout sélectionner

    $sql &= "SELECT CodeArticle, CodeFamille, MotDirecteur, Designation1, Localisation FROM ARTICLE WHERE "
    $sql &= "CodeArticle Like '%" & $CdeArt & "%' AND "
    $sql &= "CodeFamille Like '%" & $CdeFam & "%' AND "
    $sql &= "MotDirecteur Like '%" & $MotDir & "%' AND "
    $sql &= "Designation1 Like '%" & $Des & "%' AND "
    $sql &= "Designation1 Like '%" & $Des1 & "%' AND "
    $sql &= "Localisation Like '%" & $Loc & "%' "

Outre le fait qu'il y a deux critères LIKE (reliés par AND) sur la même colonne Designation1 (fort étrange), outre le fait que tous les critères soient LIKE (ce qui perso me semble peu probable et peu efficace), on doit s'imposer de quoter les littéraux texte avec une fonction du genre :

Code : Tout sélectionner

Func X($s)
    Return ("'" & StringReplace($s, "'", "''", 0, 1) & "'")
EndFunc   ;==>X

qui double toute apostrophe [simple quote] à l'intérieur du littéral texte.
Si par exemple on a une désignation contenant une simple quote (apostrophe pour nous) :

Code : Tout sélectionner

$Des = "Coude 45° de guide d'onde série UGA56"

on doit soumettre cette partie comme ceci :

Code : Tout sélectionner

    $sql &= "Designation1 Like " & X("%" & $Des & "%") & " AND "

sinon la quote de d'onde termine le littéral prématurément.

Par ailleurs, en contexte professionnel, attention à l'injection de code SQL (cf. Google).

Ces deux écueils sont normalement contournés en utilisant des paramètres (?) dans le SQL et en faisant des BIND des valeurs littérales. Ces fonctions ne sont pas toujours disponibles (sans bugs) en ODBC et pour info je n'ai pas implémenté ces possibilités dans l'UDF SQLite (car l'interface avec AutoIt devient lourde et moins efficace en utilisation moyenne).

[Strofe]

Bonsoir

Pour la simple quote ('), je n'y avais pas pensé.... Je regarde dès demain pour intégrer cela. Merci.

Par contre pour les like et and, je suis formel, c'est excellent. (Base de données Sql Server 2K)

Le but et d'avoir une interrogation avec un seul filtre, leus utilisateurs donnent les critères qui les interessent.

Donc s'il n'y a pas de désignation le critère vaut %% qui renvoit tout... Simple astuce....
De plus 2 fois designation à cause du manque de rigueur..

Ex : Vis Inox de 3x20 ----- ou ------ Vis 3x20 Inox ----- grrrrrrr

A+