[R] Déplacer des objets dans une fenêtre

[tatane]

Bonjour à tous et merci pour votre aide quotidienne et votre participation à ce forum.
Voici mon "projet", très simple à expliquer mais je ne vois pas par où commencer pour le développer :

J'aimerais simplement pouvoir déplacer des icônes (objets) dans une fenêtre comme nous pouvons le faire sur le bureau de Windows/Linux/... Et si possible interagir avec ceux-ci.

Est-ce possible de réaliser cela avec autoit ?

Merci par avance pour vos réponses.

[orax]

Est-ce que vous aviez vu l'exemple dans l'aide de la fonction _GUIImageList_BeginDrag ? Ca semble un peu correspondre.

[tatane]

Bonsoir,

Je ne connaissais pas cette fonction et en effet il se pourrait qu'elle corresponde à mes attentes.
L'exemple est un peu complexe, je l'étudierai demain à tête reposée.

Merci à vous.

P.S : Il est fort probable que j'aie encore besoin de votre aide quand je vois la longueur de l'exemple ...

EDIT : Je viens de compiler l'exemple de cette fonction et malheureusement il ne correspond pas vraiment à ce que je cherche. Enfin c'est assez difficile à dire mais ce que je recherche ce serait vraiment un système ou j'ai des icônes dans une fenêtre crée par autoit et où je peux les déplacer comme les icônes du bureau Windows. A la rigueur même si l'icône/image ne suit pas le curseur de la souris pendant le déplacement ce n'est pas très grave, mais sa position doit changer lors du "drop".

[jumby]

J'ai conçu ce petit script, il permet de glisser à volonter les 2 boutons sans perdre leurs fonctions case.

► Afficher le texteEbauche 1

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#Include <GuiImageList.au3>
#include <Misc.au3>


$wintitle = "Test 1"
$dll = DllOpen("user32.dll")
AutoItSetOption ( "MouseCoordMode", 0)


$Form1 = GUICreate($wintitle, 633, 447)
$Button2 = GUICtrlCreateButton("Button2", 575, 30, 50, 36, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 200)
$Button3 = GuictrlcreateButton("Button3", 0, 0, 100, 100, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 2)
GUISetState(@SW_SHOW)





func testpress()
for $aaaaa = 1 to 9999999999999999999999999999999999999 step 1
        If _IsPressed("01", $dll) Then
            $getcoord2 = MouseGetPos()
            if $getcoord2[0] = $getcoord[0] Then
                for $a = 1 to 999999999999999999999999999999 step 1
                                                            If _IsPressed("01", $dll) = 0 Then
                                                                    $getcoord2 = MouseGetPos()
                                                if $getcoord2[0] = $getcoord[0] Then
                                                    ExitLoop 2
                                                Else
                                                    if $getcoord2[1] = $getcoord[1] Then
                                                        Exitloop 2
                                                    EndIf
                                                EndIf
                                                
                                                $getcoord2 = MouseGetPos()
                                                GUICtrlSetPos($Button2, $getcoord2[0]-($posbutton2[2]/2), $getcoord2[1]-($posbutton2[3] + 9), $posbutton2[2], $posbutton2[3])
ExitLoop 2
EndIf
Next
                
                
            Else
                            if $getcoord2[1] <> $getcoord[1] Then
                                for $a = 1 to 999999999999999999999999999999 step 1
                                            If _IsPressed("01", $dll) = 0 Then
                                                if $getcoord2[0] = $getcoord[0] Then
                                                    ExitLoop 2
                                                Else
                                                    if $getcoord2[1] = $getcoord[1] Then
                                                        exitloop 2
                                                    EndIf
                                                EndIf
                                                
                                                $getcoord2 = MouseGetPos()
                                                GUICtrlSetPos($Button2, $getcoord2[0]-($posbutton2[2]/2), $getcoord2[1]-($posbutton2[3] + 9), $posbutton2[2], $posbutton2[3])
                                                
                                                ExitLoop 2
EndIf
Next
                                
                            EndIf
                            
                        EndIf
                        
                
            EndIf
            Next
EndFunc
func testpress2()
for $aaaaa = 1 to 9999999999999999999999999999999999999 step 1
        If _IsPressed("01", $dll) Then
            $getcoord3 = MouseGetPos()
            if $getcoord3[0] = $getcoord[0] Then
                for $a = 1 to 999999999999999999999999999999 step 1
                                                            If _IsPressed("01", $dll) = 0 Then
                                                                    $getcoord3 = MouseGetPos()
                                                if $getcoord3[0] = $getcoord[0] Then
                                                    ExitLoop 2
                                                Else
                                                    if $getcoord3[1] = $getcoord[1] Then
                                                        Exitloop 2
                                                    EndIf
                                                EndIf
                                                
                                                $getcoord2 = MouseGetPos()
                                                GUICtrlSetPos($Button3, $getcoord3[0]-($posbutton3[2]/2), $getcoord3[1]-($posbutton3[3] - 20), $posbutton3[2], $posbutton3[3])
ExitLoop 2
EndIf
Next
                
                
            Else
                            if $getcoord3[1] <> $getcoord[1] Then
                                for $a = 1 to 999999999999999999999999999999 step 1
                                            If _IsPressed("01", $dll) = 0 Then
                                                if $getcoord3[0] = $getcoord[0] Then
                                                    ExitLoop 2
                                                Else
                                                    if $getcoord3[1] = $getcoord[1] Then
                                                        exitloop 2
                                                    EndIf
                                                EndIf
                                                
                                                $getcoord3 = MouseGetPos()
                                                GUICtrlSetPos($Button3, $getcoord3[0]-($posbutton3[2]/2), $getcoord3[1]-($posbutton3[3] - 20), $posbutton3[2], $posbutton3[3])
                                                
                                                ExitLoop 2
EndIf
Next
                                
                            EndIf
                            
                        EndIf
                        
                
            EndIf
            Next
EndFunc
While 1

            $getcoord = MouseGetPos()

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button3
MsgBox(0, "Button3", "Button3")

        Case $Button2 
MsgBox(0, "Button2", "Button2")
    EndSwitch
            $getcoord = MouseGetPos()
    If _IsPressed("01", $dll) Then
        
        $posbutton2 = ControlGetPos ( $wintitle, "", $Button2 )
        $posbutton3 = ControlGetPos ( $wintitle, "", $Button3 )
        if WinActive($wintitle, "") Then
            $getcoord = MouseGetPos()
            if $getcoord[0] > $posbutton2[0] + 2 Then
            if $getcoord[0] < $posbutton2[0] + $posbutton2[2] + 3 Then
            if $getcoord[1] > $posbutton2[1] + 28 Then
            if $getcoord[1] < $posbutton2[1] + 28 + $posbutton2[3] + 1 Then
call ("testpress")

EndIf
EndIf
EndIf
EndIf
                    if $getcoord[0] > $posbutton3[0] + 2 Then
            if $getcoord[0] < $posbutton3[0] + $posbutton3[2] + 3 Then
            if $getcoord[1] > $posbutton3[1] + 28 Then
            if $getcoord[1] < $posbutton3[1] + 28 + $posbutton3[3] + 1 Then
call ("testpress2")

EndIf
EndIf
EndIf
EndIf
EndIf
    EndIf
    
WEnd

DllClose($dll)

Ce n'est qu'une ébauche, si c'est ce que vous recherchez je pourrais généraliser cette fonction sur n'importe quel bouton et rajouter par exemple, un aperçu au cours du glissage du bouton et l'impossibilité de supperposer 2 boutons.

[tatane]

Bonjour jumby,

C'est exactement ce que je recherche à l'exception des boutons (et encore), je travaillerai probablement avec des icones/images. Sinon c'est parfait surtout si :

rajouter par exemple, un aperçu au cours du glissage du bouton et l'impossibilité de supperposer 2 boutons.

Alors là ce sera le rêve

Merci encore.

[tolf]

Code : Tout sélectionner

For $aaaa = 1 To 999999999999999999 Step 1

Oh...
Utilisez la boucle

Code : Tout sélectionner

While 1
...
Wend

[tatane]

Bonsoir à tous.

Je dépoussière mon Post car je viens de triturer dans tous les sens le code que m'a fourni jumby. J'ai compris les grandes lignes bien que certains tests ou redondances me paraissent encore obscures.

Voici "ma version" allégée :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#Include <GuiImageList.au3>
#include <Misc.au3>


$wintitle = "Test 1"
$dll = DllOpen("user32.dll")
AutoItSetOption ( "MouseCoordMode", 0)


$Form1 = GUICreate($wintitle, 633, 447)
$Button = GUICtrlCreateButton("Button2", 575, 30, 50, 36, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 200)

$affichage = GUICtrlCreateLabel("", 10, 370, 50, 20)
$affichage2 = GUICtrlCreateLabel("", 10, 400, 50, 20)
Global $posbutton

GUISetState(@SW_SHOW)


While 1

    ;on récupère les coordonnées de la souris en temps réel X, Y
    $getcoord_depart = MouseGetPos()

    GUICtrlSetData($affichage , $getcoord_depart[0] & "," & $getcoord_depart[1])

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch

    ;si le clic gauche a été appuyé
    If _IsPressed("01", $dll) Then

        ;variables tableaux contenant les positions des boutons : X, Y, Largeur, Hauteur
        $posbutton = ControlGetPos ( $wintitle, "", $Button )

    ;si la fenetre est active
        If WinActive($wintitle, "") Then
            $getcoord_depart = MouseGetPos()

            ;On teste si le clic de la souris est sur le bouton (quelques ajustements nécessaires à cause de la barre de titre de la fenêtre d'où le +28)
            If $getcoord_depart[0] > $posbutton[0] + 2 Then
                If $getcoord_depart[0] < $posbutton[0] + $posbutton[2] + 3 Then
                    If $getcoord_depart[1] > $posbutton[1] + 28 Then
                        If $getcoord_depart[1] < $posbutton[1] + 28 + $posbutton[3] + 1 Then
                            While 1
                                ;on récupère à nouveau les coordonnées de la souris lorsqu'on laisse le bouton gauche appuyé
                                $getcoord_depart = MouseGetPos()

                                GUICtrlSetData($affichage2 , $getcoord_depart[0] & "," & $getcoord_depart[1])

                                GUICtrlSetPos($Button, $getcoord_depart[0]-($posbutton[2]/2), $getcoord_depart[1]-($posbutton[3] + 9))
                                ExitLoop

                            WEnd
                        EndIf
                    EndIf
                EndIf
            EndIf
        EndIf
    EndIf

WEnd

DllClose($dll)
 

J'ai quelques soucis avec le déplacement du bouton. Il suit bien la souris lors d'un déplacement à vitesse lente mais il "décroche" si on accélère un peu plus. Sauriez-vous pourquoi ?

[orax]

J'ai remplacé le AutoItSetOption("MouseCoordMode", 0) par un 2, comme ça, il n'y a plus besoin du +28.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GuiImageList.au3>
#include <Misc.au3>

$wintitle = "Test 1"
$dll = DllOpen("user32.dll")
AutoItSetOption("MouseCoordMode", 2)


$Form1 = GUICreate($wintitle, 633, 447)
$Button = GUICtrlCreateButton("Button2", 575, 30, 50, 36, $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 200)

$affichage = GUICtrlCreateLabel("", 10, 370, 50, 20)
$affichage2 = GUICtrlCreateLabel("", 10, 400, 50, 20)
Global $posbutton

GUISetState(@SW_SHOW)


While 1

    ;on récupère les coordonnées de la souris en temps réel X, Y
    $getcoord_depart = MouseGetPos()

    GUICtrlSetData($affichage, $getcoord_depart[0] & "," & $getcoord_depart[1])

    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            DllClose($dll)
            Exit
    EndSwitch

    ;si le clic gauche a été appuyé
    If _IsPressed("01", $dll) Then
        ;si la fenetre est active
        If WinActive($wintitle, "") Then
            $getcoord_depart = MouseGetPos()

            ;variables tableaux contenant les positions des boutons : X, Y, Largeur, Hauteur
            $posbutton = ControlGetPos($wintitle, "", $Button)

            ;On teste si le clic de la souris est sur le bouton (quelques ajustements nécessaires à cause de la barre de titre de la fenêtre d'où le +28)
            If $getcoord_depart[0] > $posbutton[0] And _
                    $getcoord_depart[0] < $posbutton[0] + $posbutton[2] And _
                    $getcoord_depart[1] > $posbutton[1] And _
                    $getcoord_depart[1] < $posbutton[1] + $posbutton[3] + 1 Then

                $diffClicBoutonX = $getcoord_depart[0] - $posbutton[0]
                $diffClicBoutonY = $getcoord_depart[1] - $posbutton[1]

                While 1
                    ;on récupère à nouveau les coordonnées de la souris lorsqu'on laisse le bouton gauche appuyé
                    $getcoord_depart_maj = MouseGetPos()

                    If $getcoord_depart[0] <> $getcoord_depart_maj[0] Or $getcoord_depart[1] <> $getcoord_depart_maj[1] Then
                        GUICtrlSetData($affichage2, $getcoord_depart[0] & "," & $getcoord_depart[1])

                        GUICtrlSetPos($Button, $getcoord_depart_maj[0] - $diffClicBoutonX, $getcoord_depart_maj[1] - $diffClicBoutonY)
                    EndIf

                    If Not _IsPressed("01", $dll) Then ExitLoop

                    $getcoord_depart = $getcoord_depart_maj
                    Sleep(5)
                WEnd
            EndIf
        EndIf
    EndIf
WEnd

Code édité, j'avais fait une erreur !

[tatane]

Merci beaucoup, ce code fonctionne parfaitement.
J'étudierai demain les modifications que vous avez apportées pour comprendre ce qui n'allait pas avec ma version.

Bonne nuit.

[orax]

En fait, pour résoudre le problème, il fallait juste changer le ExitLoop dans la boucle While par un If Not _IsPressed("01", $dll) Then ExitLoop.

[tatane]

Bonjour,

Grâce à vous mon petit projet avance bien. Mais je me retrouve confronté à un petit problème avec la fonction _IsPressed.

En fait dans une GUI, j'ai 2 ListView et lorsque je clique sur un item de la première, cela "remplit" la seconde en fonction d'un fichier.
Jusqu'à présent, j'avais créé une fonction que j'avais placé dans la boucle infinie et qui testait la valeur de l'item sélectionné de la ListView1. Sauf que pour me permettre de gérer certains messages d'erreur, j'ai voulu ajouter dans cette fonction la fameuse fonction _IsPressed et voici mon problème :
il faut que je double-clic sur l'item de la ListView1 pour mettre à jour la ListView2 ou que je "glisse" l'item rien qu'un peu pour que _IsPressed s'active. Finalement ce n'est pas vraiment un _IsPressed qu'il me faudrait dans ce cas là mais plutôt un _IsClicked.
Y a-t-il un moyen pour résoudre se problème ?

Par avance, merci.


P.S : si par la même occasion vous pouvez m'expliquer comment utiliser la fonction ConsoleWrite(), j'en serai ravi. (impossible d'afficher le stdout dans la console ou un éditeur de texte)

[guitarist]

Pour consolewrite d'apres mes souvenir (tres trompeurs parfois) il faut compiler le script et consolewrite affiche le text que vous voulez

Bonne chance

[tatane]

Je compile toujours mon script pourtant le consolewrite n'affiche rien du tout .
Je tourne sous Seven 64, le problème viendrait-il de là ?

Et pour problème de _IsPressed, une idée ?

[orax]

- Pour consolewrite(), j'utilise Scite4AutoIt, je lance le script avec F5 et consolewrite() écrit dans la zone en bas (F8 pour l'afficher).
Par contre, son on crée un exe du script en mode gui et qu'on le lance dans une console Dos, visiblement consolewrite n'affiche rien... C'est peut-être normal, je n'en sais rien. Mais si on ajoute #AutoIt3Wrapper_Change2CUI=y (pour compiler en mode console et non gui) au début du script, ben là, quand je lance le script dans une fenêtre Dos, consolewrite écrit bien dans la console.
Au lieu d'ajouter manuellement #AutoIt3Wrapper_Change2CUI=y, on peut aussi (dans Scite) aller dans Tools->Compile->Create CUI...

- Si j'ai bien compris, vous voulez que le script détecte quand vous faites un clic dans la listview. Si c'est bien ça, voyez l'exemple de la fonction _GUICtrlListView_Create dans l'aide. Ce qui se trouve après "Case $NM_CLICK", à la ligne 333, est exécuté quand on fait un clic sur un élément de la listview.

[Tlem]

G.U.I = Graphical User Interface
C.U.I = Console User Interface

[tatane]

Merci pour toutes ces infos !
En effet pour que consolewrite fonctionne, il suffit de compiler le script en CUI. Une invite de commande msdos s'ouvre alors lorsque consolewrite est appelée.

Bien vu orax ! Bien que je ne comprenne pas grand chose à l'exemple fourni avec _GUICtrlListView_Create(), j'en comprends suffisamment pour extraire ce dont j'ai besoin, le $NM_CLICK. Je vais être obligé de modifier un peu mon code pour l'adapter à la création des listview par _GUICtrlListView_Create() mais ça me paraît faisable (à mon niveau).

P.S. : si quelqu'un se sent capable de m'expliquer l'exemple fourni avec cette commande, en particulier la modification du WM_NOTIFY, je lui en serais reconnaissant .

EDIT : Je viens de voir que l'un des $iExStyle fait référence au clic de la souris : $LVS_EX_ONECLICKACTIVATE - The control sends an $LVN_ITEMACTIVATE messages when the user clicks an item.
Est-il utilisable dans mon cas ? Si oui, comment ?

[orax]

Pour bien comprendre le WM_NOTIFY, il faut avoir quelques connaissances en l'API Win32, notamment concernant la gestion des évènements. Pour ma part, je ne pense pas être capable de pouvoir vous expliquer , mais il y existe quelques tutoriels sur le sujet. Sinon, d'une manière générale, la documentation se trouve sur MSDN. Par exemple, si on recherche NM_CLICK sur MSDN, on tombe sur http://msdn.microsoft.com/en-us/library ... S.85).aspx, et là on a toutes les infos pour nous permettre de l'utiliser, tel que le contenu de la structure NMITEMACTIVATE (voir $tagNMITEMACTIVATE dans AutoIt).

Pour $LVS_EX_ONECLICKACTIVATE, je ne sais pas si ça serait utilisable dans ce cas.

[arrkhan]

Je suis pour ma part, parti dans une toute autre direction, mais je pense que ça peut fonctionner pour ce que vous voulez faire.
J'ai simplifié le code au maximum
En espérant que ça vous convienne

► Afficher le texte

Code : Tout sélectionner

#include<Array.au3>

Opt("MouseCoordMode", 2)
Opt("guioneventmode", 1)

Global $cHoverID[2], $Global_cHID = 0, $cHoverActive = 0, $cHClicked = 0

$Gui = GUICreate("Drag Gui", 500, 200)

AdlibEnable("_CheckPressed", 10)

$DragLabel = GUICtrlCreateLabel("Dragable Label", 10, 10, 80, 15)
$Ok = GUICtrlCreateButton("OK", 10, 100, 100, 20)
$Cancel = GUICtrlCreateButton("Annuler", 10, 140, 100, 20)
$Lock = GUICtrlCreateButton("Débloquer les contrôles", 150, 10)
$FlagMove = 0
_ControlHover(2, $Gui, $DragLabel)
_ControlHover(2, $Gui, $Ok)
_ControlHover(2, $Gui, $Cancel)
_ControlHover(2, $Gui, $Lock)

GUISetState()
GUISetOnEvent(-3, "_Exit")

While 1
    Sleep(10)
WEnd

Func _CheckPressed()

    _ControlHover(0, $Gui)
    $CtrlId2 = _ControlHover(1, $Gui)
    $tempID2 = @extended
    If $CtrlId2 = 1 Then
        ;ToolTip($tempID2, 0, 0, "DEBUG")
        If $FlagMove = 1 Then
            Switch $tempID2
                Case $DragLabel
                    MoveControl(3)
                Case $Ok
                    MoveControl(4)
                Case $Cancel
                    MoveControl(5)
                Case $Lock
                    GUICtrlSetData(6, "Débloquer les contrôles")
                    $FlagMove = 0
            EndSwitch
        Else
            Switch $tempID2
                Case $DragLabel
                    MsgBox(0, 'Test', 'Label', 2)
                Case $Ok
                    MsgBox(0, 'Test', 'Ok', 2)
                Case $Cancel
                    MsgBox(0, 'Test', 'Annuler', 2)
                Case $Lock
                    GUICtrlSetData(6, "Bloquer les contrôles")
                    $FlagMove = 1
            EndSwitch
        EndIf
    EndIf
EndFunc   ;==>_CheckPressed

Func MoveControl($ID2Move)
    Do
        $Move = GUIGetCursorInfo()
        $mousepos = MouseGetPos()
        GUICtrlSetPos($ID2Move, $mousepos[0] - 40, $mousepos[1] - 10)
        Sleep(10)
    Until $Move[2] = 0
EndFunc   ;==>MoveControl

Func _Exit()
    AdlibDisable()
    Exit
EndFunc   ;==>_Exit

;===============================================================================
;
; Function Name:    _ControlHover()
; Description:      Enable Mouse/Hover Over Control Events
;                   Find if Mouse is over a known control
;                   Find if a Mouse has Clicked on a known control
;                   Add, Remove, or Verify the control within the known control list
; Parameter(s):     $cH_Mode    [default]       0 = Find if Mouse is over a known control
;                               [optional]      1 = Find if a Mouse has Clicked on a known control
;                                               2 = Add a control to the known control list
;                                               3 = Remove a control from the known control list
;                                               4 = Verify a control is in the known control list
;                   $cH_hWin    [optional]      - Window handle as returned by GUICreate()
;                               [preferred]     - Window handle to save CPU usage and speed of _ControlHover()
;                                               - and Avoid array errors for "non-active window"
;                   $cH_hCntrl  [required]      - Control ID to Add, Remove, or Verify the control within the known control list
;                               [not used]      - to find if a mouse is over or has clicked on a known control
; Requirement(s):   #include<Array.au3>
; Return Value(s):
;                   $cH_Mode 0 or 1
;                               On Success  Return = 1      @error = 0, @extended = Current known control
;                               While Success Return = ""
;                               On Failure: Return = 0      @error = 1, @extended = Last known control
;                   $cH_Mode 2, 3, or 4
;                               On Success  Return = 1      @error = 0, @extended = Function's return line number
;                   All $cH_Mode's
;                               On Error:   Return = Description of the error
;                                                           @error = -1, @extended = Function's return line number
; Author(s):        Valuater, Robert M
;
;===============================================================================
Func _ControlHover($cH_Mode = 0, $cH_hWin = "", $cH_hCntrl = "")

    Local $cH_i, $cH_Data
    If not @Compiled Then Opt("TrayIconDebug", 1) ; 1=debug line info

    Select
        Case $cH_Mode = 0 Or $cH_Mode = 1 ; 0 = Check if mouse is over a control, 1 = Check if mouse clicked on a control

            ; Developer did not add any controls before the function mode 0 or 1 was called
            If UBound($cHoverID) = 2 Then ConsoleWrite("*** _ControlHover() Error *** " & @CRLF & "No Controls were Added" & @CRLF)

            If $cH_hWin = "" Then
                $cH_Data = GUIGetCursorInfo() ; Get cursor data from the active window
            Else
                If Not WinActive($cH_hWin) Then Return SetError( -1, 1, "Window not active") ; Dont waist CPU if the known window is not active
                $cH_Data = GUIGetCursorInfo($cH_hWin) ; Get cursor data from the known window
            EndIf

            If Not IsArray($cH_Data) Then Return SetError( -1, 2, "Window not found") ; A readable GUI window was not found

            For $cH_i = 1 to UBound($cHoverID) -1 ; Search the known controls for the currently hovered control
                If $cH_Data[4] = $cHoverID[$cH_i] Then ; Mouse is over a current known control

                    ; Mode 1 - check for a Click on a known control
                    If $cH_Mode And $cH_Data[2] = 1 and Not $cHClicked Then
                        $cHClicked = 1
                        Return SetError( 0, $cHoverID[$Global_cHID], 1) ; Mouse clicked on current control
                    ElseIf $cH_Mode And $cH_Data[2] <> 1 And $cHClicked Then
                        $cHClicked = 0
                        Return SetError( 1, $cHoverID[$Global_cHID], 0) ; Release clicked current control
                    EndIf
                    If $cH_Mode Then Return SetError ( "", "", "") ; Mouse is still over last known control and may click again

                    ; Mode 0 & 1
                    If $cHoverID[$cH_i] = $cHoverID[$Global_cHID] And $cHoverActive Then Return SetError ( "", "", "") ; Mouse is still over last known control
                    If $cHoverActive Then
                        $cHoverActive = 0
                        Return SetError( 1, $cHoverID[$Global_cHID], 0) ; Release Active - Mouse is over a new known control
                    EndIf
                    $cHoverActive = 1
                    $cHoverID[$Global_cHID] = $cHoverID[$cH_i] ; Re-set the current control to the new known control
                    Return SetError(0, $cHoverID[$Global_cHID], 1) ; Mouse is over the new-current known control

                EndIf
            Next
            ; hover control not found in the known control list
            If $cHoverActive Then
                If  $cH_Mode And $cHClicked Then  ; check - Release clicked current control
                    $cHClicked = 0
                    Return SetError( 1, $cHoverID[$Global_cHID], 0) ; Release clicked current control
                EndIf
                If $cH_Mode Then Return SetError ( "", "", "") ; Protect the release of the active control
                $cHoverActive = 0
                Return SetError( 1, $cHoverID[$Global_cHID], 0) ; Release Active - Mouse is over a new unknown control
            EndIf
            If  $cH_Mode And $cHClicked Then
                $cHClicked = 0
                Return SetError( 1, $cHoverID[$Global_cHID], 0) ; Release clicked current control
            EndIf
            Return SetError ( "", "", "")

        Case $cH_Mode = 2 ; Add the new control to the known control list

            If $cH_hCntrl = "" Then Return SetError( -1, 8, "Control not provided #1") ; The control ID was not given
            _ArrayAdd($cHoverID, $cH_hCntrl) ; Add the control to the known control array
            If @error Then Return SetError( -1, 9, "Control not added") ; Control not added to the known control list
            Return SetError( 0, 10, 1) ; ; Control was added to the known control list

        Case $cH_Mode = 3 ; Remove the control from the known control list

            If $cH_hCntrl = "" Then Return SetError( -1, 11, "Control not provided #2") ; The control ID was not given
            _ArrayDelete($cHoverID, $cH_hCntrl) ; Delete the control from the known control array list
            If @error Then Return SetError( -1, 12, "Control not removed") ; Control not deleted from the known control list
            Return SetError( 0, 13, 1) ; Control was deleted from the known control list

        Case $cH_Mode = 4 ; Verify if control is in the known control list

            If $cH_hCntrl = "" Then Return SetError( -1, 14, "Control not provided #3") ; The control ID was not given
            _ArraySearch($cHoverID, $cH_hCntrl) ; Search to verify if control is in the known control list
            If @error Then Return SetError( -1, 15, "Control not found") ; Control was not found in the known control list
            Return SetError( 0, 16, 1) ; Control was found in the known control list

        Case Else
            Return SetError( -1, 17, "$cH_Mode incorrect") ; $cH_Mode has an incorrect value
    EndSelect
    Return SetError( -1, 18, "Unknown Error") ; Error is Unknown
EndFunc
 

[tatane]

Bonjour à tous,

Merci pour votre aide, je n'aurais pu réaliser mon programme sans vous.
Il est en phase de beta test si je puis dire ^^. Il ne devrait pas tarder à passer en version finale, je le posterai dès que ce sera le cas. En fait, j'ai voulu créer ce programme pour remplacer Visual VNC qui était plutôt buggé et dont le suivi est arrêté depuis longtemps. Il est fort possible que vous ne le connaissiez pas car il est surtout orienté vers l'éducation nationale.