[R] gui ajustable comme une fenetre windons

[jl56]

Bonjour a tous

Je cherche comment rendre le fonctionnement d'une gui exactement identique au fonctionnement d'une fenêtre windows
ex . vous ouvrez un dossier et si vous réduisez la fenêtre en largeur, lorsque la fenêtre ne peut afficher tous les éléments, une barre horizontal s'affiche pour permettre le déplacement des éléments à droite ou à gauche, même fonctionnement si vous réduisez cette fenêtre en hauteur une barre verticale apparait ...

j'ai testé ceci

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$hGUI2 = GUICreate('test', 500, 600, 0, 0,BitOR($WS_HSCROLL,$WS_VSCROLL,$WS_SIZEBOX,$WS_MAXIMIZEBOX))
$bt1 = GUICtrlCreateButton("bouton1",20,550,100,40)
$bt2 = GUICtrlCreateButton("bouton2",100,400,150,40)


GUiSetState(@SW_SHOW, $hGUI2)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

les barres sont bien présentes mais inactivent
ma gui est bien modifiable mais les boutons ( écartement, position) se déforme

J'aimerais qu'ils gardent leurs positions dans la gui et que les barres me permette d'aller les chercher

j'ai testé d'autre valeurs et je ne voie pas quel styles utiliser

merci de vos suggestions

A+ JL56

[jl56]

bonjour à tous

en regardant les derniers posts j'ai vu l'option

Opt("GUIResizeMode", $GUI_DOCKALL)

du coup dans mon script je n'ai plus la déformation que j'ai cité

par contre les barres ne fonctionne toujours pas. est ce que l'un d'entre vous à déjà vu un script
fonctionné avec ces barres.
si oui merci de le fournir en exemple

A+ JL56

[jl56]

Bonjour à tous

Et bien comme souvent la réponse est dans l'aide autoit. Mais j'avais recherché avec les mots WS_HSCROLL et $WS_VSCROLL d'où mon égarement dans les limbes des forums francais et anglais. Puis au fil de mes lectures et test de script divers je suis tombé sur _GUIScrollBars_ScrollWindow et avec je trouve dans l'aide autoit un exemple de script qui fonctionne que je désire.
ouf une bonne dizaine d'heures de recherche comme même. Ma femme me demande pourquoi je reste si longtemps sur le net ( moi aussi ) ne lui dite pas S.V.P.

sur ce script j'ai une remarque ( je l'ai modifié pour l'exemple )

► Afficher le texte

Code : Tout sélectionner

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>

Opt("GUIResizeMode", $GUI_DOCKall)
_Main()

Func _Main()
    Local  $GUIMsg, $hGUI
    Local $button1 ,$button2 ,$button3 ,$button4 ,$button5 ,$button6 ,$button7 ,$button8 ,$button9 ,$button10,$button11,$button12
    $hGUI = GUICreate("ScrollBar Example", 950, 750, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    GUISetBkColor(0x88AABB)

    $button1 = GUICtrlCreateButton("30, 30", 30, 30, 60,20)
    $button2 = GUICtrlCreateButton("380, 380", 380, 380, 60, 20)
    $button3 = GUICtrlCreateButton("360, 30", 360, 30, 60, 20)
    $button4 = GUICtrlCreateButton("30, 360", 30, 360, 60, 20)
    $button5 = GUICtrlCreateButton("30, 340", 30, 340, 60, 20)
    $button6 = GUICtrlCreateButton("340, 30", 340, 30, 60, 20)
    $button7 = GUICtrlCreateButton("300, 300", 300, 300, 60, 20)
    $button8 = GUICtrlCreateButton("320, 30", 320, 30, 60, 20)
    $button9 = GUICtrlCreateButton("320, 30", 320, 30, 60, 20)
    $button10 = GUICtrlCreateButton("820, 620", 820, 620, 60, 20)
    $button11= GUICtrlCreateButton("820, 30", 820, 30, 60, 20)
    $button12= GUICtrlCreateButton("320, 630", 320, 630, 60, 20)



    GUIRegisterMsg($WM_SIZE, "WM_SIZE")
    GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
    GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")

    GUISetState()


    _GUIScrollBars_Init($hGUI,950,40)

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

Func WM_SIZE($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam
    Local $index = -1, $yChar, $xChar, $xClientMax, $xClient, $yClient, $ivMax
    For $x = 0 To UBound($aSB_WindowInfo) - 1
        If $aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $xClientMax = $aSB_WindowInfo[$index][1]
            $xChar = $aSB_WindowInfo[$index][2]
            $yChar = $aSB_WindowInfo[$index][3]
            $ivMax = $aSB_WindowInfo[$index][7]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0

    Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)

    ; Retrieve the dimensions of the client area.
    $xClient = BitAND($lParam, 0x0000FFFF)
    $yClient = BitShift($lParam, 16)
    $aSB_WindowInfo[$index][4] = $xClient
    $aSB_WindowInfo[$index][5] = $yClient

    ; Set the vertical scrolling range and page size
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $ivMax)
    DllStructSetData($tSCROLLINFO, "nPage", $yClient / $yChar)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)

    ; Set the horizontal scrolling range and page size
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", 2 + $xClientMax / $xChar)
    DllStructSetData($tSCROLLINFO, "nPage", $xClient / $xChar)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE

Func WM_HSCROLL($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $lParam
    Local $nScrollCode = BitAND($wParam, 0x0000FFFF)

    Local $index = -1, $xChar, $xPos
    Local $Min, $Max, $Page, $Pos, $TrackPos

    For $x = 0 To UBound($aSB_WindowInfo) - 1
        If $aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $xChar = $aSB_WindowInfo[$index][2]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0

;~  ; Get all the horizontal scroll bar information
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
    $Min = DllStructGetData($tSCROLLINFO, "nMin")
    $Max = DllStructGetData($tSCROLLINFO, "nMax")
    $Page = DllStructGetData($tSCROLLINFO, "nPage")
    ; Save the position for comparison later on
    $xPos = DllStructGetData($tSCROLLINFO, "nPos")
    $Pos = $xPos
    $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    #forceref $Min, $Max
    Switch $nScrollCode

        Case $SB_LINELEFT ; user clicked left arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)

        Case $SB_LINERIGHT ; user clicked right arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)

        Case $SB_PAGELEFT ; user clicked the scroll bar shaft left of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)

        Case $SB_PAGERIGHT ; user clicked the scroll bar shaft right of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)

        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
    EndSwitch

;~    // Set the position and then retrieve it.  Due to adjustments
;~    //   by Windows it may not be the same as the value set.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    ;// If the position has changed, scroll the window and update it
    $Pos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($Pos <> $xPos) Then _GUIScrollBars_ScrollWindow($hWnd, $xChar * ($xPos - $Pos), 0)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL

Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $nScrollCode = BitAND($wParam, 0x0000FFFF)
    Local $index = -1, $yChar, $yPos
    Local $Min, $Max, $Page, $Pos, $TrackPos

    For $x = 0 To UBound($aSB_WindowInfo) - 1
        If $aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $yChar = $aSB_WindowInfo[$index][3]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0


    ; Get all the vertial scroll bar information
    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $Min = DllStructGetData($tSCROLLINFO, "nMin")
    $Max = DllStructGetData($tSCROLLINFO, "nMax")
    $Page = DllStructGetData($tSCROLLINFO, "nPage")
    ; Save the position for comparison later on
    $yPos = DllStructGetData($tSCROLLINFO, "nPos")
    $Pos = $yPos
    $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")

    Switch $nScrollCode
        Case $SB_TOP ; user clicked the HOME keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Min)

        Case $SB_BOTTOM ; user clicked the END keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Max)

        Case $SB_LINEUP ; user clicked the top arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)

        Case $SB_LINEDOWN ; user clicked the bottom arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)

        Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)

        Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)

        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
    EndSwitch

;~    // Set the position and then retrieve it.  Due to adjustments
;~    //   by Windows it may not be the same as the value set.

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    ;// If the position has changed, scroll the window and update it
    $Pos = DllStructGetData($tSCROLLINFO, "nPos")

    If ($Pos <> $yPos) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $yChar * ($yPos - $Pos))
        $yPos = $Pos
    EndIf

    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_VSCROLL
 

Modifiez ma ligne 39 _GUIScrollBars_Init($hGUI,950,40) par la ligne original _GUIScrollBars_Init($hGUI)
maintenant lorsque vous réduisez la gui à sa moitié ( hauteur et largeur ) vous ne pouvez plus afficher le dernier bouton en bas à droite "820, 620" tous juste vous voyez le bouton "380,380"
j'ai donc modifié la ligne par _GUIScrollBars_Init($hGUI,950,750) avec les dimensions de la gui.
la cela fonctionne mais l'ascenseur verticale descend vraiment trop bas inutilement.
de manière empirique j'ai trouvé la valeur _GUIScrollBars_Init($hGUI,950,40) !!!
j'aimerais savoir comment renseigner ces valeurs ( quel règle appliquer )

autre remarque de fonctionnement curieux
réduisez la hauteur de la gui ensuite déplacez l'ascenseur verticale tout en bas , augmentez la hauteur de la gui
(pas complètement) placez l'ascenseur en haut et les boutons placés en haut n'apparaisse plus !!
il faut agrandir complètement la gui pour revoir ces boutons !!

voila j'attends quelque jours vos sugestions sur ces remarques avant de passer ce post en résolu

A+ JL56

ps J'utilise au boulot un petit portable 11 " et avec mes script standard je ne pouvais atteindre les boutons ou valeur en bas du script. c'est pourquoi je recherchais une solution comme celle ci

[Tlem]

Concernant votre problème N°1, il n'y à pas vraiment de règle, mais plutôt une certaine logique.
Et cette logique serait de prendre les coordonnées MAX des contrôle les plus éloignés du point d'origine.
Soit dans votre cas les coordonnées du bouton $button10 plus ses dimensions.
Ce qui donne :

• left = 620 + 60
  top = 820 + 20

Pour votre second problème, je dirais que cela fait partie des choses désagréables sur des problèmes de traitement de la GUI.
Dans ce cas précis, il vous faudra gérer le re-dimensionnement de la GUI et vérifier que les ascenseurs soient en haut juste après.

[jl56]

Bonsoir Tlem

Merci de votre réponse je vais ajuster ca demain

Bonne nuit

A+ JL56