[R] Problème CheckBox et appel de fonction

[AirPE]

Bonjour,

Quel beau temps il fait aujourd'hui!!

J'ai un problème à propos de la sélection/désélection de CheckBox.
Je vous met d'abord mon code:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Global $check1, $check2, $check3, $check4, $check5, $check6, $check11

GUICreate("test", 600, 500)

$dateHeure = GUICtrlCreateLabel("Nous sommes le "&@MDAY&"/"&@MON&"/"&@YEAR&" et il est "&@HOUR&":"&@MIN, 10, 10)

$tab = GUICtrlCreateTab(20, 30, 560, 460)
$tab0 = GUICtrlCreateTabItem("onglet1")


GUICtrlCreateGroup("test1", 40, 90, 120, 150)
Createcheck(45)
toutSelectionner()
GUICtrlCreateGroup("test2", 170, 90, 120, 150)
Createcheck(175)
toutSelectionner()

$bouton1 = GUICtrlCreateButton(" tout désélectionner ", 40, 250)

$bouton2 = GUICtrlCreateButton(" tout désélectionner ", 170, 250)

$tab1 = GUICtrlCreateTabItem("onglet2")
;contenu du deuxieme onglets

GUICtrlCreateTabItem("");fin des onglets

GUISetState()

While 1
    $msg = GUIGetMsg()

    dateHeure()
    
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $bouton1
            If GUICtrlRead($bouton1) = " tout désélectionner " Then
                If GUICtrlRead($check1) = $GUI_CHECKED Or GUICtrlRead($check2) = $GUI_CHECKED Or GUICtrlRead($check3) = $GUI_CHECKED Or GUICtrlRead($check4) = $GUI_CHECKED Or GUICtrlRead($check5) = $GUI_CHECKED Or GUICtrlRead($check6) = $GUI_CHECKED Then
                    toutDeselectionner()
                EndIf
                GUICtrlSetData($bouton1, " tout sélectionner ")
            ElseIf GUICtrlRead($bouton1) = " tout sélectionner " Then
                If GUICtrlRead($check1) <> $GUI_CHECKED Or GUICtrlRead($check2) <> $GUI_CHECKED Or GUICtrlRead($check3) <> $GUI_CHECKED Or GUICtrlRead($check4) <> $GUI_CHECKED Or GUICtrlRead($check5) <> $GUI_CHECKED Or GUICtrlRead($check6) <> $GUI_CHECKED Then
                    toutSelectionner()
                EndIf
                GUICtrlSetData($bouton1, " tout désélectionner ")
            EndIf
        Case $msg = $bouton2
            If GUICtrlRead($bouton2) = " tout désélectionner " Then
                If GUICtrlRead($check1) = $GUI_CHECKED Or GUICtrlRead($check2) = $GUI_CHECKED Or GUICtrlRead($check3) = $GUI_CHECKED Or GUICtrlRead($check4) = $GUI_CHECKED Or GUICtrlRead($check5) = $GUI_CHECKED Or GUICtrlRead($check6) = $GUI_CHECKED Then
                    toutDeselectionner()
                EndIf
                GUICtrlSetData($bouton2, " tout sélectionner ")
            ElseIf GUICtrlRead($bouton2) = " tout sélectionner " Then
                If GUICtrlRead($check1) <> $GUI_CHECKED Or GUICtrlRead($check2) <> $GUI_CHECKED Or GUICtrlRead($check3) <> $GUI_CHECKED Or GUICtrlRead($check4) <> $GUI_CHECKED Or GUICtrlRead($check5) <> $GUI_CHECKED Or GUICtrlRead($check6) <> $GUI_CHECKED Then
                    toutSelectionner()
                EndIf
                GUICtrlSetData($bouton2, " tout désélectionner ")
            EndIf
    EndSelect
WEnd

Func dateHeure()
    $String = StringRight(GUICtrlRead($dateHeure), 2)
    If $String <> @MIN Then
        GUICtrlSetData($dateHeure, "Nous sommes le "&@MDAY&"/"&@MON&"/"&@YEAR&" et il est "&@HOUR&":"&@MIN)
    EndIf
EndFunc

Func Createcheck($x)
    $check1 = GUICtrlCreateCheckbox("box1", $x, 110)
    $check2 = GUICtrlCreateCheckbox("box2", $x, 130)
    $check3 = GUICtrlCreateCheckbox("box3", $x, 150)
    $check4 = GUICtrlCreateCheckbox("box4", $x, 170)
    $check5 = GUICtrlCreateCheckbox("box5", $x, 190)
    $check6 = GUICtrlCreateCheckbox("box6", $x, 210)

    GUICtrlSetTip($check1, "activer box1")
    GUICtrlSetTip($check2, "activer box2")
    GUICtrlSetTip($check3, "activer box3")
    GUICtrlSetTip($check4, "activer box4")
    GUICtrlSetTip($check5, "activer box5")
    GUICtrlSetTip($check6, "activer box6")
EndFunc

Func toutSelectionner()
    GUICtrlSetState($check1, $GUI_CHECKED)
    GUICtrlSetState($check2, $GUI_CHECKED)
    GUICtrlSetState($check3, $GUI_CHECKED)
    GUICtrlSetState($check4, $GUI_CHECKED)
    GUICtrlSetState($check5, $GUI_CHECKED)
    GUICtrlSetState($check6, $GUI_CHECKED)
EndFunc

Func toutDeselectionner()
    GUICtrlSetState($check1, $GUI_UNCHECKED)
    GUICtrlSetState($check2, $GUI_UNCHECKED)
    GUICtrlSetState($check3, $GUI_UNCHECKED)
    GUICtrlSetState($check4, $GUI_UNCHECKED)
    GUICtrlSetState($check5, $GUI_UNCHECKED)
    GUICtrlSetState($check6, $GUI_UNCHECKED)
EndFunc

En gros quand vous cliquer sur "tout sélectionner" ou "tout désélectionner" du groupe 1 ca fonctionne sur le groupe 2 si je fais la même chose avec le deuxième bouton, ca le fait bien sur le groupe 2. Les deux boutons sélectionnent/désélectionnent les Box du goupe 2 et j'aimerai bien que le premier bouton fonctionne sur le premier groupe et le deuxième bouton sur le deuxième groupe et tout ça avec une appel de fonction ou un moyen quelconque pour optimier le code. Car il y aura au final 4 groupe ayant le même contenu, ce serait assez lourd de faire 4 gros pavé différent pour faire la même chose. Seulement en faisant des appels de fonctions, les variables ne changent pas (ce qui est normal! ) du coup beh ca donne mon problème...

Merci d'avance!

[GaRydelaMer]

Bonsoir

j'ai corrigé ton code. le voila!

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Global $Check_Lib[3][6]

GUICreate("test", 600, 500)

$dateHeure = GUICtrlCreateLabel("Nous sommes le "&@MDAY&"/"&@MON&"/"&@YEAR&" et il est "&@HOUR&":"&@MIN, 10, 10)

$tab = GUICtrlCreateTab(20, 30, 560, 460)
$tab0 = GUICtrlCreateTabItem("onglet1")


GUICtrlCreateGroup("test1", 40, 90, 120, 150)
Createcheck(45, 1)
toutSelectionner(1)
GUICtrlCreateGroup("test2", 170, 90, 120, 150)
Createcheck(175, 2)
toutSelectionner(2)

$bouton1 = GUICtrlCreateButton(" tout désélectionner ", 40, 250)

$bouton2 = GUICtrlCreateButton(" tout désélectionner ", 170, 250)

$tab1 = GUICtrlCreateTabItem("onglet2")
;contenu du deuxieme onglets

GUICtrlCreateTabItem("");fin des onglets

GUISetState()

While 1
    $msg = GUIGetMsg()

    dateHeure()
   
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $bouton1
            If GUICtrlRead($bouton1) = " tout désélectionner " Then
                toutDeselectionner(1)
                GUICtrlSetData($bouton1, " tout sélectionner ")
            ElseIf GUICtrlRead($bouton1) = " tout sélectionner " Then
                toutSelectionner(1)
                GUICtrlSetData($bouton1, " tout désélectionner ")
            EndIf
        Case $msg = $bouton2
            If GUICtrlRead($bouton2) = " tout désélectionner " Then
                toutDeselectionner(2)
                GUICtrlSetData($bouton2, " tout sélectionner ")
            ElseIf GUICtrlRead($bouton2) = " tout sélectionner " Then
                toutSelectionner(2)
                GUICtrlSetData($bouton2, " tout désélectionner ")
            EndIf
    EndSelect
WEnd

Func dateHeure()
    $String = StringRight(GUICtrlRead($dateHeure), 2)
    If $String <> @MIN Then
        GUICtrlSetData($dateHeure, "Nous sommes le "&@MDAY&"/"&@MON&"/"&@YEAR&" et il est "&@HOUR&":"&@MIN)
    EndIf
EndFunc

Func Createcheck($x, $id)
    $Check_Lib[$id][0] = GUICtrlCreateCheckbox("box1", $x, 110)
    GUICtrlSetTip(-1, "activer box1")
    $Check_Lib[$id][1] = GUICtrlCreateCheckbox("box12", $x, 130)
    GUICtrlSetTip(-1, "activer box2")
    $Check_Lib[$id][2] = GUICtrlCreateCheckbox("box3", $x, 150)
    GUICtrlSetTip(-1, "activer box3")
    $Check_Lib[$id][3] = GUICtrlCreateCheckbox("box4", $x, 170)
    GUICtrlSetTip(-1, "activer box4")
    $Check_Lib[$id][4] = GUICtrlCreateCheckbox("box5", $x, 190)
    GUICtrlSetTip(-1, "activer box5")
    $Check_Lib[$id][5] = GUICtrlCreateCheckbox("box6", $x, 210)
    GUICtrlSetTip(-1, "activer box6")
EndFunc

Func toutSelectionner($id)
    For $i = 0 To 5
        GUICtrlSetState($Check_Lib[$id][$i], $GUI_CHECKED)
    Next
EndFunc

Func toutDeselectionner($id)
    For $i = 0 To 5
        GUICtrlSetState($Check_Lib[$id][$i], $GUI_UNCHECKED)
    Next
EndFunc

Le truc c'est d'utiliser un tableau à 2 dimensions pour stocker dans ton application les variables d'accès à tes differentes CheckBox.

Ensuite pour y accéder la 1ere dimension correspond à tes groupes (penses à l'augmenter pour tes autres groupes ) et la 2émé dimension correspond à tes CheckBox en partant de 0 pour la 1ère.
de cette façon dans une boucle: $Check_Lib[$id][$i]
ou directement $Check_Lib[1][2], Groupe 1, checkbox 3


Ton erreur venait du fait que tu utilisais la même variable pour tes checkbox en appelant 2 fois la fonction de création et donc tu remplacer $check1, 2 etc par les dernières valeurs au differents appels.
Voila

[AirPE]

Waaaah!!! Merci!! Ca paraît tellement facile quand on a la réponse!!
pour mon erreur, oui j'avais bien compris que c'était à cause des variables, et j'avais effectivement penser à un tableau mais simple, donc le problème revenait au même!

Là je viens juste de rentrer chez moi et Ô surprise!! Un script tout jolie tout bon!

Franchement un GRAND merci!!!